.include "m32def.inc"

.equ XTAL  		= 1000000
.equ LCD_PORT	= PORTB
.equ LCD_Com	= PortC
.equ LCD_RS		= PC0
.equ LCD_RW    	= PC2
.equ LCD_E   	= PC4
.equ LCD_LED	= PD5 
.equ RTCs		= PC5
.equ RTCi		= PC3
.equ RTCr		= PC1
.equ PW_Relais	= PC7
.equ SW0_Pin	= PD0
.equ SW1_Pin	= PD1
.equ SW2_Pin	= PD4
.def temp1		= r16
.def temp2		= r17
.def temp3		= r18
.def dat0		= r19
.def adr0		= r20    
.def MenuDelay	= r21

;Sekunden		= RtcAdress, 0x80  (1R) (0W)
;Minuten		= RtcAdress, 0x82
;Stunden		= RtcAdress, 0x84
;Tag			= RtcAdress, 0x86
;Monat			= RtcAdress, 0x88
;Wochentag		= RtcAdress, 0x8A
;Alarm0 		= RtcAdress, 0xC0
;Alarm1			= RtcAdress, 0xC2
;Alarm on/off	= RtcAdress, 0xC4
;Status			= RtcAdress, 0xC6

.org 0x0000
	rjmp main
.org INT0addr
	reti
.org INT1addr
	reti
.org OVF0addr
	rjmp Overflow0


main:
	ldi r16, LOW(RAMEND)
	out SPL, r16
	ldi r16, HIGH(RAMEND)
	out SPH, r16
	
	ldi r16, (1<<CS02)
	out TCCR0, r16
	ldi r16, (1<<TOIE0)
	out TIMSK, r16
	sei

	clr temp1
	sts SW0, temp1
	sts SW0_Toggle, temp1
	sts SW0_Delay, temp1
	sts SW0_Count, temp1
	sts SW12_Dir, temp1
	sts SW12_DirSet, temp1
	ldi temp1, 4
	sts SW0_Times, temp1

	clr MenuDelay

	ldi r16, 255
	out DDRB, r16
	out DDRC, r16
	clr r16
	out PortB, r16
	out PortC, r16
	ldi r16, 32
	out DDRD, r16

	rcall lcd_init
	rcall rtc_init

	ldi adr0, 0x82
	ldi dat0, 0x10
	rcall RtcWriteCommand
 
	ldi      temp1, 1<<COM1A1 | 1<<WGM11
    out      TCCR1A, temp1
    ldi      temp1, 1<<WGM13 | 1<<WGM12 | 1<<CS10
    out      TCCR1B, temp1
	ldi      temp1, 0x0F
    out      ICR1H, temp1
	
	
    ldi      temp1, 0xFF
    out      ICR1L, temp1
	ldi      temp1, 0x0F
    out      OCR1AH, temp1
    ldi      temp1, 0xFF
    out      OCR1AL, temp1


Home:
	ldi r19, 0x01
	rcall lcd_command
CurrentClock:
	ldi r19, 0x80
	rcall lcd_command
	ldi adr0, 0x85
	rcall RtcReadCommand
	rcall ReClock
	ldi r19, ':'
	rcall lcd_data
	ldi adr0, 0x83
	rcall RtcReadCommand
	rcall ReClock
	ldi r19, ':'
	rcall lcd_data
	ldi adr0, 0x81
	rcall RtcReadCommand
	rcall ReClock
CurrentAlarm:
	ldi r19, ' '
	rcall lcd_data
	rcall lcd_data

	ldi adr0, 0x88
	ldi dat0, 0x10
	rcall RtcWriteCommand
	

	ldi adr0, 0xC5
	rcall RtcReadCommand
	rcall lcd_data
	ldi adr0, 0xC1
	rcall RtcReadCommand
	cpi dat0, 17
	brlo noZero
	rcall ReClock
noZeroOut:
	ldi r19, ':'
	rcall lcd_data
	ldi adr0, 0xC3
	rcall RtcReadCommand
	rcall ReClock
CurrentDate:
	ldi r19, 0xA8
	rcall lcd_command
	ldi adr0, 0x8B
	rcall RtcReadCommand
	ldi ZL, LOW(date*2)
	ldi ZH, HIGH(date*2)
	mov temp1, dat0
	add dat0, temp1
CurrLoop:
	lpm temp2, z+
	dec dat0
	brne CurrLoop
	lpm dat0, z+
	rcall lcd_data
	lpm dat0, z+
	rcall lcd_data
	ldi dat0, '.'
	rcall lcd_data
	ldi adr0, 0x87
	rcall RtcReadCommand
	rcall ReClock
	ldi dat0, '.'
	rcall lcd_data
	ldi adr0, 0x89
	rcall RtcReadCommand
	rcall ReClock

CurrentStatus:
	ldi dat0, ' '
	rcall lcd_data
	ldi adr0, 0xC7
	rcall RtcReadCommand
	clr temp2
	inc dat0
CurrentStatus0:
	subi temp2, -7
	dec dat0
	brne CurrentStatus0	

	ldi ZL, LOW(status*2)
	ldi ZH, HIGH(status*2)

	
