/*
SLdt  240726          Disclaimer: none. Sue me.

ATmega1284: Bootloader & Interrupt: https://www.mikrocontroller.net/topic/569711#new

Bootloaderprogramm zaehlt LEDs auf PORTC 0..3 hoch
Anwenderprogramm laesst LED an PORTD7 blinken

beide Programme springen bei einem bestimmten Zaehlerstand in das jeweils andere

avrasm2
*/

.nolist
.include    "m1284Pdef.inc"
;*******************************************************
.macro  put
.if @0 < $40
    out     @0,@1
.else
    sts     @0,@1
.endif
.endmacro
;----------------------
.macro  puti
    ldi     tmp0,@1
    put     @0,tmp0
.endmacro
;----------------------
.macro  get
.if @1 < $40
    in      @0,@1
.else
    lds     @0,@1
.endif
.endmacro
;*******************************************************
.list

.def    tmp0    = r16
.def    cnt     = r18
.def    tmpi    = r20

.org    $F000
    rjmp        reset

.org    $F000 + OVF1addr
    in      tmpi,SREG
    push    tmpi
    in      tmpi,GPIOR0
    inc     tmpi
    out     GPIOR0,tmpi
    out     PORTC,tmpi
    pop     tmpi
    out     SREG,tmpi
    reti

reset:
    ldi     ZL,0
    ldi     ZH,0
    puti    RAMPZ,0
    lpm     tmp0,z
    cpi     tmp0,$FF
 breq       write
    puti    MCUCR,(1<<IVCE)
    puti    MCUCR,(1<<IVSEL)
    puti    DDRC,$FF
    puti    TIMSK1,(1<<TOIE1)
    puti    TCCR1B,(1<<CS11)                            ; /8

    sei
main_loop:
    in      tmp0,GPIOR0
    cpi     tmp0,11
  brne      main_loop
    cli
    jmp     0
;======================================================

write:
    ldi     ZL,0
    ldi     ZH,0
    ldi     tmp0,(1<<PGERS)
    rcall   do_spm
    ldi     tmp0,(1<<RWWSRE)
    rcall   do_spm

    ldi     cnt,24
    ldi     XL,0
    ldi     XH,0
    ldi     ZL,low (2*Anwendung)
    ldi     ZH,high(2*Anwendung)
spm_loop:
    puti    RAMPZ,1
    elpm    r0,z+
    elpm    r1,z+
    movw    y,z
    movw    z,x
    puti    RAMPZ,0
    ldi     tmp0,0
    rcall do_spm
    movw    z,y
    puti    RAMPZ,1
    adiw    x,2
    dec     cnt
  brne      spm_loop
    ldi     ZL,0
    ldi     ZH,0
    puti    RAMPZ,0
    ldi     tmp0,(1<<PGWRT)
    rcall   do_spm
    ldi     tmp0,(1<<RWWSRE)
    rcall   do_spm

    jmp     0

do_spm:
    ori     tmp0,(1<<SPMEN)
    put     SPMCSR,tmp0
    spm
do_spm_loop:
     get    tmp0,SPMCSR
     sbrc   tmp0,SPMEN
    rjmp    do_spm_loop
    ret

;*******************************************************
Anwendung:
    ldi     cnt,0
    sbi     DDRD,7
loop:
    sbiw    x,1
    rjmp    pc+1
    rjmp    pc+1
   brne     loop
    sbi     PIND,7
    inc     cnt
    cpi     cnt,10
  brne      loop  
    puti    GPIOR0,3

    jmp     0xF000