Westinghouse Deckenventilator über Infrarot (Westinghouse IR 78095) mit Arduino steuern

[Christoph G. (fadingdream)]

Ich habe lange nach einer Lösung suchen müssen, um meinen Westinghouse 
Deckenventilator über Infrarot zu steuern, da mir alle IR Libraries für 
Arduino nicht weitergeholfen haben. Vielleicht habe ich mich auch zu 
blöd angestellt, aber ich habe jetzt eine gut funktionierende Lösung 
gefunden.

Und da mir das Internet und dieses Forum im speziellen schon viele gute 
Antworten geliefert hat, möchte ich meine Lösung hier gerne teilen.

Der Westinghouse Deckenventilator hat einen IR-Empfänger von 
Westinghouse (78095) mit dran.

Den Schaltungsaufbau habe ich als Bild angehängt.

Als IR-LED habe ich eine SFH4580 mit einen 4,7 Ohm Vorwiderstand 
genommen (der könnte auch kleiner sein, aber ich möchte den Transistor 
nicht überlasten und es funktioniert damit sehr gut).
Als Transistor habe ich einen BC337-16 verwendet, der mit einen 1 kOhm 
Widerstand am Arduino hängt.

Für den Arduino-Code habe ich versucht den Speicherverbrauch klein zu 
halten und den Code möglichst übersichtlich zu schreiben.
Der komplette Code sieht so aus:
.
.

// Westinghouse ceiling fan ir control 78095
#define irLedPin 8 // der Pin an dem der Transistor für die IR-LED hängt

void setup() {
  pinMode(irLedPin, OUTPUT);
}

void loop() {
  delay(3000);
  sendCodeLight(); // Licht an- oder ausschalten
  delay(2000);
  sendCodeFan1(); // Ventilator auf Stufe 1
  delay(10000);
  sendCodeFan2(); // Ventilator auf Stufe 2
  delay(10000);
  sendCodeFan3(); // Ventilator auf Stufe 3
  delay(10000);
  sendCodeFan0(); // Ventilator aus
  delay(10000);
  sendCodeLightDimmer(38); // Licht dimmen - 38 ist 1x komplett runter- oder hochgedimmt
}

// IR-Codes definieren
void sendCodeLight() {
  byte irCode[] = {1, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0};
  sendCode(irCode);
}
void sendCodeLightDimmer(byte dimmingSteps) {
  byte irCode[] = {1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0};
  for (byte i = 0; i < dimmingSteps; i++) {
    sendCode(irCode);
  }
}
void sendCodeFan0() {
  byte irCode[] = {1, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0};
  sendCode(irCode);
}
void sendCodeFan1() {
  byte irCode[] = {1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1};
  sendCode(irCode);
}
void sendCodeFan2() {
  byte irCode[] = {1, 1, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0};
  sendCode(irCode);
}
void sendCodeFan3() {
  byte irCode[] = {1, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 1};
  sendCode(irCode);
}

// IR-Code senden
void sendCode(byte irCode[]) {
  for (byte r = 0; r < 4; r++) {
    for (byte i = 0; i < 12; i++) {
      sendCodeStep(irCode[i]);
    }
    delayMicroseconds(6620);
  }
}

// aktuelle Stelle vom IR-Code senden
void sendCodeStep(byte actualStep) {
  if (actualStep == 0) {
    sendPulse(460);
    delayMicroseconds(1180);
  } else {
    sendPulse(1300);
    delayMicroseconds(340);
  }
}

// Puls mit ca. 38 kHz senden
void sendPulse(int pulseLength) {
  cli();
  while (pulseLength > 0) {
    digitalWrite(irLedPin, HIGH);
    delayMicroseconds(10);
    digitalWrite(irLedPin, LOW);
    delayMicroseconds(10);
    pulseLength -= 26;
  }
  sei();
}

[RvK (Gast)]

Thanks a lot for sharing, we succeeded using your timings / messages. We 
used the arduino IR library (which is also used within the ESPEasy 
project). The trick is to send the code multiple times (it's 4x in your 
code, in our case 2x was sufficient) sending it just once did never work 
in our setup.
We ended up with a esp (with ESPEasy) using irsend raw command, a 
transistor/mosfet with resistors to drive the IR led.

[Christian (raccoon_chr)]

Vielen Dank für das Austüfteln! Ich hab auch einen Westinghouse Comet 
und lediglich eine Fernbedienung (hängt überm Bett) und ansonsten nur 
den normalen Lichtschalter, an dem er hängt. Sehr unpraktisch.

Ich hab einen Wemos D1 mini mit dem IR-Controller-Shield genommen - der 
soll einen Webserver oder MQTT bekommen, sodass der Ventilator dann über 
einen iobroker aus beliebigen Geräten angesteuert werden kann. Klappt 
prototypisch dank dieses Codes auch sehr gut. Nur das Dimmen hat nicht 
hin (auch nicht, wenn ich genau diesen Code auf den D1 mini flashe), da 
passiert einfach gar nichts. Dimmen über die Fernbedienung ist 
allerdings möglich.

Hat dazu jemand eine Idee? Wird bei Westinghouse das Dimmen inzwischen 
anders angesteuert? Der Comet scheint eine relativ neue Konstruktion zu 
sein insofern, als dass er noch mit "austauschbare Leuchtmittel" 
beworben wurde, aber (leider) mit einem fest eingebauten 
LED-Leuchtmittel kam.