Arduino Funktionen in der Setup

[Cihan K. (cihan7515)]

Hallo Leute,

ich bin ein Arduino Neuling und komme im Moment nicht voran. Ich möchte 
einen XY-Plotte programmieren. Bevor ich überhaupt loslege möchte ich 
den zwei Antrieben ihre Endposition erlernen lassen (Initialisierung). 
Ich dachte diese Funktion setzte ich in die Setup rein da ich sie ja nur 
einmal vor der Loop brauche. Das funktioniert aber nicht! :(

Wenn ich meine Funktion in der Loop, mit einer if abfrage ausführe läuft 
es Einwand frei. In der Setup tut sich jedoch nichts.

Hier meine Setup Funktion:

void setup()
{
    stepperY.setCurrentPosition(0);
    stepperX.setCurrentPosition(0);
    initSteppers();
}


Muss ich etwas beachten wenn ich eine Funktion in der Setup ausführen 
möchte???

[Markus (Gast)]

Zeig doch mal das ganze Programm.
Oder auch dasjenige, so wie es funktionierte.

[Cihan K. (cihan7515)]

Hier mal das Ganze. Wie schon gesagt, wenn ich die Funktion 
initSteppers() so in die Loop nehme funktioniert es.

#include <AccelStepper.h>
#include <Makeblock.h>
#include <Arduino.h>
#include <SoftwareSerial.h>
#include <Wire.h>

/*
* Setzen der Ein- und Ausgänge des Arduino Boards
*/
AccelStepper stepperX(AccelStepper::DRIVER, 13, 12); // 13-PUL,12-DIR OR 2-PUL, 8-DIR
AccelStepper stepperY(AccelStepper::DRIVER, 2, 8); 
int motorDrc = 4; //M1
int motorPwm = 5; //M1
MeLimitSwitch limitSwitchX(PORT_7); //Me_LimitSwitch module can only be connected to the PORT_3, PORT_4, PORT_6, PORT_7 and PORT_8 of Me - Base Shield.
MeLimitSwitch limitSwitchY(PORT_8);

/*
* Benötigte Variablen
*/
long current_positionY;
long target_positionY = 0;
long current_positionX;
long target_positionX = 0;
long counter = 1;

/*
* Setup, wird nur einmal vor der loop ausgeführt
*/
void setup()
{  
    stepperY.setCurrentPosition(0);
    stepperX.setCurrentPosition(0);
    initSteppers();
}

void loop() 
{
   driveTest(); 
}

void initSteppers(){
  
     current_positionX = stepperX.currentPosition();
     current_positionY = stepperY.currentPosition();
     
   if(counter == 1){
     current_positionX = stepperX.currentPosition();
     current_positionY = stepperY.currentPosition();
     stepperX.setMaxSpeed(250);
     stepperX.setAcceleration(4000); 
     stepperX.moveTo(-2000);
     
     stepperY.setMaxSpeed(350);
     stepperY.setAcceleration(8000); 
     stepperY.moveTo(-2000);
     
     counter = 0;
   }
   
   if(limitSwitchX.touched()==0){ //If the limit switch is up, the "readUpPin" return value is true.
     stepperX.setCurrentPosition(0);
     stepperX.moveTo(1200);

     //while(limitSwitch.touched()==0){ //Repeat check the switch state, until released. 
     }
    else if(current_positionX == 1200){
      target_positionX = stepperX.currentPosition();

      stepperX.moveTo(0);
     }
     
   if(limitSwitchY.touched()==0){ //If the limit switch is up, the "readUpPin" return value is true.
     stepperY.setCurrentPosition(0);
     stepperY.moveTo(1300);

     }
   else if(current_positionY == 1300){
      target_positionY = stepperY.currentPosition();
      stepperY.moveTo(0);

     }
     

     stepperX.run();
     stepperY.run();
   
}

void driveTest(){
     if(current_positionX == 0){
        stepperX.moveTo(target_positionX);
     }
     else if(current_positionX == target_positionX){
       stepperX.moveTo(0);
     }
     stepperX.run();
}

[Markus (Gast)]

Ich weiss jetzt nicht, aber eine leere
void loop()
{
}

könnte allenfalls ein Problem sein.
Setze da zumindest mal was ein.

[Karl H. (kbuchegg)]

Ich seh jetzt nicht, wie das in setup() überhaupt jemals funktionieren 
soll.

In loop funktioniert das, weil loop() laufend immer wieder aufgerufen 
wird.
Damit erfolgt die Abfrage auf das Ansprechen der Endschalter und die 
Aufrufe von run() immer wieder. Aber setup() wird ja nur ein einziges 
mal aufgerufen und dazu ist dann auch noch die Abfrage auf die 
Endschalter falsch. Zudem macht ein Aufruf von run() nicht den 
kompletten Weg, sondern immer nur ein kleines Stück davon. D.h. mit 
deinem einzelnen Aufruf von run() in setup tut sich da praktisch gesehen 
überhaupt nichts. Und selbst wenn, überdenk doch mal deine Logik in 
setup()! Du stellst die Werte für den nächsten Verfahrweg ein, dann 
überprüfst du die Endschalter und dann fährst du (ohne dich weiter um 
die Endschalter zu kümmern). Was ist denn das für eine Logik?

Erwartet hätte ich eigentlich eine Art Schleifen-konstruktion in Setup.
Nach dem Muster

void setup()
{
  ...

  // X-Acchse kalibrieren
  gib dem X-Stepper Befehl gaaaaanz weit zu kleinen X-Werten zu fahren
  (das sollte er nicht mit Full-Speed machen, sondern eher langsam.
  Immerhin haben wir noch keine Ahnung, wie der Kopf in Bezug zum
  Endschalter steht


  while( Endschalter X nicht angesprochen )
    X-Stepper.run();

  da wir jetzt am Endschalter stehen, wissen wir, dass hier 0 ist.
  Daher dem Stepper mitteilen, dass er jetzt auf 0 steht.

  Eventuell sollte man das noch mal etwas verfeinern, da ja mit einer
  gewissen Geschwindigkeit in den Endschalter gefahren wurde und das
  das Ergebnis verfälschen könnte. Noch einmal ein bischen in Richtung
  positiver X-Werte verfahren und dann gemächlich unter Bebachtung des
  Endschalters sich der 0-Position annähern, könnte einen besseren Wert
  liefern.

  // Y-Achse kalibrieren
  Y-Stepper den Befehl geben, gaaaanz weit (langsam) in Richtung
  kleiner Y-Werte zu fahren

  while( Endschalter Y nicht angesprochen )
    Y-Stepper.run();

  dem Y-Stepper mitteilen, dass er jetzt auf 0 steht.

  Eventuell das Ergebnis nochmal verbessern.
}

Eine derartige Struktur hätte ich eigentlich in setup() erwartet. Dein 
Code sieht aber nicht annähernd so oder so ähnlich aus.
Insbesondere fehlt mir die Schleife, die immer wieder Aufrufe von run() 
macht und bei der die Schleifenbedingung (und dadurch die run() Aufrufe) 
vom Ansprechen des Endschalters abhängt.

In deiner Version funktioniert das deshalb, weil du die Schleife durch 
die laufenden Aufrufe von loop() automatisch erhältst und in Loop dann 
prüfst ob die Endschalter angesprochen haben. Das geht in loop(), aber 
das geht nicht in setup(), weil setup() ja nicht mehrmals aufgerufen 
wird. Da musst du schon selber eine Schleife rund um die run() Aufrufe 
legen, die dann den Motor tatsächlich verfahren.

[Cihan K. (cihan7515)]

Danke für die ausführlicher Antwort echt Top! Das mit dem run() in der 
Setup ist mir auch aufgefallen und habe eine Lösung, ähnlich wie deine 
gefunden. Hier meine Lösung zu dem Problem:

void setup()
{  
  current_position_X = stepperX.currentPosition();
  current_position_Y = stepperY.currentPosition();
  initSteppers();
  stepperX.setMaxSpeed(2000); stepperY.setMaxSpeed(2000);// set XY working speed
  stepperX.setAcceleration(4000); stepperY.setAcceleration(4000);// set XY working acceleration
}  


void initSteppers(){
  stepperX.setMaxSpeed(250); stepperX.setAcceleration(2000); // set X stepper speed and acceleration
  stepperY.setMaxSpeed(300); stepperY.setAcceleration(2000); // set Y stepper speed and acceleration
  stepperX.moveTo(-2000); stepperY.moveTo(-2000);            // move XY to origin

  while(limitSwitchX.touched()==1)   //Sucht die Endpos. bis der Schalter schaltet
  stepperX.run();
  while(limitSwitchY.touched()==1)
  stepperY.run();
  
  stepperX.setCurrentPosition(0);stepperY.setCurrentPosition(0); // reset XY position
  target_position_X = 1200; target_position_Y = 1300;
}

Danke für die Antworten!