TCL Command mit Variable

[Dominik Gausa (Gast)]

Hallo Forum,

ich nutze Modelsim-Altera 10.1d und möchte rekursiv durch die instanzen 
gehen und diese gruppiert darstellen lassen.
Dazu schreibe ich mir eine Prozedur, die ich für alle Instanzen aufrufe 
und in der ich die einzelnen Signale etc. optisch aufbereitet ausgebe.

proc plot { inst } {
  echo plotting $inst "\n"
  set entity_name "top"
  
  set group ""
  foreach sgrp [split $inst "/"] {
    if { $sgrp eq "" } {
      echo "empty"
    } else {
      echo "append " $sgrp
      append group " -group " $sgrp " "
      }
    }
    echo "Group: " $group

  echo "add wave $group -divider -height 32 CLOCK"
  add wave $group -divider -height 32 CLOCK
  foreach sig [ find signals /$inst/CLK_* ] { 
    echo "add wave -group vhdl $group -color #F5BCA9 $sig"
    set var "-group top "
    add wave -group vhdl $var -color #F5BCA9 $sig
    }

  foreach sig [ find signals /$inst/RESET_* ] { 
    add wave $group -color #FE642E $sig
    }

  add wave -group $inst -noupdate -divider -height 32 SIGNALS
  foreach sig [ find signals /$inst/s_* ] {
    add wave -group $inst -color #00BFFF $sig
    }
}

