ADC Mit Atmega48PA

[A. B. (developer_x)]

Sehr geehrtes Forum, ich habe folgendes Tutorial durchgearbeitet :
http://www.mikrocontroller.net/articles/AVR-Tutorial:_ADC

Und habe dementsprechend versucht das ganze umzusetzen.
Ich habe dafür an meinen Pin PC0 eine Spannung über einen drehbaren 
Potentiometer angeschlossen.

Mir ging es bei dem Test ermal darum zu sehen, ob er überhaupt etwas 
misst, die Spannungsberechnung etc wollte ich im folgenden machen.

Hier mein Code

.include "M48PAdef.inc"

; //////////////////////////////////////////////////////////////
;  LCD_COUNTER
;  Kevin Riehl - 01.04.2013
;  
;  Dieses Programm misst die Spannung von einem Spannungsteiler
;  und stellt den ermittelten Wert auf dem Bildschirm dar.
;  
; //////////////////////////////////////////////////////////////
; /////// Defintionen
; //////////////////////////////////////////////////////////////
.DEF STACK_LOW = R16
.DEF STACK_HIG = R17
.DEF OUTPUT    = R22

.DEF NUMBER    = R24

.DEF temp1 = R25
.DEF temp2 = R26

.DEF char1 = R23
.DEF char2 = R28
.DEF char3 = R27

; //////////////////////////////////////////////////////////////
; Stackpointerinitialisierung
  LDI STACK_LOW, LOW(RAMEND)    ;Stackpointer initialisieren
  OUT SPL, STACK_LOW
  LDI STACK_HIG, HIGH(RAMEND)   ;Stackpointer initialisieren
  OUT SPH, STACK_HIG
; //////////////////////////////////////////////////////////////

; LCD Konfigurieren
LDI NUMBER,0
RCALL Wait1000MS
RCALL LCD_INIT

; Willkommen heißen
LDI INFO,'H'
RCALL LCD_DATA
LDI INFO,'A'
RCALL LCD_DATA
LDI INFO,'L'
RCALL LCD_DATA
LDI INFO,'L'
RCALL LCD_DATA
LDI INFO,'O'
RCALL LCD_DATA
LDI INFO,'!'
RCALL LCD_DATA
RCALL WAIT1000MS
RCALL WAIT1000MS

; Messung ADC am Port C0 konfigurieren
LDI R16,0b01000000
STS ADMUX,R16

LDI R16,0b10000011
STS ADCSRA,R16

; Programm Beginnt
RCALL LCD_Home
LDI INFO,'S'
RCALL LCD_DATA
LDI INFO,'T'
RCALL LCD_DATA
LDI INFO,'A'
RCALL LCD_DATA
LDI INFO,'R'
RCALL LCD_DATA
LDI INFO,'T'
RCALL LCD_DATA
LDI INFO,'!'
RCALL LCD_DATA
RCALL WAIT1000MS
RCALL WAIT1000MS
RCALL LCD_CLEAR
main:
  RCALL LCD_Home
  LDS R16,ADCSRA
  SBR R16,ADSC       ;Start Conversion
  STS ADCSRA,R16

  waitconversion:      ; Darauf warten, dass Conversion abgeschlossen
    LDS R16,ADCSRA
    SBRC R16,ADSC   
    RJMP waitconversion

  ; ADC Low Byte ausgeben
  RCALL LCD_LINE1
  LDS NUMBER,ADCL
  RCALL lcd_number

  MOV INFO,char1
  RCALL LCD_DATA

  MOV INFO,char2
  RCALL LCD_DATA

  MOV INFO,char3
  RCALL LCD_DATA

  ; ADC High Byte ausgeben
  RCALL LCD_LINE2
  LDS NUMBER,ADCH
  RCALL lcd_number

  MOV INFO,char1
  RCALL LCD_DATA

  MOV INFO,char2
  RCALL LCD_DATA

  MOV INFO,char3
  RCALL LCD_DATA

  ; WARTEN
  RCALL Wait1000MS

RJMP main      

.include "LCD_Lib.asm"

Problem ist, auf meinem Bildschirm kommt für ADCL und ADCH immer der 
Wert 0 raus, das heißt das ganze misst irgendwie nichts.

Ich habe schon mehrmals das Rädchen gedreht, oder auch mit einem 
Multimeter nachgemessen, das ganze sollte eigentlich laufen.

Seht ihr da zufällig einen Softwarefehler, denn im Hardwarebereich sehe 
ich nach sorgfältigem Prüfen immer noch keinen.

(Beachtet, ich mach das anders als im Tutorial, an einigen Stellen, da 
ich auf ADCSRA und ADCMUX nicht einfach normal zugreifen kann, steht ja 
in der .INC Datei)

Danke für eure Hilfe,
m.f.G. Developer_X

[Sascha W. (sascha-w)]

Hallo,

versuchs mal so ...

  SBR R16,(1<<ADSC)       ;Start Conversion

in ADSC ist nur die Bitnummer gespeichert, sbr verlangt aber eine 
Bitmaske!

Sascha

[A. B. (developer_x)]

Juhu! Danke es klappt, danke schön!
Ich bin ganz entzückt :D