STC 8051 EEPROM zugriff

[Future (Gast)]

Hallo,
ich möchte Daten während des Betriebes dauerhaft auf dem uC speichern 
und habe daher vergeblich versucht auf den EEPROM zu zugreifen.
Leider weiß ich nicht genau wo dran es scheitert da ich die MCU 8051 IDE 
verwende und diese den EEPROM zugriff für meinen uC nicht unterstützt.

Das unten stehende Demoprogramm vom Hersteller hat auch nicht 
funktioniert.
Kann mir jemand helfen das Demoprogramm zum laufen zu bringen?
und nebenbei kennt jemand eine Assembler IDE die mein uC unterstützt?

Programmiere in Assembler und verwende das STC 8051 Starter Kit mit den 
STC 12C5A60S2 und dem small-sized development board.

;/*------------------------------------------------------------------*/
;/* --- STC MCU Limited ---------------------------------------------*/
;/* --- STC12C5Axx Series MCU ISP/IAP/EEPROM Demo -------------------*/
;/* --- Web: www.STCMCU.com -----------------------------------------*/
;/* If you want to use the program or the program referenced in the  */
;/* article, please specify in which data and procedures from STC    */
;/*------------------------------------------------------------------*/

;/*Declare SFR associated with the IAP */
IAP_DATA    EQU 0C2H                ;Flash data register
IAP_ADDRH   EQU 0C3H                ;Flash address HIGH
IAP_ADDRL   EQU 0C4H                ;Flash address LOW
IAP_CMD     EQU 0C5H                ;Flash command register
IAP_TRIG    EQU 0C6H                ;Flash command trigger
IAP_CONTR   EQU 0C7H                ;Flash control register

;/*Define ISP/IAP/EEPROM command*/
CMD_IDLE    EQU 0                   ;Stand-By
CMD_READ    EQU 1                   ;Byte-Read
CMD_PROGRAM EQU 2                   ;Byte-Program
CMD_ERASE   EQU 3                   ;Sector-Erase

;/*Define ISP/IAP/EEPROM operation const for IAP_CONTR*/
ENABLE_IAP  EQU 82H                 ;if SYSCLK<20MHz

;//Start address for STC12C5Axx EEPROM
IAP_ADDRESS EQU 0400H
;-----------------------------------------
    ORG   0000H
    LJMP  MAIN
;-----------------------------------------
    ORG   0100H
MAIN:
    MOV   P1,#0FEH                  ;1111,1110 System Reset OK
    LCALL DELAY                     ;Delay
;-------------------------------
    MOV   DPTR,#IAP_ADDRESS         ;Set ISP/IAP/EEPROM address
    LCALL IAP_ERASE                 ;Erase current sector
;-------------------------------
    MOV   DPTR,#IAP_ADDRESS         ;Set ISP/IAP/EEPROM address
    MOV   R0,#128                     ;Set counter (512)
    MOV   R1,#4
CHECK1:                             ;Check whether all sector data is FF
    LCALL IAP_READ                  ;Read Flash
    CJNE  A,#0FFH,ERROR             ;If error, break
    INC   DPTR                      ;Inc Flash address
    DJNZ  R0,CHECK1                 ;Check next
    DJNZ  R1,CHECK1                 ;Check next
;-------------------------------
    MOV   P1,#0FCH                  ;1111,1100 Erase successful
    LCALL DELAY                     ;Delay
;-------------------------------
    MOV   DPTR,#IAP_ADDRESS         ;Set ISP/IAP/EEPROM address
    MOV   R0,#128                   ;Set counter (512)
    MOV   R1,#4
    MOV   R2,#0                     ;Initial test data
NEXT:                               ;Program 512 bytes data into data flash
    MOV   A,R2                      ;Ready IAP data
    LCALL IAP_PROGRAM               ;Program flash
    INC   DPTR                      ;Inc Flash address
    INC   R2                        ;Modify test data
    DJNZ  R0,NEXT                   ;Program next
    DJNZ  R1,NEXT                   ;Program next
;-------------------------------
    MOV   P1,#0F8H                  ;1111,1000 Program successful
    LCALL DELAY                     ;Delay
;-------------------------------
    MOV   DPTR,#IAP_ADDRESS         ;Set ISP/IAP/EEPROM address
    MOV   R0,#0                     ;Set counter (512)
    MOV   R1,#2
    MOV   R2,#0