foreach ent [lsort [find instances /top_tb/* ] ] {
  echo $ent "\n"
  plot [lindex $ent 0]
}

habe folgendes Problem:

  foreach sig [ find signals /$inst/CLK_* ] { 
    echo "add wave -group vhdl $group -color #F5BCA9 $sig"
    set var "-group top "
    add wave -group vhdl $var -color #F5BCA9 $sig
    }

Ergibt:

# add wave -group vhdl  -group top_tb  -group top  -color #F5BCA9 /top_tb/top/CLK_SYS 
# ** Error: Unrecognized option: "-group top " ignored.
# Error in macro ./plot.do line 41
# Unrecognized option: "-group top " ignored.

Wie muss ich die Variable in den Befehlsaufruf einbringen, damit es 
funktioniert ?

Danke euch!

[Prof. Dr. Wolf (Gast)]

Ich glaube diese thread wäre im PC-Programmierung Forum besser 
aufgehoben.

[Dominik Gausa (Gast)]

Da es Hier hauptsächlich um die Nutzung von Makros für Modelsim für die 
Simulation von FPGA Verhalten geht. Denke ich das es Hier eher jemanden 
geben wird, welcher sich damit schon einmal beschäftigt hat.

Ferner spricht die Suchfunktion eine deutliche Sprache, das TCL im FPGA 
Forum eher verbreitet ist als im PC Forum.

[bernhard (Gast)]

Um auf das Problem zurückzukommen: das liegt an den Parametern die add 
erwartet und wie TCL Parameter ersetzt. In deinem Beispiel wird add mit 
7 Parametern aufgerufen, nämlich

#arg:        1      2     3      4          5     6       7
       add wave -group  vhdl   $var     -color #F5BCA9 $sig

Auch nach der Ersetzung von $var durch den Inhalt "-group top " bleiben 
das 7 Parameter, nämlich

#arg:       1      2     3      4           5     6       7
       add wave -group  vhdl -group top  -color #F5BCA9 $sig

Der 4. Parameter ist also "-group top ", mit dem konnte add nichts 
anfangen. Eine mögliche Abhilfe wäre, in var nur den Gruppennamen zu 
speichern und add folgendermaßen aufzurufen

       set var top
       add wave -group vhdl -group $var -color #F5BCA9 $sig
#arg:         1     2    3      4    5     6       7      8

denn hier sind -group und $var zwei Argumente. Ich kenne Modelsim nicht, 
den "unrecognized option"-Fehler wird damit wohl los, ob es sinnvoll 
ist, zweimal eine Gruppe mit -group anzugeben, weiss ich nicht.

Viel Spass damit
B

[Dominik Gausa (Gast)]

Vielen Dank, es hat mich weiter geführt.

Ich möchte damit rekursiv durch die Instanzen gehen und diese dann 
hirarchisch gruppiert anzeigen.

top
|-Counter
| |-Clock
| |-Signale
|-Ports
| |-Clock
| |-Signale
.
.
.

[Dominik Gausa (Gast)]

Bin nun weiter:

proc plot { inst } {
  echo plotting $inst "\n"
  set entity_name "top"
  set hirac [string trim [string map {"/" " "} $inst] ]
  set group [join [split $hirac " "] " -group " ]
  
  add wave -group vhdl -group $group -divider -height 32 CLOCK
  foreach sig [ find signals /$inst/CLK* ] {     
    add wave -group vhdl -group $group -color #F5BCA9 $sig
    }
  foreach sig [ find signals /$inst/RESET* ] {
    add wave -group vhdl -group $group -color #FE642E $sig
    }
    
  add wave -group vhdl -group $group -divider INTERFACE
  foreach sig [ find signals /$inst/in_* ] {
    add wave -group vhdl -group $group -color #FE642E $sig
    }
  foreach sig [ find signals /$inst/out_* ] {
    add wave -group vhdl -group $group -color #FE642E $sig
    }
  foreach sig [ find signals /$inst/io_* ] {
    add wave -group vhdl -group $group -color #FE642E $sig
    }

  add wave -group vhdl -group $group -noupdate -divider -height 32 SIGNALS
  foreach sig [ find signals /$inst/s_* ] { 
    add wave -group vhdl -group $group -color #00BFFF $sig
    }
}

foreach ent [lsort [find instances -recursive /top_tb/* ] ] {
  echo $ent "\n"
  plot [lindex $ent 0]
}

Läuft nun Fehlerfrei durch, aber statt $group so wie gewünscht mit in 
den Aufruf zu integrieren wird es als String gewertet aller -group 
".....".
Gibt es da noch eine Idee?

Danke euch ;-)

[Dominik Gausa (Gast)]

---- Breaking News ! ----

"eval" löst die Probleme ;-)

[bernhard (Gast)]

Hm, ohne Kenntnis vom Modelsim verstehe ich immer noch nicht so richtig, 
was du vor hast. Ich vermute folgendes:

- du hast einen String inst, der durch Slash getrennte Gruppennamen 
enthält, also etwa

 gruppe1/g2/g3

- aus dem möchtest du den Befehl

  add wave -group vhdl -group gruppe1 -group g2 -group g3 -color ...

zusammenbasteln. Im Moment baust du dir in group ungefähr folgenden 
String zusammen

 -group gruppe1 -group g2 -group g3

und übergibst den an add. Dein String wird aber wieder nicht 
aufgebrochen, die add-Prozedur bekommt jetzt als Name einer Gruppe den 
ganzen String übergeben.

Ich sehe zwei Baustellen: eine ist eher weltanschaulich. Die Methode mit 
der du den String baust, ist nämlich umständlich und fehleranfällig, z. 
B. wenn die Gruppen Leerzeichen enthalten. Ich würde die Gruppenliste so 
bauen

   set inst g1/g2/g3

   set hirac [list]
   foreach i [split $inst /] {lappend hirac -group $i}

Jetzt steht in hirac

  -group g1 -group g2 -group g3

Zweite Baustelle: hirac soll in einzelne Parameter aufgebrochen werden. 
Bei alten TCLs (vor 8.5) gab es dazu nur eine unangenehme Möglichkeit

  eval add wave -group vhdl $group -color #00BFFF $sig

Da Unangenehme ist: mit eval wird das Kommando komplett evaluiert, wenn 
die Gruppennamen böse Zeichen (z. B. Leerzeichen oder []) enthalten, 
gibt es Ärger. Um einen boshaften Fall zu zeigen: Evaluiert man den 
Gruppenname "[exec rm -fr]" ist unter Umständen die Platte leer. Ab TCL 
8.5 geht stattdessen

  add wave -group vhdl {*}$group -color #00BFFF $sig

wenn Modelsims TCL neu genug ist, nimm die zweite Methode. In beiden 
Fällen gehört vor $group kein -group, denn das -group steht ja schon in 
der Variablen.

Jetzt sehe ich grade die "breaking news". Naja, jetzt schicke ich meinen 
Post trotzdem ab.

Viel Spass
B.