Servo Ansteuerung mit PIC12F675 fehlerhaft

[Stefan (Gast)]

Hallo,
ich versuche schon den ganzen Tag ein Servo mit einem PIC16F675 
anzusteuern. Leider funktioniert es nicht. Beim Einschalten dreht sich 
das Servo auf eine bestimmte Stellung und brummt. Es sieht ganz so aus, 
als würde ich den Timer0 zum generieren des Steuerpulses falsch 
anwenden. Ich kann aber einfach keinen Fehler finden.

Prinzip:
- beim ersten Timer0 Interrupt setze ich die Servoleitung auf high
- der zweite Timer0 Interrupt sollte dann nach 1ms kommen.
- der dritte Timer0 Interrupt sollte nach 0-1ms kommen (je nach 
gewünschter Position), danach setze ich die Servoleitung auf low und 
warte ich 18.5ms und alles beginnt von vorn.

Kann jemand einen Fehler in meinem Code erkennen?

Code zur Initialisierung:

;------------------------------------------------------------------------------
; PROCESSOR DECLARATION
;------------------------------------------------------------------------------
     LIST      P=12F675              ; list directive to define processor
     #INCLUDE <P12F675.INC>          ; processor specific variable definitions  

;------------------------------------------------------------------------------
; CONFIGURATION WORD SETUP
;------------------------------------------------------------------------------
    __CONFIG   _CP_OFF & _CPD_OFF & _BODEN_OFF & _MCLRE_OFF & _WDT_OFF & _PWRTE_ON & _INTRC_OSC_NOCLKOUT 

;------------------------------------------------------------------------------
; VARIABLE DEFINITIONS
;------------------------------------------------------------------------------
; example of using Shared Uninitialized Data Section
INT_VAR     UDATA_SHR   0x20   
W_TEMP      RES     1             ; variable used for context saving 
STATUS_TEMP RES     1             ; variable used for context saving
; für waitwx:
anzmin  RES 1
anzs  RES 1
anzds  RES 1
anzms  RES 1
msconst  RES 1
flags  RES 1
puls  RES  1

;------------------------------------------------------------------------------
; Definitionen:
;------------------------------------------------------------------------------
#define servo     GPIO,5
#define  taster    GPIO,0
#define  rechtsLauf  GPIO,1
#define  wartePulsDauer  flags,0


;------------------------------------------------------------------------------
; EEPROM INITIALIZATION
; The 12F675 has 128 bytes of non-volatile EEPROM, starting at address 0x2100
;------------------------------------------------------------------------------
;DATAEE    CODE  0x2100
;    DE    "MCHP"          ; Place 'M' 'C' 'H' 'P' at address 0,1,2,3


;------------------------------------------------------------------------------
; OSCILLATOR CALIBRATION VALUE
; Internal RC calibration value is placed at location 0x3FF by Microchip as
; a 0xADDLW K instruction, where the K is a literal value to be loaded into 
; the OSCCAL register.  
;------------------------------------------------------------------------------
OSC       CODE    0x03FF

;------------------------------------------------------------------------------
; RESET VECTOR
;------------------------------------------------------------------------------
RESET_VECTOR  CODE    0x0000  ; processor reset vector
        GOTO    INIT         ; go to beginning of program



;------------------------------------------------------------------------------
; INTERRUPT SERVICE ROUTINE
;------------------------------------------------------------------------------
INT_VECTOR    CODE    0x0004  ; interrupt vector location
        MOVWF   W_TEMP        ; save off current W register contents
        MOVF    STATUS,w      ; move status register into W register
        MOVWF   STATUS_TEMP   ; save off contents of STATUS register

; isr code can go here or be located as a call subroutine elsewhere
  btfss  servo
  goto  pulsIsOff
  goto  pulsIsOn  
pulsIsOff
  bsf    OPTION_REG,0 ;prescaler auf 1:4 umschalten
  bcf    OPTION_REG,1 ;prescaler auf 1:4 umschalten
  bcf    OPTION_REG,2 ;prescaler auf 1:4 umschalten  
  bsf    servo
  bsf    wartePulsDauer
  movlw  D'5' ;=255-250, 250=1ms
  movwf  TMR0
  goto  returnFromInterrupt
pulsIsOn
  btfss  wartePulsDauer
  goto  pulsEnde
  movlw  puls
  movwf  TMR0
  bcf    wartePulsDauer
  goto  returnFromInterrupt
