Digitale Positionsanzeige mit Bascom

[Hans L. (holzwurm56)]

Hallo ,
bei mir ist eine Positionsanzeige kaputt gegangen . Ich habe eine 
Schaltung mit einem ATMega8 gebastelt , in das alte Gehäuse eingebaut 
und die vorhandenen Siebensegmentanzeigen angesteuert . Es gibt eine 
Taste zum nullen und bei längerem Drücken springt man in ein Menu um den 
Teiler an verschiedene Drehgeber anzupassen und mit 2 Tasten kann man 
den Teiler einstellen , wenn beide Tasten ein paar Sekunden nicht 
betätigt werden springt man auf die Positionsanzeige zurück . Es hat 
mich selbst gewundert aber das Ganze hat sofort funktioniert , aber nur 
mit Teiler = 1 .
Hat jemand eine Idee woran das liegt ?
Hier ist der Code :

' Digitalanzeige mit
' 7-Segmentanzeigen
' In: Drehimpulsgeber an d.2 und d.3
' Out: 7-Segmentanzeige

$regfile = "M8def.dat"
$crystal = 8000000


'--------------Declarationen für Drehimpulsgeber
Config Int0 = Falling                                       'Change
On Int0 Drehencoder
Enable Int0
Enable Interrupts
'--------------Config Eingänge Drehgeber
Config Pind.2 = Input
Config Pind.3 = Input
Portd.2 = 1
Encoder_a Alias Pind.2
Portd.3 = 1
Encoder_b Alias Pind.3
'-------------Config Ausgänge Siebensegment
Config Portb = &B11111111
Config Portc = &B00111100
'-------------Pullup Taster0 Taster_Auf Taster_Ab
Config Pind.0 = Input
Portc.0 = 1
Taster0 Alias Pinc.0
Portc.1 = 1
Taster_ab Alias Pinc.1
Portd.0 = 1
Taster_auf Alias Pind.0
'-------------Deklaration Variable
Dim Wert As Word
Dim Grad As String * 4
Dim Grad1 As String * 1
Dim Teiler As Byte
Dim Ee_teiler As Eram Byte
Dim Hilfswert As Byte
Dim Rueck As Byte
Teiler = Ee_teiler
'-------------Test Siebensegmentanzeige
Portb = &B00000000
Portc = &B00000010
Waitms 2000
Portc = &B11011111
Waitms 2000
Portc = &B11101111
Waitms 2000
Portc = &B11110111
Waitms 2000
Portc = &B11111011
Waitms 2000
Portb = &B00000000
Portc = &B00000010
Waitms 2000
'-------------Hauptprogramm---------------

Do

  If Taster0 = 0 Then                                       'Anzeige nullen
    Wert = 0
  End If
    While Taster0 = 0                                       'Einstellung Teiler
        Hilfswert = Hilfswert + 1
        Waitms 500
        If Hilfswert > 10 Then
        Gosub Einstellung
        End If
    Wend
    Hilfswert = 0
      Wert = Wert / Teiler
  Grad = Str(wert)                                          'Wandlung zu String
  Grad = Format(grad , "0000")                              'Formatieren immer 4 Stellen
   'Ansteuerung 1. Segment
    Grad1 = Mid(grad , 1 , 1)
            Portb.2 = 1
            Gosub Auswahl
            Portc = &B11011111
            Waitms 2
   'Ansteuerung 2. Segment
    Grad1 = Mid(grad , 2 , 1)
            Portb.2 = 1
            Gosub Auswahl
            Portc = &B11101111
            Waitms 2
   'Ansteuerung 3. Segment
    Grad1 = Mid(grad , 3 , 1)
            Gosub Auswahl
            Portc = &B11110111
            Portb.2 = 0                                     'Dezimalpunkt setzen
            Waitms 2
   'Ansteuerung 4. Segment
    Grad1 = Mid(grad , 4 , 1)
            Portb.2 = 1
            Gosub Auswahl
            Portc = &B11111011
            Waitms 2
Loop
End

Drehencoder:
If Encoder_b = 0 Then Decr Wert Else Incr Wert
Return

   Auswahl:
    Select Case Grad1
       Case "0" : Portb = &B00000110
       Case "1" : Portb = &B11100111
       Case "2" : Portb = &B00001101
       Case "3" : Portb = &B01000101
       Case "4" : Portb = &B11100100
       Case "5" : Portb = &B01010100
       Case "6" : Portb = &B00010100
       Case "7" : Portb = &B11000111
       Case "8" : Portb = &B00000100
       Case "9" : Portb = &B01000100
     End Select
    Return

    Einstellung:
      Do
      Rueck = Rueck + 1
      If Taster_auf = 0 Then
      Waitms 100
      Rueck = 0
      Teiler = Teiler + 1
      End If
      If Taster_ab = 0 Then
      Waitms 100
      Rueck = 0
      Teiler = Teiler - 1
      End If
      Waitms 50
       Select Case Teiler
       Case 0 : Portb = &B00000110
       Case 1 : Portb = &B11100111
       Case 2 : Portb = &B00001101
       Case 3 : Portb = &B01000101
       Case 4 : Portb = &B11100100
       Case 5 : Portb = &B01010100
       Case 6 : Portb = &B00010100
       Case 7 : Portb = &B11000111
       Case 8 : Portb = &B00000100
       Case 9 : Portb = &B01000100
     End Select
      Portc = &B11111011
      Waitms 2
      Loop Until Rueck = 100
      Ee_teiler = Teiler
      Return

Ich habe die Frage schon in einem anderen Forum gestellt aber keine 
Antwort erhalten .

Vielen Dank für jede Antwort

Hans

[Karl H. (kbuchegg)]

Ohne jetzt die komplette Logik durchgegangen zu sein

Dir ist klar, dass du hier ...

Do
...
      Wert = Wert / Teiler
...
Loop

... den 'Wert' in jedem Schleifendurchlauf sukzessive immer kleiner 
machst bis du irgendwann bei 0 angelangt bist? Und dass dieses 'kleiner 
machen' rasend schnell gehen wird?

Einzige Ausnahme: Wenn 'Teiler' auf 1 steht. Denn dann verändert sich 
'Wert' nicht.

[Hans L. (holzwurm56)]

Hallo Karl Heinz ,
danke für deine Hilfe , habe noch einen Hilfswert eingefügt der ständig 
aktualisiert wird und das Teilerergebnis habe ich als Fließkommazahl 
deklariert .

MfG

Hans