Entprellung im Drehgeber-Beispiel

[Michael H. (mah)]

ich krabble die VHDL-Lernkurve und sehe mir 
http://www.mikrocontroller.net/articles/Drehgeber#Beispielcode_in_VHDL 
an, da steht:

-- Abtastung und Verzoegerung der Quadratursignale

process(clk)
begin
  if rising_edge(clk) then
    a_in  <= A;
    a_old <= a_in;
    b_in  <= B;
    b_old <= b_in;
  end if;
end process;


wenn das sequentiell abläuft, dann ist a_old immer gleich a_in (b_in und 
b_old detto), was die Entprellung funktionslos macht (?)

sollte es nicht heissen:

process(clk)
begin
  if rising_edge(clk) then
    a_old <= a_in;
    a_in  <= A;
    b_old <= b_in;
    b_in  <= B;
  end if;
end process;

-Michael

[Andreas S. (andreas) (Admin)]

Bei Signalen wird die Zuweisung erst am Ende des Prozesses ausgeführt, 
somit ist die Reihenfolge egal.

[Kuckuck (Gast)]

>wenn das sequentiell abläuft

So sollte man das formulieren. Aber was hat das mit VHDL zu tun?

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

> ich krabble die VHDL-Lernkurve
Offenbar kommend aus der Software-Ecke ;-)

Ein paar kleine Worte zu Andreas kompakter Zusammenfassung:
Bei Signalen gibt es im Prozess ein vorher und nachher. Vorher ist 
alles rechts vom Zuweisungspfeil, nachher das Signal links davon. 
Wäahrend des Prozesses behalten alle Signale den Wert von vorher. Am 
Ende des Prozesses (oder beim nächsten wait) werden die berechneten 
Werte zugewiesen.
Sieh dir diesen Code an:

process(clk)
begin
  if rising_edge(clk) then
-- nachher   |  vorher
      a_in  <= B and A;
      b_in  <= B or A;
      a_old <= a_in;
      b_old <= b_in;
      b_in  <= B;
      a_in  <= A;
  end if;
end process;  --- erst hier erfolgt die Zuweisung

Auch mit diesem Code wird die Entprellung problemlos funktionieren, weil 
a_in und b_in immer nur den Wert von A und B zugewiesen wird.

BTW:
Mit Variablen hättest du dein erwartetes sequentielles Verhalten. Aber 
vor du dich jetzt vor Freude überschlägst: du wirst diverse unschöne 
andere Probleme bekommen  :-(

[Selbständiger (Gast)]

Vielleicht sollte man sich mal von der abstrakten Prozessebene lösen und 
einfach mal darlegen, dass "vorher" vor dem FF bedeutet und "nachher" 
hinter dem FF, also ein neues Signal.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

> dass "vorher" vor dem FF bedeutet und "nachher" hinter dem FF
Richtig, ein

  if rising_edge(clk) then

beschreibt ein D-Flipflop, und die ganzen Zuweisungen "vorher" 
beschreiben irgendwelche Logik und/oder Verdrahtung am FF-Eingang. 
"Nachher" ist ganz einfach der FF-Ausgang.

Etwas schwieriger wirds dann schon bei einem kombinatorischen Prozess:

process(A,B)
begin
-- nachher   |  vorher
      a_in  <= B and A;
      b_in  <= B or A;
      b_in  <= B;
      a_in  <= A;
end process;  --- erst hier erfolgt die Zuweisung

hier ist b_in = B und a_in = A.
Allerdings ist dieses Beispiel ziemlich witzlos, weil keinerlei 
Verzögerung oder Speicherung modelliert wird. Dieser Prozess ist 
gleichbedeutend mit diesen Concurrent-Zuweisungen:

   b_in  <= B;
   a_in  <= A;

> Vielleicht sollte man sich mal von der abstrakten Prozessebene lösen
Ich denke schon ganz automatisch "in Hardware", und deshalb war mir 
schon beim Schreiben klar, war "vorher" und "nachher" ist. Aber du hast 
recht, die VHDL als Sprache für die Hardwaresynthese verleitet zu 
abstrakten Ansichten.
In der FPGA-Hardware gibt es (vereinfacht) nur Flipflops und LUTs 
(Logik). Und nur das kann aus einer VHDL-Beschreibung synthetisiert 
werden.