8051, lcd anzeige verschiebt sich

[Helge K. (kind_nr_5)]

heyho,

Ich hab mich grade erst in dem forum angemeldet, kann sein das ich in 
der falschen abteilung bin. Wenn ja wäre es schön wen man mir das 
mitteilt.

Also ich benutze ein 8051 controller und ein LCD-Display LTN 214 R-10. 
Das display ist an P0 angeschlossen. Das ganze ist auf so einer Art 
Test-board wo alles mögliche noch dran angeschlossen ist. Das hab ich so 
von meinem Lehrer in die Hand gedrückt bekommen.
Zum hex-datei erstellen benutz ich keil und zum draufspielen 8051win.
Falls sont noch wichtige Informationen fehlen bitte fragen.

Ich muss für die Schule eine Art Fahrahdcomputer erstellen. Ich hab bis 
jetzt eine Art Grundgerüst geschrieben und mich dann an der LCD-Anzeige 
versucht. Dazu hab ich eine Datei mit Unterprogrammen bekommen die mein 
Lehrer geschrieben hat:

;***** Vor der Verwendung initialisieren mit lcall initLCD   **************
;***** veränderte Register: r2 bis r7 der Registerbank 1              *****
;***** daher Stack hinter den Bitadressierbaren Bereich: mov sp,#2fh  *****
;***** Übergaberegister ist der Akku                         **************

;include reg_51.pdf  ;Registeradressen einbinden
  
LCD_ROUTINES  SEGMENT  CODE  ;Name für das folgende relative Codesegment

  RSEG  LCD_ROUTINES     ;relatives Segment, wird vom Linker hinter anderes Codesegment gehängt  

LCD_PORT EQU P0 ; *** Hier den verwendeten Port einsetzen !!!!!!!!!!!! ****

public initLCD,loeschzeile1,loeschzeile2,textzeile1,textzeile2,cursorpos,textaus,zifferaus, hexaus, dezaus, loeschen


;----   Verwendung der Hilfsprogramme: ------------------------------------
;  lcall  initLCD    ;Initialiserung des LCD-Displays
;  lcall  loeschen  ;gesamtes Diplay löschen
;  lcall  loeschzeile1  ;nur Zeile 1 des Displays löschen
;  lcall  loeschzeile2  ;nur Zeile 2 des Displays löschen

;***  Die 16 Zeichen belegen die Display-Adressen 00h-0Fh (Zeile1) und 40h-4Fh (Zeile2)
;  mov  a,#03    ;Cursor auf die 4. Anzeigestelle setzen
;  lcall  cursorpos

;***  Textausgaben ************* die Anfangsadresse des Textes muß ***********
;***  im DPTR stehen und der Text muß mit einer 0 abgeschlossen werden!  *****
;  mov  dptr,#Text1  ;Text ab der
;  lcall  textaus    ;aktuellen Cursorposition ausgeben
;  mov  dptr,#Text1  ;Text ab der 1.Stelle
;  lcall  textzeile1  ;in Zeile 1 ausgeben
;  mov  dptr,#Text1  ;Text ab der 1.Stelle
;  lcall  textzeile2  ;in Zeile 2 ausgeben
;Text1:  db 'Hallo! Test...',0  ;Angabe des auszugebenden Textes am Programmende

;***  Zahlenausgaben: Übergaberegister ist der Akku *******************************************
;  mov  a,p1    ;Ausgabe des Portinhalts von P1
;  lcall  zifferaus  ;mit nur einer Ziffer (Lownibbel) an das Display
;  mov  a,p1    ;Ausgabe des Portinhalts von P1 als 2-stellige Hexzahl 
;  lcall  hexaus    ;Es werden immer 2 Stellen mit führenden Nullen ausgegeben
;  mov  a,p1    ;Ausgabe des Portinhalts von P1 als 3-stellige Dezimalzahl     
;  lcall  dezaus    ;Es werden immer 3 Stellen ausgegeben, führende Nullen sind dunkel
;  mov  a,p1    ;Ausgabe des Portinhalts von P1 als 8-Bit-Dualzahl
;  lcall  dualaus    ;Es werden immer 8 Stellen ausgegeben mit führenden Nullen
;  mov  a,p1    ;Ausgabe des Portinhalts von P1 als 8-Bit-Dualzahl
;  lcall  dualaus1  ;rechtsbündig in Zeile1
;  mov  a,p1    ;Ausgabe des Portinhalts von P1 als 8-Bit-Dualzahl
;  lcall  dualaus2  ;rechtsbündig in Zeile2

