ASM: Rücksprung aus Funktion fehlerhaft (Mega32)

[Thomas B. (nichtessbar)]

Hallo,

ich denke dass ich einfach irgendwas übersehe, aber ich suche jetzt 
schon ein paar Stunden und finde den Fehler nicht darum möcht ich gern 
jemand Außenstehenden um Hilfe fragen.

Folgendes Problem:
Unten geposteter Code soll irgendwann mal ein Bootloader werden, 
momentan versuche ich einfach eine Echoschleife für die USART zu machen 
(als Test).

Wenn ich jetzt die Funktion init_uart aufrufe mittels rcall wird diese 
ausgeführt und dann springt der PC irgendwohin im Speicher bis der 
Prozessor dann wieder resettet und von vorn anfängt. Verhalten konnte 
mit AVR Sim und alternativ JTAGICE direkt am Prozessor beobachtet 
werden. Schreibe ich die richtige Rücksprungadresse manuell beim 
Debuggen in den Speicher, auf den der Stackpointer zeigt, läuft das 
Programm tadellos (auch Interruptabarbeitung etc. funktioniert).

Stackpointer hat beim Programmstart den Wert 0x0000 und wenn dann zwei 
weggezählt (wg. 2 Byte PC am Stack ablegen, siehe AVR-ISM rcall) werden 
kommt natürlich ein Überlauf (dann zeigt er auf 0x0ffe) - das ist das 
einzige was mir derzeit komisch erscheint?

/*
 * assBootloader.asm
 *
 *  Created: 28.01.2012 19:52:00
 *   Author: tbergmueller
 */ 

 .include "m32def.inc"

  .def    mp=R16    
  .equ    INT_TAB_LENGTH=100                    ; Länge der Interrupttabelle (für Tests mal lang genug...)
  .equ    APP_STARTADDR=0                      ; Start der Applikation, 0 wegen Debugmöglichkeit, später dann 0x03f00
  .equ    BOOTLOADER_STARTADDR=APP_STARTADDR+INT_TAB_LENGTH    ; start der Eigentlichen Bootloadersoftware
   

 .cseg

 .org APP_STARTADDR
      rjmp  main      ; reset handler
 .org URXCaddr+APP_STARTADDR
      rjmp  recByte      ; RXC Handler



;.org BOOTLOADER_STARTADDR

main:    ;call  Move_interrupts  
      rcall  init_uart

      ; Testweise 8 LED an Port einschalten
      ldi    mp, 0xff
      out    DDRA, mp
      ldi    mp, 0
      out    PORTA, mp

loop:    rjmp  loop          ; endlosschleife
      jmp    0            ; start normal (später für Bootloader)



; ################### FUNCTIONS
init_uart:  ldi    mp, 0x98        ; load registers
      out    UCSRB, mp        ; RXIE enabled, RXEN, TXEN      test
      ldi    mp, 103          ; load ubrrl
      out    UBRRL, mp
      sei  
      ret

; Interrupthandler RXC
recByte:  in    mp, UDR
      call  USART_Transmit

      reti

; Senden via USART
USART_Transmit:
      sbis  UCSRA,UDRE
      rjmp  USART_Transmit

      out    UDR,mp
      ret

; Interrupts in den Bootloaderbereich verschieben
Move_interrupts:      
      ; Enable change of interrupt vectors
      ldi    mp, (1<<IVCE)
      out    GICR, mp
      ; Move interrupts to boot Flash section
      ldi    mp, (1<<IVSEL)
      out    GICR, mp
      ret

Vielen Dank schonmal für die Hilfe und ich mir ist der vermutlich extrem 
dumme Fehler jetzt schon peinlich...

Thomas

[MWS (Gast)]

Du hast schon mal davon gehört, dass man den SP initialisieren muss ?

[spess53 (Gast)]

Hi

Beim ATMega32 musst du den Stackpointer initialisieren:

  
  ldi r16,high(RAMEND)
  out SPH,r16
  ldi r16,Low(RAMEND)
  out SPL,r16

MfG spess

[Thomas B. (nichtessbar)]

Wusst ich's doch dass es ein peinlicher Fehler ist...

Dankeschön für die rasche Hilfe! Muss zugeben, hab Assembler das letzte 
Mal glaub ich vor 5 Jahren benutzt und das am 8051, da war wurde 
StackPtr per default initialisiert, soweit hab ich nicht gedacht.

[spess53 (Gast)]

Hi

>...und das am 8051, da war wurde
>StackPtr per default initialisiert, soweit hab ich nicht gedacht.

Ist bei neueren AVR auch so. Der ATMega32 ist halt schon ein 
Dinosaurier.

MfG Spess

[Thomas B. (nichtessbar)]

War der einzige den ich in DIL-Bauform zuhause hatte und am Steckbrett 
is doch am Einfachsten JTAG anzuschließen für ein paar schnelle Tests ;)

Aber auf alle Fälle gut zu wissen dass es Controller gibt die das nicht 
selbst machen.

[oldmax (Gast)]

Hi
Auch wenn es vielleicht jetzt noch nicht zum tragen kommt, aber ich würd 
die ISR so nicht stehen lassen...

; Interrupthandler RXC
recByte:  in    mp, UDR
      call  USART_Transmit

      reti

In einer ISR macht es Sinn, grad bei Assembler, verwendete Register zu 
sichern. Das Status- als auch das mp-Register kann wichtige Inhalte 
haben, die dann u.U. beim Eintreten eines Interrupts futsch sind.
Gruß oldmax

[Ben _. (burning_silicon)]

Das Statusregister MUSS bei Interruptroutinen gesichert werden. 
Ansonsten gibts schwere Probleme wenn ein Interrupt zwischen einem 
Compare und der nachfolgenden Branch-If-Irgendwas-Anweisung auftritt. 
Schade daß die Dinger kein PUSHF/POPF können wie die x86...

[Thomas B. (nichtessbar)]

Ich seh schon, das wird ein langer Kampf bis das alles stabil läuft und 
getestet ist, es fehlt einfach die Routine ;)

Danke für die Hinweise!