AVR als Slave per TWi abfragen

[Cassio (Gast)]

Ich möchte einen Atmega 32 dazu veranlassen, Werte von einem Atmega 8 
per TWI zu lesen. Nur irgendwie klappt das nicht.

Ich habe dieses Beispiel aus dem RB Wiki für den Atmega8 verwendet:

' TWI-slave test 
' zum simulieren eines PCF8574 

$regfile = "m8def.dat"                                      ' the used chip 
$crystal = 16000000                                          ' frequency used 
' $baud = 9600                                              ' keine baud rate angeben ! 

Dim Twi_control As Byte                                     ' Controlregister lokale kopie 
Dim Twi_status As Byte
Dim Twi_data As Byte

Dim Count As Byte                                           ' Testwert, jedes mal +1 

Declare Sub Twi_init_slave

' Werte zurücksetzen 
Count = 0
Twi_data = 0
Call Twi_init_slave                                         ' TWI aktivieren 


' Hauptschleife 
Do
    ' hier könnte ihr Code stehen 


    ' schauen ob TWINT gesetzt ist 
    Twi_control = Twcr And &H80                             ' Bit7 von Controlregister 

    If Twi_control = &H80 Then
        Twi_status = Twsr And &HF8                          ' Status 

        ' will der Master ein Byte haben 
        If Twi_status = &HA8 Or Twi_status = &HB8 Then
            Twdr = Count                                    ' neue Daten ausgeben 
            Incr Count                                      ' testwert +1 
        End If

        ' TWINT muss immer gelöscht werden, damit es auf dem Bus weiter geht 
        Twcr = &B11000100                                   ' TWINT löschen, mit ACK 
    End If

Loop

End


' Unterprogramme 


' TWI als slave aktivieren 
Sub Twi_init_slave
    Twsr = 0                                                ' status und Prescaler auf 0 
    Twdr = &HFF                                             ' default 
    Twar = &H40                                             ' Slaveadresse setzen 
    Twcr = &B01000100                                       ' TWI aktivieren, ACK einschalten 

End Sub

Und das Programm für den Atmega32:

$regfile = "M32def.dat"
$crystal = 16000000

$lib "i2c_twi.lbx"                                          ' Für Hardware TWI

Waitms 100

Config Twi = 400000                                         ' setzt die TWI-Register
' Twsr = 0                                               ' Status reset
' Twbr = 12                                              ' Bus Geschwindigkeit 400kHz @ 16MHz
Twcr = &B00000100                                           ' TWI Modul aktivieren, nur TWEN


Dim Modus As Byte
Dim Wert As Byte

Const Servom8w = &H40                                       ' Slaveadresse


Do

    Print  "Senden? : " ;
    Input  Modus

    If Modus = 1 Then

        I2cstart
        I2cwbyte Servom8w
        I2crbyte Wert , Nack                                ' "S" Kennzeichen für Servo ansteuern
        I2cstop

        ' Fehler-Flag ausgeben, sollte immer 0 sein, dann war kein Fehler
        Print "Wert: " ; Wert
        Print "Err " ; Err

    End If


Loop

End

Ich erhalte immer als Wert 32 und als Errorwert 0. Das bedeutetja, das 
der Atmega 8 reagiert, nur sendet er nicht das was ich will.
Warum nicht?

Danke schonmal für hilfreiche Antworten. Ich komm seit Stunden nicht 
dahinter wahrscheinlich ist es so einfach...

[Cassio (Gast)]

Keiner eine Idee?

[Cassio (Gast)]

Habs selber rausgefunden.

Statt &H40 muss man &H41 einsetzen dann funktioniert es. Was ja klar 
ist, denn das ist dann die Sendeadresse des Atmega8.

Tja je kleiner der Fehler desto länger die Fehlersuche...