CHECK2:                             ;Verify 512 bytes data
    LCALL IAP_READ                  ;Read Flash
    CJNE  A,2,ERROR                 ;If error, break
    INC   DPTR                      ;Inc Flash address
    INC   R2                        ;Modify verify data
    DJNZ  R0,CHECK2                 ;Check next
    DJNZ  R1,CHECK2                 ;Check next
;-------------------------------
    MOV   P1,#0F0H                  ;1111,0000 Verify successful
    SJMP  $
;-------------------------------
ERROR:
    MOV   P0,R0
    MOV   P2,R1
    MOV   P3,R2
    CLR   P1.7                      ;0xxx,xxxx IAP operation fail
    SJMP  $

;/*----------------------------
;Software delay function
;----------------------------*/
DELAY:
    CLR   A
    MOV   R0,A
    MOV   R1,A
    MOV   R2,#20H
DELAY1:
    DJNZ  R0,DELAY1
    DJNZ  R1,DELAY1
    DJNZ  R2,DELAY1
    RET

;/*----------------------------
;Disable ISP/IAP/EEPROM function
;Make MCU in a safe state
;----------------------------*/
IAP_IDLE:
    MOV   IAP_CONTR,#0              ;Close IAP function
    MOV   IAP_CMD,#0                ;Clear command to standby
    MOV   IAP_TRIG,#0               ;Clear trigger register
    MOV   IAP_ADDRH,#80H            ;Data ptr point to non-EEPROM area
    MOV   IAP_ADDRL,#0              ;Clear IAP address to prevent misuse
    RET

;/*----------------------------
;Read one byte from ISP/IAP/EEPROM area
;Input: DPTR(ISP/IAP/EEPROM address)
;Output:ACC (Flash data)
;----------------------------*/
IAP_READ:
    MOV   IAP_CONTR,#ENABLE_IAP     ;Open IAP function, and set wait time
    MOV   IAP_CMD,#CMD_READ         ;Set ISP/IAP/EEPROM READ command
    MOV   IAP_ADDRL,DPL             ;Set ISP/IAP/EEPROM address low
    MOV   IAP_ADDRH,DPH             ;Set ISP/IAP/EEPROM address high
    MOV   IAP_TRIG,#5AH             ;Send trigger command1 (0x5a)
    MOV   IAP_TRIG,#0A5H            ;Send trigger command2 (0xa5)
    NOP                             ;MCU will hold here until ISP/IAP/EEPROM operation complete
    MOV   A,IAP_DATA                ;Read ISP/IAP/EEPROM data
    LCALL IAP_IDLE                  ;Close ISP/IAP/EEPROM function
    RET

;/*----------------------------
;Program one byte to ISP/IAP/EEPROM area
;Input: DPAT(ISP/IAP/EEPROM address)
;       ACC (ISP/IAP/EEPROM data)
;Output:-
;----------------------------*/
IAP_PROGRAM:
    MOV   IAP_CONTR,#ENABLE_IAP    ;Open IAP function, and set wait time
    MOV   IAP_CMD,#CMD_PROGRAM     ;Set ISP/IAP/EEPROM PROGRAM command
    MOV   IAP_ADDRL,DPL            ;Set ISP/IAP/EEPROM address low
    MOV   IAP_ADDRH,DPH            ;Set ISP/IAP/EEPROM address high
    MOV   IAP_DATA,A               ;Write ISP/IAP/EEPROM data
    MOV   IAP_TRIG,#5AH            ;Send trigger command1 (0x5a)
    MOV   IAP_TRIG,#0A5H           ;Send trigger command2 (0xa5)
    NOP                            ;MCU will hold here until ISP/IAP/EEPROM operation complete
    LCALL IAP_IDLE                 ;Close ISP/IAP/EEPROM function
    RET

;/*----------------------------
;Erase one sector area
;Input: DPTR(ISP/IAP/EEPROM address)
;Output:-
;----------------------------*/
IAP_ERASE:
    MOV   IAP_CONTR,#ENABLE_IAP    ;Open IAP function, and set wait time
    MOV   IAP_CMD,#CMD_ERASE       ;Set ISP/IAP/EEPROM ERASE command
    MOV   IAP_ADDRL,DPL            ;Set ISP/IAP/EEPROM address low
    MOV   IAP_ADDRH,DPH            ;Set ISP/IAP/EEPROM address high
    MOV   IAP_TRIG,#5AH            ;Send trigger command1 (0x5a)
    MOV   IAP_TRIG,#0A5H           ;Send trigger command2 (0xa5)
    NOP                            ;MCU will hold here until ISP/IAP/EEPROM operation complete
    LCALL IAP_IDLE                 ;Close ISP/IAP/EEPROM function
    RET

    END