;***  Anwendungsbeispiele siehe Datei LCDTEST.asm *******************************  



;****** Definitionen / Abkürzungen ************************************************
  reg2  EQU  0Ah  ;Register der Bank1
  reg3  EQU  0Bh
  reg4  EQU  0Ch
  reg5  EQU  0Dh
  reg6  EQU  0Eh
  reg7  EQU  0Fh

; **************** Display initialisieren ****************
;
; Display arbeitet im 2*4-Bit Modus
; 
; Die 16 Zeichen belegen die Display-Adressen 00-0F und 40-4F (HEX!)
;
; Bit:    7       6       5       4       3       2      1      0
;      Register  Read/    0      Takt   D7/D3   D6/D2  D5/D1  D4/D0
;      Select    Write

initLCD:  mov   LCD_PORT,#00010011b     ;aufwecken! Takt=1
    mov   LCD_PORT,#00000011b  ;           Takt=0

    mov   reg5,#10            ; ca. 5 msec warten     
w0:         djnz   reg4,w0
    djnz   reg5,w0

    mov   LCD_PORT,#00010011b    ;aufwecken! Takt=1
    mov   LCD_PORT,#00000011b  ;           Takt=0
w2:    djnz   reg5,w2             ; wartet 100 usec

    mov   LCD_PORT,#00010011b     ;aufwecken! Takt=1
    mov   LCD_PORT,#00000011b  ;           Takt=0
w3:    djnz   reg5,w3      ; wartet 100 usec

    mov   LCD_PORT,#00010010b     ;8->4  BITS UMSCHALTEN, Takt=1
    mov   LCD_PORT,#00000010b  ;                       Takt=0
w4:    djnz   reg5,w4
    
    mov   A,#00101000b      ;Function set 4 bits  
    lcall   LCDbefehl    ;Ausgabe im 4Bit-Modus
    
    mov   A,#00001100b      ; Display AN, Cursor AUS
    lcall   LCDbefehl    ;des Zeichens an der Cursorposition

    mov   A,#00000110b      ; Not Shifted Display, Increment
    lcall   LCDbefehl
    ret

;*********** Loeschen Display *****************************************
loeschen:  mov   A,#00000001b      ;Display clear
    lcall   LCDbefehl
    ret  
;*********** Cursor AN ************************************************
cursorAN:  mov   A,#00001110b    ;Cursor und Display AN
    lcall   LCDbefehl
    ret
;*********** Cursor AUS ***********************************************
cursorAUS:  mov   A,#00001100b    ;Cursor AUS, Display AN
    lcall   LCDbefehl
    ret

;*********** Cursorposition *******************************************
cursorpos:    orl   a,#10000000b    ;Kennung für DD RAM address set
    lcall   LCDbefehl
    ret
;*********** Cursorhome ***********************************************
cursorhome:  mov   A,#00000010b    ;Cursor home
    lcall   LCDbefehl
    ret
      
;*********** Zeile 1 löschen ******************************************
loeschzeile1:  mov   A,#00000010b    ;Cursor home
    lcall   LCDbefehl
    mov   dptr,#textloesch
    lcall   textzeile1
    mov   A,#00000010b    ;Cursor home
    lcall   LCDbefehl
    ret
textloesch:  DB '                ',0        

;*********** Zeile 2 löschen ******************************************
loeschzeile2:  mov   a,#40h
    lcall   cursorpos    ;Cursor auf Position 1.Stelle/2.Zeile
    mov   dptr,#textloesch
    lcall   textzeile2
    mov   a,#40h
    lcall   cursorpos    ;Cursor auf Position 1.Stelle/2.Zeile
    ret
    
;*********** Text an Zeile 1 ausgeben *********************************
textzeile1:  mov   A,#00000010b    ;Cursor home
      lcall   LCDbefehl