CS_Loop:
	lpm dat0, z+
	dec temp2
	brne CS_Loop
	ldi temp2, 7
CS_Loop0:
	lpm dat0, z+
	rcall lcd_data
	dec temp2
	brne CS_Loop0
	rcall CheckSW0_Times
	rcall CheckSW1SW2
	rjmp CurrentClock

noZero:
	push dat0
	ldi dat0, ' '
	rcall lcd_data
	pop dat0
	mov temp2, dat0
	rcall check_bcd
	rjmp noZeroOut

ReClock:
	mov temp2, dat0
	push temp2
	swap temp2
	andi temp2, 0b00001111
	rcall check_bcd
	pop temp2
	andi temp2, 0b00001111
	rcall check_bcd
	ret

check_bcd:
	ldi temp3, '0'
check_bcd1:
	add temp3, temp2
	mov r19, temp3
	rcall lcd_data
	ret

lcd_init:
 	cbi PortC, LCD_RW
    ldi   temp3,6
powerupwait:
    rcall delay5ms
    dec   temp3
    brne  powerupwait
    ldi   temp1, 0b00110000
    out   PortB, temp1 
    rcall lcd_enable
    rcall delay5ms
    rcall lcd_enable
    rcall delay5ms
    rcall lcd_enable
    rcall delay5ms
    ldi   temp1, 0b00111000    
    out   PortB, temp1
	rcall lcd_enable
	rcall delay50us
    ldi   temp1, 0b00001100   
    out   PortB, temp1
	rcall lcd_enable
	rcall delay50us
	ldi r19, 0b00000001
	rcall lcd_command
	rcall delay5ms
Charakter:
	ldi r19, 0b01000000
	rcall lcd_command
	
	ldi ZL, LOW(CG00*2)
	ldi ZH, HIGH(CG00*2)
	ldi temp3, 16
cg00loop:
	lpm r19, z+
	rcall lcd_data
	dec temp3
	brne cg00loop

	ldi r19, 0b10000000
	rcall lcd_command
	ret

lcd_data:
	sbi PortC, LCD_RS
	out LCD_PORT, r19
	rcall lcd_enable
	cbi PortC, LCD_RS
	ret               

lcd_command:
	cbi PortC, LCD_RS
	out LCD_Port, r19
	rcall lcd_enable
	sbi PortC, LCD_RS
	ret

lcd_enable:
	sbi PortC, LCD_E
	rcall delay50us
	cbi PortC, LCD_E
	ret 

delay50us:             
	ldi  temp1, ( XTAL * 50 / 3 ) / 1000000
delay50us_:
	dec  temp1
    brne delay50us_
	ret                         
 
delay5ms:                               
	ldi  temp1, ( XTAL * 5 / 607 ) / 1000
WGLOOP0:   
	ldi  temp2, $C9
WGLOOP1:   
	dec  temp2
    brne WGLOOP1
    dec  temp1
    brne WGLOOP0
    ret        

rtc_init:
	ldi adr0, 0x8E
	clr dat0
	rcall RtcWriteCommand

	ldi adr0, 0x90
	ldi dat0, 0xA0
	rcall RtcWriteCommand
	ret



RtcWriteCommand:
	sbi DDRC, 3
	sbi PortC, 1
	push dat0
	mov dat0, adr0
	rcall CeClkSetupTime
	rcall RtcWriteByte
	pop dat0
	rcall RtcWriteByte
	cbi PortC, 1
	ret
	
RtcWriteByte:
	ldi temp1, 8
RtcWriteByte2:
	rcall ClkDataDelayTime
	lsr dat0
	brcs RtcWriteByte3
	cbi PortC, 3
	rjmp RtcWriteByte4
RtcWriteByte3:
	sbi PortC, 3
RtcWriteByte4:
	nop
	sbi PortC, 5
	rcall ClkLoHiTime
	cbi PortC, 5
	rcall ClkLoHiTime
	dec temp1
	brne RtcWriteByte2
	ret

RtcReadCommand:
	cbi DDRC, 3
	cbi PortC, 3
	sbi PortC, 1
	rcall CeClkSetupTime
	mov dat0, adr0
	rcall RtcWriteByte
	ldi temp1, 8
RtcReadCmd1:
	clc
	sbic PinC, 3
	sec
	sbi PortC, 5
	ror dat0
	rcall ClkLoHiTime
	cbi PortC, 5
	rcall ClkLoHiTime
	dec temp1
	brne RtcReadCmd1
	cbi PortC, 1
	ret

ClkLoHiTime:
ClkDataDelayTime:
	ldi temp2, 1
ClkLoHiTime1:
	nop
	dec temp2
	brne ClkLoHiTime1
	ret 

CeClkSetupTime:
	ldi temp2,5
	nop
CeCLKSetupTime1:
	dec temp2
	brne CEClkSetupTime1
	ret

CheckSW0_Times:
	lds temp2, SW0_Times
	cpi temp2, 0
	breq CheckSW0
	dec temp2
	sts SW0_Times, temp2
	lds temp2, SW0
	sbic PinD, SW0_Pin
	inc temp2
	sts SW0, temp2
	ret
