[PIC]24FV32KA302 RB4 funktioniert nicht.

[Max H. (hartl192)]

Ich habe ein kurzes Testprogramm für den PIC24FV32KA302 geschrieben. 
Alle LEDs an PROTB blinken außer die an RB4. Die Platine ist ok, der PIC 
dürfte nicht kaputt sein, da zwei neue das gleich Problem habe.
Im DB steht zum PIN 11: SOSCI/AN15/U2RTS/CN1/RB4
Den sekundären Oszillator habe ich deaktiviert.
Die Analogfunktionen habe ich alle deaktiviert.
U2RTS sollte nicht das Problem sein, da RB9 (U1RTS) keine Probleme 
macht.


Quellcode:

    .equ  __24FV32KA302, 1
    .include  "p24FV32KA302.inc"
  config   __FBS, BWRP_OFF            ;Boot segment may be written
  config  __FGS, GWRP_OFF & GSS0_OFF         ;General segment may be written, No Protection
  config  __FOSCSEL, FNOSC_PRIPLL & IESO_OFF   ;Primary oscillator with PLL module (HS+PLL, EC+PLL) & Internal External Switchover mode disabled
  config  __FOSC, POSCMOD_HS               ;HS oscillator mode selected
  config  __FWDT, FWDTEN_OFF          ;WDT disabled (control is placed on the SWDTEN bit)


.global  __reset  
.text
__reset:
  ;stack pointer init
  mov   #__SP_init,w15
  mov   #__SPLIM_init,W0
  mov   W0,_SPLIM
  
  mov  #0x00FF, w0
  mov  w0,TRISA      ;set PORTA<0:7> as digital input
  mov  #0x0000, w0
  mov  w0,TRISB      ;set PORTB<0:15> as digital output
  mov #0x0000,w0
  mov w0,LATB
  clr ANSA        ;All inputs on PORTA digital
  clr ANSB        ;All inputs on PORTB digital
  
  
  bclr OSCCON,#SOSCEN    ;Disables the secondary oscillator
  
  ;T1 init
  bclr T1CON,#TCS      ;Internal clock (FOSC/2)
  bset T1CON,#TCKPS1    
  bset T1CON,#TCKPS0    ;Prescaler 1:256
  bset T1CON,#TON      ;Starts 16-bit Timer1
  mov #31249,w0      
  mov w0,PR1        ;Peiod
  ;Init interrupt
  bclr SR,#IPL2
  bclr SR,#IPL2
  bclr SR,#IPL2      ;CPU interrupt priority level is 0
  bset IPC0,#T1IP2
  bset IPC0,#T1IP1
  bset IPC0,#T1IP0    ;Interrupt is Priority 7 (highest priority interrupt)
  bclr IFS0,#T1IF      ;Clear T1 interrupt flag
  bset IEC0,#T1IE      ;Enable T1 Interrupt
  
  bra $

  .global __T1Interrupt
  __T1Interrupt:
  bclr IFS0,#T1IF ; clear the interrupt flag
  com LATB
  retfie
  
.end

Gruß
Max


Edit:

Problem gelöst:
"bclr OSCCON,#SOSCEN" deaktiviert den sekundären Oszillator zu wenig. 
Man muss ihn mit den config-bits "SOSCSRC" im Word "FOSCSEL" 
deaktivieren.