ADC in AVR ASM: Was läuft hier schief

[Andreas B. (bitverdreher)]

Hallo,
anbei mal eine Code, der mittels eines Tasters mit einem ATTiny10 ein 
Gerät ein/ausschalten soll.
Das funktioniert auch soweit gut.
Nun soll auch die Betriebsspannung überprüft werden (läuft direkt an 
einer Liion Zelle) und bei ca. 3V das Gerät abgeschaltet werden.
Dazu ist Pin 3 (PB1) extern an 1.8V angeschlossen.
Das Problem ist nun, daß der ADC scheinbar nie angesprochen wird. Ich 
habe mal probeweise in die ISR des ADCs den Ausgang PB2 aktiviert. Diese 
ISR wird nie angesprungen.
Wo ist hier mein Denkfehler?

Hier der Code:

;-----------------------------------------------------------------------------
;* Switcher for ATtiny10 and Bluetooth loop    
;*
;* PB0 = Button
;* PB1 = ADC connected to 1.8V Pin12 XS3868 (reference for ADC is Vcc = Vbatt of LiIon)
;*       < 3,0V should be a ADC value > 154. Use 150 for security
;* PB2 = Gate mosfet, 0 = switch on the BT and amplifier!
;* PB3 = Status LED + Tx to bluetooth module
;*
;* off= 8uA, on 0.97mA 5V
;* off= 5uA, on 0.60mA 3V3
;-----------------------------------------------------------------------------

.include "tn10def.inc"

.org 0
rjmp RESET        ; Reset Handler
rjmp INT0         ; IRQ0 Handler
rjmp PCINT0       ; PCINT0 Handler
rjmp TIM0_CAPT    ; Timer0 Capture Handler
rjmp TIM0_OVF     ; Timer0 Overflow Handler
rjmp TIM0_COMPA   ; Timer0 Compare A Handler
rjmp TIM0_COMPB   ; Timer0 Compare B Handler
rjmp ANA_COMP     ; Analog Comparator Handler
rjmp WDT          ; Watchdog Interrupt Handler
rjmp VLM          ; Voltage Level Monitor Handler
rjmp ADCCH        ; ADC Conversion Handle


; defines + equ
;-----------------------------------------------------------------------------
.def  save_sreg         = r16
.def  iwr0              = r17
.def  iwr1              = r18
 
.def  key_old           = r19
.def  key_state         = r20
.def  key_press         = r21
 
.def  rTEMP             = r22
.def  adc_value         = r23

; IRQs
;-----------------------------------------------------------------------------

TIM0_COMPA:                   ; IRQ Timer0 compare match A
   in     save_sreg, SREG

; Timer-Verfahren (nach Peter Dannegger): http://www.mikrocontroller.net/articles/Entprellung
get8key:                         ;/old      state     iwr1      iwr0
   mov    iwr0, key_old       ;00110011  10101010            00110011
   in     key_old, PINB       ;11110000
   eor    iwr0, key_old       ;                              11000011
   com    key_old             ;00001111
   mov    iwr1, key_state     ;                    10101010
   or     key_state, iwr0     ;          11101011
   and    iwr0, key_old       ;                              00000011
   eor    key_state, iwr0     ;          11101000
   and    iwr1, iwr0          ;                    00000010
   or     key_press, iwr1     ;store key press detect
   out    SREG, save_sreg
   reti

ADCCH:
   in adc_value, ADCL
   reti
      

; not used IRQs      
TIM0_CAPT:      
TIM0_OVF:
TIM0_COMPB:
ANA_COMP:
      reti
      
;-----------------------------------------------------------------------------

; Start, Power On, Reset
RESET:
WDT:
VLM:
; initialize SP
   ldi rTEMP, HIGH(RAMEND)
   out SPH, rTEMP
   ldi rTEMP, LOW(RAMEND)     
   out SPL, rTEMP

   rcall SetLowClock

   sbi ACSR, ACD                 ; disable AC