CheckSW0:
	lds temp2, SW0
	cpi temp2, 0
	breq SW0_Toggle1
	cpi temp2, 4
	breq SW0_Toggle0
Checkout:
	clr temp2
	sts SW0, temp2
	ldi temp2, 4
	sts SW0_Times, temp2
	ret
Checkout_delay:
	lds temp2, SW0_Delay
	cpi temp2, 24
	brsh DelaySet
	inc temp2
	sts SW0_Delay, temp2
	rjmp Checkout
DelaySet:
	lds temp2, SW0_Count
	cpi temp2, 1
	brsh DelaySet1
	inc temp2
	sts SW0_Count, temp2
DelaySet1:
	clr temp2
	sts SW0_Delay, temp2
	ldi adr0, 0xC5
	rcall RtcReadCommand
	cpi dat0, 0
	breq SW_delay1
	cpi dat0, 1
	breq SW_Delay0
	rjmp Checkout
SW_delay1:
	ldi adr0, 0xC4
	ldi dat0, 1
	rcall RtCWriteCommand
	rjmp Checkout
SW_delay0:
	ldi adr0, 0xC4
	ldi dat0, 0
	rcall RtCWriteCommand
	rjmp Checkout
SW0_Toggle0:
	lds temp3, SW0_Toggle
	sbrc temp3, 0
	rjmp Checkout_delay
	inc temp3
	sts SW0_Toggle, temp3
	rjmp Checkout
SW0_Toggle1:
	lds temp3, SW0_Toggle                            
	sbrs temp3, 0
	rjmp Checkout
	inc temp3
	sts SW0_Toggle, temp3
	rcall SW0set
	rjmp Checkout
SW0set:
	lds Temp2, SW0_Count
	cpi temp2, 0
	breq SW0set1
	dec temp2
	sts SW0_Count, temp2
	rjmp Checkout
SW0set1:
	ldi adr0, 0xC7
	rcall RtcReadCommand
	cpi dat0, 0
	breq SWsetON
	cpi dat0, 1
	breq SWsetOFF
	cpi dat0, 2
	breq SWsetOFF
	ret
SWsetON:
	ldi adr0, 0xC6 
	ldi dat0, 1
	rcall RtcWriteCommand
	sbi PortC, 7
	ret
SWsetOFF:
	ldi adr0, 0xC6
	ldi dat0, 0
	rcall RtcWriteCommand
	cbi PortC, 7
	ret


CheckSW1SW2:
	sbis PinD, SW1_pin
	rjmp SW1c
SW1s:
	sbis PinD, SW2_Pin
	rjmp DirSet0
SW1SW2s:
	ldi temp1, 1
	sts SW12_DirSet, temp1
	ret

SW1c:
	sbis PinD, SW2_Pin
	ret
	rjmp DirSet1 
DirSet0:
	lds temp2, SW12_DirSet
	cpi temp2, 1
	breq S1
	clr temp2
	sts SW12_dir, temp2
	ret
DirSet1:
	lds temp2, SW12_DirSet
	cpi temp2, 1
	breq S2
	ldi temp2, 1
	sts SW12_dir, temp2
	ret

S1:
	clr temp2
	sts SW12_DirSet, temp2

	ldi adr0, 0xC3
	rcall RtcReadCommand
	inc dat0

	ldi adr0, 0xC2
	rcall RtcWriteCommand

	ret

S2:
	clr temp2
	sts SW12_DirSet, temp2

	ldi adr0, 0xC3
	rcall RtcReadCommand
	dec dat0
	ldi adr0, 0xC2
	rcall RtcWriteCommand
	
	ret

SleepTimer_Start:
	ldi MenuDelay, 200
	ldi r19, 0x01
	rcall lcd_command
SleepTimer:
	ldi r19, 0x80
	rcall lcd_command
	ldi ZL, LOW(MenuSleep*2)
	ldi ZH, HIGH(MenuSleep*2)
SleepTimer0:
	lpm dat0, z+
	cpi dat0, '0'
	breq SleepTimer1
	rcall lcd_data
	rjmp SleepTimer0
SleepTimer1:
	ldi r19, 0xA8
	rcall lcd_command





	cpi MenuDelay, 0
	breq Return
	rjmp SleepTimer

Return:
	rjmp Home

Overflow0:
	cpi MenuDelay, 0
	breq Overflow0_Out
	dec MenuDelay

Overflow0_Out:
	reti


CG00:
	.db 0x00, 0x04, 0x0A, 0x0A, 0x0A, 0x1F, 0x04, 0x00, 0b00000000, 0b00000100, 0b00001110, 0b00001110, 0b00001110, 0b00011111, 0b00000100, 0b00000000
date:
	.db "FFMoDiMiDoFrSaSo"

status:

	.db "FFFFFFF< off > < on ><sleep>"

MenuSleep:
	.db "Sleep-Timer0"


	.dseg
SW0:				.byte 1
SW0_Times:			.byte 1
SW0_Toggle:			.byte 1
SW0_Delay:			.byte 1
SW0_Count:			.byte 1
SW12_Dir:			.byte 1
SW12_DirSet:		.byte 1