pulsEnde
  bcf    servo
  bcf    OPTION_REG,0 ;prescaler auf 1:128 umschalten
  bsf    OPTION_REG,1 ;prescaler auf 1:128 umschalten
  bsf    OPTION_REG,2 ;prescaler auf 1:128 umschalten  
  movlw  D'111'     ;18.5 ms warten (255-x)*128µs
  movwf  TMR0  
  goto  returnFromInterrupt
returnFromInterrupt
  bcf    INTCON,T0IF  ;clear flag
        MOVF    STATUS_TEMP,w ; retrieve copy of STATUS register
        MOVWF   STATUS        ; restore pre-isr STATUS register contents
        SWAPF   W_TEMP,f
        SWAPF   W_TEMP,w      ; restore pre-isr W register contents
        RETFIE                ; return from interrupt




;------------------------------------------------------------------------------
; MAIN PROGRAM
;------------------------------------------------------------------------------
INITIALIZATION     CODE
INIT
;------------------------------------------------------------------------------
; OSCCAL RESTORE (not required if internal OSC is not used)
;------------------------------------------------------------------------------
    errorlevel -302
    BSF     STATUS,RP0    ; set file register bank to 1 
    CALL    0x3FF         ; retrieve factory calibration value
    MOVWF   OSCCAL        ; update register with factory cal value 
    BCF     STATUS,RP0    ; set file register bank to 0
    errorlevel +302


;------------------------------------------------------------------------------
; Pin I/O, pull ups und timer0:
;------------------------------------------------------------------------------
  bcf    STATUS,RP0  ;Bank 0
  clrf  GPIO    ;Init GPIO, alle low
  movlw  B'00000111' ;Comparators off
  movwf  CMCON    ;Comparators off
  bsf    STATUS,RP0  ;Bank 1
  clrf  ANSEL    ;AD Off --> digital IO
  movlw  B'00000011' ;alle output außer GP0 und GP1;
  movwf  TRISIO
  clrwdt
  movlw  B'01010001'; pull-ups on, Timer 0 internal clock, prescaler für timer0 auf 1:4
  movwf  OPTION_REG  
  bcf    STATUS,RP0  ;Bank 0
  clrf  TMR0    ;clear Timer0
  clrf  GPIO    ;Init GPIO, alle low
  movlw  D'128'    ; Servomittelstellung
  movwf  puls
  bsf    INTCON,T0IE ;Timer0 Interpt enabled
  bsf    INTCON,GIE  ;Enable interupts
  

;------------------------------------------------------------------------------
; Main Program
;------------------------------------------------------------------------------
Main
  
  movlw  D'10'    
  movwf  puls
  movlw  D'10'
  call  waitwds

  movlw  D'128'    
  movwf  puls
  movlw  D'10'
  call  waitwds


  movlw  D'230'    
  movwf  puls
  movlw  D'10'
  call  waitwds

  movlw  D'128'    
  movwf  puls
  movlw  D'10'
  call  waitwds

  goto  Main

[Stefan (Gast)]

habe den/die Fehler endlich gefunden.
Fehler, der das brummen verursacht hat:
Für den Zugriff auf das OPTION_REG muss auf Bank 1 umgeschaltet werden

Fehler, der dazu führte, das das Servo immer die gleiche Stellung 
einnahm:
"movlw puls" muss zu "movf puls,w" geändert werden.

Jetzt funktioniert alles!
Sorry wegen des unnötigen Threads.

[CHW311 (Gast)]

HiHo,
schön das du den Fehler gefunden hast. Nachdem ich gerad ebenfalls mit 
dem Pic12... schaffe dachte ich stellst die Frage mal hier. ;)

Programmier mit dem HiTech C Compiler in MP-Lab und bekomme immer diese 
Fehlermeldung:

Programming...
The following memory regions failed to program correctly:
Program Memory
Address: 000003d3 Expected Value: 0000302c Received Value: 00003000
Programming failed

Kann mir einer sagen wo das her kommt. Verblüffender Weiße funktioniert 
die Programmierung einmal und dann ists vorbei. Zunächst dachte ich 
irgendwo nen Kurzschluss zu haben der mir die Pics krachen lässt sobald 
das Programm los läuft. Aber rein mit Prog. Interface selbes Problem.

Irgendwelche Ideen?

[CHW311 (Gast)]

Ebenfalls Fehler gefunden. Externe Spannungsquelle ran PicKit Versorgung 
aus und es Funktioniert...