; set ADC clock dividier to 8, irq on, auto trigger, free running in ADCSRB is default
   ldi rTemp, 1<<ADPS0 | 1<<ADPS1 | ADIE | ADATE
   out ADCSRA, rTemp
   sbi DIDR0, ADC1D              ; deactivate digital input PB1 (1V8)
   sbi ADMUX, MUX0               ; set AD mux to PB1  (1V8)
   cbi ADCSRA, ADEN              ; disable ACD
   ldi rTEMP, 1<<PRADC 
   out PRR, rTEMP                ; shut down ACD

   ldi rTEMP, 1<<PB2
   out DDRB, rTEMP               ; Out -> Mosfet (-> BT)

   sbi PUEB, PUEB0               ; Pullup an PB0 (Button)
   
   ldi rTEMP, 1<<OCIE0A          ; enable timer compare A interrupt 
   out TIMSK0, rTEMP

   clr key_old
   clr key_state
   clr key_press
   
   sbi PORTB, PB2                ; switch BT off

   
mainloop: 
   cli
   sbis PORTB, PB2
   rjmp status_on

status_off:
   rjmp check_key

status_on:
   mov rTEMP, adc_value          ; check battery
   sbci rTEMP, 150
   brcc switch_to_off            ; low battery

check_key:
   sbrs key_press, PB0           ; skip the next if key 0 is pressed
   rjmp endloop
   
   clr key_press                 ; clear, if key press action done
   sei
   sbis PORTB, PB2
   rjmp switch_to_off
     
switch_to_on:                    ; actual status is off
   cbi PORTB, PB2                ; switch BT on (out is GND)
   rcall SetHighClock

   ldi rTemp, 0
   out PRR, rTemp                ; power on ACD (+ Timer/Counter)
   sbi ADCSRA, ADEN              ; enable ACD
   sbi ADCSRA, ADSC              ; start first ADC conversion

   rjmp endloop
   
switch_to_off:                   ; actual status is on 
   sbi PORTB, PB2                ; switch BT off (out is Vcc)
   rcall SetLowClock

   cbi ADCSRA, ADEN              ; disable ACD
   ldi rTemp, 1<<PRADC
   out PRR, rTemp                ; shut down ACD

endloop:   
   clr key_press                 ; clear, if key press action done
   sei
   sleep
   rjmp mainloop

; set clock to 500Hz
SetLowClock:
   ldi rTEMP, 0xD8
   out CCP, rTEMP                ; Configuration Change Protection Register
   ldi rTEMP, 0x01               ; Clock source 128kHz
   out CLKMSR, rTEMP         

; Clock dividier 256
   ldi rTEMP, 0xD8
   out CCP, rTEMP                ; Configuration Change Protection Register
   ldi rTEMP, 1<<CLKPS3          ; Clk / 256 -> Clock 500Hz
   out CLKPSR, rTEMP

   ldi rTEMP, 1<<CS00 | 1<<WGM02 ; clock divide by 1 + CTC mode A
   out TCCR0B, rTEMP 

   ldi rTEMP, 0x00
   out OCR0AH, rTEMP 
   ldi rTEMP, 0x80 
   out OCR0AL, rTEMP             ; load timer with 0x80FF
   ret

;Set clock to 1MHz
SetHighClock:
   ldi rTEMP, 0xD8
   out CCP, rTEMP                ; Configuration Change Protection Register
   ldi rTEMP, 0x00               ; Clock source 8MHz
   out CLKMSR, rTEMP         

; Clock dividier 8
   ldi rTEMP, 0xD8
   out CCP, rTEMP                ; Configuration Change Protection Register
   ldi rTEMP, 1<<CLKPS0 | 1<<CLKPS1 ; Clk / 8 -> Clock 1 MHz
   out CLKPSR, rTEMP

   ldi rTEMP, 1<<CS00 | 1<<CS02 | 1<<WGM02 ; clock divide by 1024 + CTC mode A
   out TCCR0B, rTEMP 

   ldi rTEMP, 0x01
   out OCR0AH, rTEMP 
   ldi rTEMP, 0x00 
   out OCR0AL, rTEMP             ; load timer with 0x100FF (for 1MHz / 1024)
   ret

Gruß
Andreas

[spess53 (Gast)]

Hi

>Wo ist hier mein Denkfehler?

hier:

 ldi rTemp, 1<<ADPS0 | 1<<ADPS1 | ADIE | ADATE
                                 ^^^^^^ ^^^^^^

MfG Spess

[Andreas B. (bitverdreher)]

Aua, Tomaten auf den Augen. Und ich such mir hier einen Wolf.

Danke Dir!
Andreas