Tcl-Ansteuerung des HTRONIC HB627 Messmoduls

[Peter Kämpf (Gast)]

Hallo,

anbei ein Musterprogramm, um dem Modul HB627 seine Daten zu entlocken, 
ohne in die Abgründe von VB zu versinken. Mit Tcl ist eine sehr einfache 
Ansteuerung möglich, die ohne DLLs auskommt. Der wesentliche Trick ist, 
die Bitordnung der vom HB627 gemeldeten Bytes richtig zu interpretieren.

Bitte Tcl 8.6 oder zumindest 8.5.12 verwenden. Link: 
http://www.activestate.com/activetcl/downloads

Leider läuft es derzeit nur auf Windows. Für OSX muss manuell der 
richtige USB-Port eingetragen werden, und bei Linux sollte es ähnlich 
laufen. Prinzipiell sollte das Programm auf allen Plattformen 
funktionieren, wenn man das Portöffnen anpasst.

#
# HB627_Testprogramm
#
# (c) Peter Kämpf 2012
#
#
# Kommunikation starten:
#  n = Portnummer des virtuellen COM-Ports
#
proc Kanal_auf { n } {
    global Code
    global Kanal
#
# alten Kanal schließen
#
    if {[string length $Kanal] > 0} {
        close $Kanal
    }
#
    if {[catch {open com$n [list RDWR BINARY]} Ergebnis]} {
        tk_messageBox -type ok -icon error \
             -message [encoding convertfrom $Code "Fehler beim Öffnen des Ports COM$n"] \
             -detail "Offizielle Fehlermeldung:\n $Ergebnis"
        set Kanal ""
    } else {
        set Kanal $Ergebnis
#        chan configure $Ergebnis -blocking false -buffering full \
#            -mode 256000,n,8,1 -translation binary
    }
}

#
# Die Spannungen der einzelnen Meßstellen abfragen
#
proc SignalLesen { Kanal } {
    global Pruefsumme
#
    if {[catch {read $Kanal 17} Antwort]} {
        return
    }
#
# Auslesen der 8 2-Byte Antworten + 1 Byte Prüfsumme. Wichtig: Big endian!
#
    binary scan $Antwort S8c Ergebnis Pruefsumme
    for {set i 0} {$i < 8} {incr i} {
        set Messwert($i) [lindex $Ergebnis $i]
    }
#
    .nb.ft.t insert end "$Messwert(0) | $Messwert(1) | $Messwert(2) | $Messwert(3) \
        | $Messwert(4) | $Messwert(5) | $Messwert(6) | $Messwert(7) | $Pruefsumme \n"
    .nb.ft.t yview moveto 1.0
}

#
# Einrichten des Datenfensters mit den Meßwerten
#
proc Textfenster { base } {
#
# Ein Rahmen, alles für den Text:
#
    ttk::scrollbar $base.vsb -orient vertical \
        -command [list $base.t yview]
    text $base.t -autoseparators 1 -maxundo 0 -undo 1 -wrap word \
        -yscrollcommand [list $base.vsb set]
#
# Die Elemente im Plotrahmen verteilen
#
    grid rowconfigure    $base 0 -weight 1
    grid columnconfigure $base 0 -weight 3
    grid columnconfigure $base 1 -weight 0
    grid $base.t   -row 0 -column 0 -sticky nsew
    grid $base.vsb -row 0 -column 1 -sticky ns
}

#
# Endlos-Schleife für Abfragen etwa alle Zehntelsekunde
#
proc Durchlauf {} {
    global Kanal
    global Pruefsumme
#
# Da die Prüfsumme maximal 255 groß wird (1 Byte!), wird sie auf
# einen unmöglichen Wert gesetzt, damit sie sich auch bestimmt ändert,
# wenn gelesen worden ist und das vwait beendet werden kann.
#
    set Pruefsumme 999
#
# Anfrage für den Meßwert aller 8 Kanäle.
#
    puts -nonewline $Kanal "c09"
    catch {flush $Kanal}
#
# Abarbeitung zugunsten des Event Loops anhalten, bis sich Pruefsumme ändert.
#
    vwait Pruefsumme
#
# Ein paar Millisekunden übrig lassen, bevor der nächste Durchlauf startet.
#
    after 90 Durchlauf
}

#
# Hauptprogramm
#
proc main {} {
    global Code
    global Kanal
#
    encoding system cp1252
    set Code cp1252
#
#   Hauptfenster mit Notebook und Menüleiste.
#
    wm title . "HB627 Ausgabe"
    ttk::notebook .nb -width 800 -height 480 -padding 5
#
# COM-Port öffnen. Hier einstellen, was in der Systemsteuerung angezeigt wird.
#
    Kanal_auf 6
#
# Eine Seite mit der Liste der Meßwerte.
#
    .nb add [ttk::frame .nb.ft] -state normal -sticky nsew -text "Textliste"
    Textfenster .nb.ft
    update
#
# Event für die Rückmeldungen einbauen:
#
    fileevent $Kanal readable "SignalLesen $Kanal"
#
# Endlosschleife starten:
#
    Durchlauf
}

#
# JETZT endlich wird das Hauptprogramm aufgerufen und es geht wirklich los:
#
console hide
main
wm geom . [wm geom .]

[Peter Kämpf (Gast)]

Hmm - ich kann wohl nicht mehr den ersten Eintrag editieren. Eine Zeile 
muss noch im Hauptprogramm ergänzt werden, damit die Variable Kanal 
existiert:

set Kanal ""

am besten nach "set Code cp1252" einfügen.

[Uwe B. (boerge)]

MoinMoin,

ich bin mir zwar nicht ganz sicher, was eigentlich deine Frage ist, aber 
ich vermute mal, du möchtest ein OS-unabhängiges Tcl-Script 
schreiben...?

Es geht um diese Zeile?

open com$n [list RDWR BINARY]

Ich würde com$n auf eine globale Variable auslagern.

Dann würde ich mir mal das Tcl-interne Array tcl_platform anschauen 
(http://wiki.tcl.tk/1649). Mit Hilfe dessen bekommt man raus, wie die 
Plattform aussieht, auf der das Script läuft. Den Rest kannst du dir 
dann sicherlich denken..., ...je nach OS Com-Variable setzen...

Grüße Uwe

PS.: nebenbei, ich würde "Durchlauf" nicht in "main" aufrufen, sondern 
ganz unten nach "main" und ganz am Ende (zur Sicherheit):

vwait forever

sieht schicker und logischer aus, zumal "main" in deinem Script ja nur 
ein Initialisieren verschiedener Dinge ist...

[Uwe B. (boerge)]

...achso, noch eine kleine Anmerkung: globale Variablen sollte man auch 
global vorbelegen, also am Anfang des Scripts, um genau solchen 
Problemchen wie mit "Kanal" aus dem Weg zu gehen.

Grüße Uwe

[Peter Kämpf (Gast)]

Hallo Uwe,

die globalen Variablen nach vorne zu verlegen ist in der Tat besser. 
Beim vwait ist das mit der nicht existenten Variablen forever ja 
neckisch, aber meine Implementierung halte ich für leichter verständlich 
und korrekter - immerhin ändert sich ja Pruefsumme bei jedem Lesen.

Jeder so, wie er es mag. Anbei eine Version für OSX und Windows, wobei 
man bei OSX im Verzeichnis /dev selber schauen muß, wie der richtige 
USB-Kanal heißt.

Ach ja - eine Frage hatte ich gar nicht gestellt. Aber Danke für die 
Antwort!

Peter