textaus:  mov   reg4,#0      ;0 ins r4 => Buchstabe 0
textloop:    mov   A,reg4      ;Nr des Buchstabens in den Akku
      inc   reg4
      cjne   a,#10h,holbuchst  ;schon Maximalzahl an Buchstaben?
      sjmp   textende    ;für eine Zeile => ja => Ende
holbuchst:  movc   A,@A+DPTR    ;Text Buchstabenweise holen
      jz     textende    ;falls 0 => Ende, sonst ausgeben
ausgeben:  lcall   LCDtext
      sjmp   textloop
textende:    ret

;*********** Text an Zeile 2 ausgeben *********************************
textzeile2:  mov   a,#40h
    lcall   cursorpos    ;Cursor auf 1.Stelle/2.Zeile
    sjmp   textaus

;********* Textaus (Text ab momentaner Cursorposition ausgeben **********
;textaus:  mov   a,#0
;    movc   a,@a+dptr    ;Text zeichenweise holen
;    jz   textend      ;Ende wenn Ordnungszahl des zeichens=0
;    lcall   LCDtext
;    inc   dptr      ;nächstes zeichen
;    sjmp   textaus
;textend:  ret

;********* Befehl fr LCD-Display im Akku ausgeben an LCD_PORT **************
;*************** RS  R/W  D7  D6  D5  D4  D3  D2  D1  D0
;*************** 0    0   x   x   x   x   x   x   x   x
LCDbefehl:  push   ACC
    swap   a      ;High- und Low-Nibbel tauschen
    anl   A,#00001111b    ;4 Bits maskieren
    orl   A,#00010000b    ;Übergabetakt = 1, High-Nibbel senden
    mov   LCD_PORT,A
    anl   A,#00001111b    ;Takt = 0
    mov   LCD_PORT,A
    pop   ACC
    anl   A,#00001111b    ;Low-Nibble
    orl   A,#00010000b    ;Takt = 1
    mov   LCD_PORT,A
    anl   A,#00001111b    ;Takt = 0
    mov   LCD_PORT,A
    sjmp   wbusy      ;warten bis Bearbeitung beendet

;********* Text fr LCD-Display im Akku ausgeben an LCD_PORT **************
;*************** RS  R/W  D7  D6  D5  D4  D3  D2  D1  D0
;*************** 1    0   x   x   x   x   x   x   x   x
LCDtext:push   ACC
    swap   a      ;Nibbel vertauschen
    anl   A,#00001111b    ;4 Bits maskieren
    orl   A,#10010000b    ;Übergabetakt = 1, RS = 1 (Befehl!)
    mov   LCD_PORT,A
    anl   A,#10001111b    ;Takt = 0
    mov   LCD_PORT,A
    pop   ACC
    anl   A,#00001111b    ;Low-Nibble
    orl   A,#10010000b    ;Takt = 1, RS = 1
    mov   LCD_PORT,A
    anl   A,#10001111b    ;Takt = 0
    mov  LCD_PORT,A
  ;************** warten bis Bearbeitung im Display beendet **********
wbusy:    mov   LCD_PORT,#01011111b    ; Busy lesen, Takt=1, RS = 0
    mov   A,LCD_PORT              ; und holen
    mov   LCD_PORT,#01001111b     ;             Takt=0
    nop
    mov   LCD_PORT,#01011111b     ; Low-Byte holen (ohne Bedeutung)
    mov   LCD_PORT,#01001111b

    mov   reg2,50                  ;Zeitverzögerung 1ms
warteR2:  mov   reg3,#10                 ;statt auf busy warten
warteR3:  djnz   reg3,warteR3            ;wenn LCD an p0
    djnz   reg2,warteR2    
  
;    jb   ACC.3,wbusy       ; Busy? warten , geht nicht mit LCD an p0
    ret 

;*********************** dezaus *********************************************
;+++++++++ Die Zahl im Akku wird als Dezimalzahl ausgegeben +++++++++++++++++
;--------- Es werden immer 3 Stellen ausgegeben, führende Nullen sind dunkel 
dezaus:    
  push  acc
  mov   b,#100          ;der in A stehende Wert wird durch 100
  div   ab          ;geteilt und die Hunderter-Ziffer in
  mov   reg7,a          ;r7 gegeben
  mov   a,b          ;die verbleibende Zehnerzahl
  mov   b,#10          ;wird durch 10
  div   ab          ;geteilt
  swap   a          ;Die Zehnerziffer wird das High-Nibbel,
  add   a,b          ;die Einerziffer das Low-Nibbel
  mov   reg5,a          ;diese BCD-Zahl wird in r5 gespeichert        
  mov   a,reg7            ;die vorderste BCD-Ziffer
  mov   reg4,a    ;wird in r4 gesichert und
  jnz   ausg1    ;wird normal ausgegeben, falls sie nicht 0 ist
  mov   a,#31    ;leere Anzeige
  lcall   lcdtext    ;falls null
  sjmp   Ziff2
ausg1:  lcall sendascii    ;1.Ziffer ausgeben
Ziff2:  mov a,reg5     ;2. u. 3. Ziffer zurückholen
hex0:   mov reg7,a     ;zwischenspeichern in r7
  anl a,#0f0h    ;High-Nibbel maskieren
  swap a      ;und zur Ziffer im Low-Nibbel machen
  jnz ausg2    ;wird normal ausgegeben, falls sie nicht 0 ist
  cjne a,reg4,ausg2  ;nur 0 unterdrücken falls 1.Ziffer auch 0 war
  mov a,#31    ;leere Anzeige
  lcall lcdtext    ;falls null
  sjmp Ziff3
ausg2:  lcall sendascii    ;2.Ziffer ausgeben
Ziff3:  mov a,reg7    ;Zwischengespeicherte Zahl zurck
  anl a,#0fh    ;Low-Nibbel ausblenden
  lcall sendascii    ;und ausgeben
dezend:  pop acc
  ret

;*********************** hexaus *****************************************
;+++++++++ Die Zahl im Akku wird hexadezimal ausgegeben +++++++++++++++++
;--------- Es werden immer 2 Stellen mit führenden Nullen ausgegeben ---- 
hexaus:  push acc
  mov   reg7,a    ;zwischenspeichern in r7
  anl   a,#0f0h    ;High-Nibbel maskieren
  swap   a    ;und zur Ziffer im Low-Nibbel machen
;  cjne   a,#0,ausg2Z  ;zur Unterdrückung der führenden Null   
;  mov   a,#20    ;leere Anzeige
;  lcall   lcdtext    ;       
;  sjmp   weit2    ;
ausg2Z:  lcall   sendascii        ;
weit2:  mov   a,reg7    ;Zwischengespeicherte Zahl zurck
  anl   a,#0fh    ;Low-Nibbel ausblenden
  lcall   sendascii  ;und ausgeben
  pop   acc
  ret

;****************** dualaus (Zahl im Akku als 8-Bit-Dualzahl ausgeben) ********
dualaus:
  push  acc
  mov  reg5,#8    ;Zähler
dloop:  mov  reg7,a    ;Zahl zwischenspeichern
  jb  acc.7,d1  ;Sprung zur "1"-Ausgabe wenn Bit=1
  mov  a,#0    ;Null ausgeben
  lcall  sendascii  ;
  sjmp  d2    ;
d1:  mov  a,#1    ;Eins ausgeben
  lcall  sendascii  ;
d2:  mov  a,reg7    ;zwischengespeicherte Zahl zurück
  rl  a    ;nächstes Bit
  djnz  reg5,dloop  ;von vorne falls noch nicht alle 8 Bit
  pop  acc
  ret

;***************** Duale Ausgabe rechtsbündig in Zeile 1 *********************
dualaus1:
  push  acc
  mov  a,#08
  lcall  cursorpos
  pop  acc
  lcall  dualaus
  ret
;***************** Duale Ausgabe rechtsbündig in Zeile 2 *********************
dualaus2:
  push  acc
  mov  a,#48
  lcall  cursorpos
  pop  acc
  lcall  dualaus
  ret

;************** sendascii (1 Hexziffer als Ascii-Zeichen senden) *********
sendascii: 
  mov   reg6,a
  subb   a,#0Ah
  mov   a,reg6
  jc   zahl
Buchst:  add   a,#37h
  sjmp   weit1
zahl:  clr   c             ;Carry zurcksetzen, sonst Fehler bei add
  add   a,#30h
weit1:  lcall   LCDtext
  ret

;*************** zifferaus (eine Ziffer 0 bis 9 ausgeben *****************
zifferaus: 
  push   acc
  anl   a,#0Fh
  lcall   sendascii                      
  pop   acc
  ret

;****** PIN-Belegung für LCD-Display LTN 214 R-10 am LCD_PORT **************
; * Uebertragung eines Bytes als 2 * 4 Bits.
; * Ansicht von oben auf Display
; * 1 GND--------------------------------------------------> GND
; * 2 +5Volt-----------------------------------------------> +5V
; * 3 V0: Steuerspannung Kontrast 0..5 Volt erlaubt,-------> V0 
; *       Arbeitspunkt ca. 0.6 V (am besten Spindeltrimmer zum Einst.)
; * 4 RS: Registersatz (Display oder Befehl)---------------> LCD_PORT.7
; * 5 R/W: Schreiben oder lesen----------------------------> LCD_PORT.6
; * 6 E: Uebergabetakt-------------------------------------> LCD_PORT.4
; * 7-10: frei (eigentlich D0 - D3, wird aber nicht verwendet)
; * 11: D4/D0----------------------------------------------> LCD_PORT.0
; * 12: D5/D1----------------------------------------------> LCD_PORT.1
; * 13: D6/D2----------------------------------------------> LCD_PORT.2
; * 14: D7/D3----------------------------------------------> LCD_PORT.3
; *******************************************************

END

Dieses hab ich geschrieben:

;-------------------------------------------------------------------------------------------------------------
;----------------------------- Projekt Fahradcomputer von Helge und Yannik -----------------------------------
;-------------------------------------------------------------------------------------------------------------





EXTRN Code (initLCD,loeschzeile1,loeschzeile2,textzeile1,textzeile2,cursorpos,textaus,zifferaus,hexaus,dezaus,loeschen,charaus)




;-------------------------------------------------------------------------------------------------------------
;--------- Definitionen --------------------------------------------------------------------------------------
  re0          EQU    r0
  re1          EQU    r1   
  modus        EQU    r2    ;Anzeigemodus (0 = Geschwindigkeit, 1 =  Durchschnittsgeschwindigkeit,
                    ;        2 = Tageskilometer, 3 = Tagesfahrzeit)
  timerzaehler0    EQU    r3    ;Timer-Zähler (in 10 ms)  für radumdrehung
  timerspeicher    EQU    r4    ;Timer-Speicher (in 10 ms)
  geschwindigkeit    EQU    r5    ;momentane Geschwindigkeit (in KM/h)
  durchschnitt    EQU    r6    ;durchschnittliche Geschwindigkeit (in KM/h)
  fahrzeit0      EQU    r7    ;Tagesfahrzeit (in s)
  fahrzeit1      EQU    10h    
  streckenk      EQU    11h    ;Tagesstrecke (in m)
  strecke0      EQU    12h
  strecke1      EQU    13h
  strecke2      EQU    14h
  timerzaehler1    EQU    15h    ;Timer-Zähler (in 10 ms) für Tagesfahrzeit
  re14        EQU    16h
  re15        EQU    17h  
;-------------------------------------------------------------------------------------------------------------



    cseg at 0
    jmp   init










;-------------------------------------------------------------------------------------------------------------
;--------- Interrupt Aufrufe ---------------------------------------------------------------------------------
    org    0x0003
    call  intrad
    reti  

    org    0x000b
    call  inttimer
    reti

    org    0x0013
    call  intknopf
    reti
;-------------------------------------------------------------------------------------------------------------



;-------------------------------------------------------------------------------------------------------------
;--------- Interrut Rad --------------------------------------------------------------------------------------
intrad:    ;mov    a,04h
      ;lcall  cursorpos
      ;mov    a,modus
      ;lcall  dezaus  
      
      ret
;-------------------------------------------------------------------------------------------------------------


;-------------------------------------------------------------------------------------------------------------
;--------- Interrupt Knopf -----------------------------------------------------------------------------------
intknopf:  inc    modus
      cjne  modus,#4d,endeknopf  
      mov    modus,#0d
endeknopf:  ret
;-------------------------------------------------------------------------------------------------------------

  
;-------------------------------------------------------------------------------------------------------------
;--------- Interrupt Timer -----------------------------------------------------------------------------------
inttimer:  mov   TL0,#0xF0    
      mov   TH0,#0xD8

      inc    timerzaehler0
      inc    timerzaehler1
      push  acc
      mov    a,timerzaehler1        ;nach 1 sec fahrzeit erhöhen
      cjne  a,#100,endtimer  
      mov    timerzaehler1,00h
      clr    cy
      inc    fahrzeit0
      jnc    endtimer
      inc    fahrzeit1           ;falls fahrzeit0 voll dann fahrzeit1 erhöhen
endtimer:   pop    acc
      ret
;-------------------------------------------------------------------------------------------------------------










;-------------------------------------------------------------------------------------------------------------
;--------- Intitialisierung ----------------------------------------------------------------------------------
init:    mov    sp,18h      ;Stack aus benutzten Registern raus
    
      lcall  initlcd      ;Display initialisieren
      lcall   loeschzeile1
      lcall   loeschzeile2
  
      setb   et0        ;timer initialisieren
      mov   TMOD,#00000001b  
      mov   TL0,#0xF0    
      mov   TH0,#0xD8
      mov   TCON,#00010000b  
      
      setb   IT0        ;externer Interrupt 0 (Rad) initialisieren
      clr    IE0
      setb   EX0    

      setb   IT1        ;externer Interrupt 1 (Knopf) initialisieren
      clr    IE1
      setb   EX1
           
      mov    re0,#00h    ;alle Register initialiesieren  
      mov    re1,#00h          
      mov    modus,#00h
      mov    timerzaehler0,#00h
      mov    timerspeicher,#00h
      mov    geschwindigkeit,#00h
      mov    durchschnitt,#00h
      mov    fahrzeit0,#00h
      mov    fahrzeit1,#00h
      mov    streckenk,#00h
      mov    strecke0,#00h
      mov    strecke1,#00h
      mov    strecke2,#00h
      mov    timerzaehler1,#00h
      mov    re14,#00h
      mov    re15,#00h
      
      setb  ea        ;alle Interrupts freigeben        
;-------------------------------------------------------------------------------------------------------------










;-------------------------------------------------------------------------------------------------------------
;--------- Hauptschleife -------------------------------------------------------------------------------------
main:  lcall   loeschzeile1
    lcall   loeschzeile2

    mov     dptr,#textm0
    lcall   textzeile1
    mov    re1,00h
    lcall   wait
    jmp    main

;-------------------------------------------------------------------------------------------------------------









;-------------------------------------------------------------------------------------------------------------
;--------- Texte ---------------------------------------------------------------------------------------------
textm0:  db  'Geschwindigkeit:',0  
textm1:  db  'Durchschnitt:   ',0
textm2:  db  'Tageskilometer: ',0
textm3:  db  'Tagesfahrzeit:  ',0

;-------------------------------------------------------------------------------------------------------------








;-------------------------------------------------------------------------------------------------------------
;--------- wait ----------------------------------------------------------------------------------------------
wait:    mov    re15, #30              
wait2:    mov    re14, #10
wait1:    mov    re1,  #10
wait0:    djnz  re1, wait0      
      djnz  re14, wait1
      djnz  re15, wait2
      djnz  re0, wait  
      ret 
;-------------------------------------------------------------------------------------------------------------
end

Das wollte ich erreichen:
In der ersten Zeile des LCD wird "Geschwindigkeit:" ausgegeben

Das passiert:
es wir mal "Geschwindigkeit" mal "eschwindigkeit" mal "schwindigkeit" 
mal "windigkeit" und so weiter ausgegeben.


wäre echt cool wenn sich irgendjemand die mühe machen würde mir zu 
helfen, ich sitz schon seit über 1,5 tagen davor und komm kein 
millimeter weiter =(

LG Helge

[holger (Gast)]

Füge hinter dieser Stelle

    mov   A,#00000110b      ; Not Shifted Display, Increment
    lcall   LCDbefehl

mal ein

    mov   A,#00010100b
    lcall   LCDbefehl

an.

[Helge K. (kind_nr_5)]

danke für die antwort, es ändert sich leider nichts =(

[holger (Gast)]

>danke für die antwort, es ändert sich leider nichts =(

Dann stimmt evtl. was mit dem LCD Timing nicht.

[Helge K. (kind_nr_5)]

okay, wie finde ich raus, wie das timing sein muss?

edit: kann eigentlich fast nicht sein, da wenn ich statt meinem 
hauptprogramm das testprogramm von meinem lehrer einbinde tuts und das 
arbeitet ja mit den gleichen operationen.

testprogramm:

;lcdtest.a51****************************************************************************
;******** Testprogramm: Aufwärtszähler sichtbar an 8LEDs und als Hexziffer im LC-Display
;***************************************************************************************
; lcd8252.a51 verwenden

EXTRN Code (initLCD,loeschzeile1,loeschzeile2,textzeile1,textzeile2,cursorpos,textaus,zifferaus,hexaus,dezaus)

;******************** Deklarationen *******************************************
  LCDPosHex  EQU 0Eh    ;Position der Hex-Zahl im Display
  LCDPosDez  EQU 4Dh    ;Position der Dez-Zahl im Display
  LEDs    EQU p2    ;LEDs an P2
  
;******************** Programm ************************************************
          cseg at 0
    ljmp   go      ;Das eigentliche Programm beginnt hinter
            ;den Interrupt-Einsprung-Adressen

;*********** Interrupt-Service-Routine ********************************************
    org 000Bh      ;Interrupt-Einsprung
ISRtimer0:   
    mov  R0, DPL
    mov  R4, DPH
    inc  R2              ;Inhalt Port2 um 1 erhöhen
    cjne  R2, #3, next
    mov  R2, #0    

    mov  A, R3
    rl  A
    mov  LEDs, A
    mov  R3, A
    
next:    reti

;******* Initialisierung **********************************************************
go:    mov   TMOD,#00000001b  ;Timer in Modus 1, Timer-Betrieb, 16Bit-Zähler
    mov   TL0,#0x00    ;Anfangswert Zählregister=> 65536-10000 = 55536 = D8F0h
    mov   TH0,#0x00    ;D8F0 ist Nachladewert für 10000µs Zählzeit
    mov   TCON,#00010000b  ;Timer-Run-Bit Timer0 setzen => Timer0 starten
    mov   IP,#0      ;alle Interrupts haben gleiche Priorität
    setb   EA      ;Interrupts freigeben (IEN0.7)
    setb   ET0      ;Enable Timer0 Interrupt (IEN0.1)
    
    mov     sp,#2fh    ;Stackpointer oberhalb Bitadressierbarer Bereich
    lcall  initlcd    ;Display initialisieren
  
    mov  R2,#0    ;Interruptzähler auf null setzen
    mov  R3,#1
    mov  LEDs, #0x00
    mov  DPTR, #seg7code

;******** Hauptprogramm  ***********************************************************

  
  
start:  lcall   loeschzeile1
  lcall   loeschzeile2

  mov   dptr,#Text1
  lcall   textzeile1
  mov  R1, 0
  lcall   Zeit
  
  mov   dptr,#Text2
  lcall   textzeile2
  mov  R1, 0
  lcall   Zeit

  lcall   loeschzeile1
  lcall   loeschzeile2

  mov   dptr,#Text3
  lcall   textzeile1
  mov  R1, 0
  lcall   Zeit

  mov   dptr,#Text4
  lcall   textzeile2
  mov  R1, 0
  lcall   Zeit

  jmp   start


;********** Zeitverzögerung **************************************************************************
; R1 als Übergabe-Schleifenzähler
  
Zeit:    mov  R7, #30              ;ca. 0.5s
Zeit2:    mov  R6, #10
Zeit1:    mov  R5, #10
Zeit0:    djnz  R5, Zeit0      
      djnz  R6, Zeit1
      djnz  R7, Zeit2
      djnz  R1, Zeit  
      ret 


;************************ Texte *******************************************************
Text1:  db '   Herzlich ',0
Text2:  db '  Willkommen!',0
Text3:  db ' Technisches',0
Text4:  db '  Gymnasium',0


seg7code:  
  db 0x04
  db 0x08
  db 0x40
  db 0x20
  db 0x10
  db 0x02

END