Arduino Mega 2560 & Windows per RS-232

[Thomas S. (zeilentrafo)]

Hallo,
hier möchte ich Euch vorstellen, wie ein AVR (hier ATMega 2560, es kann 
aber auch an jeden anderen AVR angepasst werden) über RS-232 mit dem 
Windows-PC (geht auch unter Linux und MAC-OS) gesteuert werden kann. Als 
Hardware wird hier die LED an PortB.7 verwendet, es lässt sich natürlich 
jede hardware analog steuern: Relais, Servos etc.

Hier der Bascom-code auf dem AVR:

$regfile = "m2560def.dat"
$framesize = 32
$swstack = 32
$hwstack = 32
$crystal = 16000000
$baud = 1200

Config Portb.7 = Output
Led Alias Portb.7

Dim X As Byte
Dim Y As Byte
Dim Z As Byte

Z = 50                                                      ' General Wait Time
Y = 0                                                       'initialize software-timer

Do

If Ischarwaiting() = 1 Then                                 'Eingang RS-232 prüfen
Inputbin X
X = 100 - X                                                 'Software-Umkehr damit LED dunkel ist, wenn der Trackbar links gezogen wird
End If

While Y < 100                                               'Software-timer. Das kann
If Y = X Then Led = 1                                       'natürlich auch mit einem onboard-timer
Waitus Z                                                    'gemacht werden. Mit der Software-Lösung
Incr Y                                                      'wird jedoch die Funktion erläutert
Wend                                                        'und es kann bspw. eine RGB-Diode oder
                                                             'beliebig viele Servos in einer
While Y > 0                                                 'Routine abgearbeitet werden.
If Y = X Then Led = 0
Waitus Z
Decr Y
Wend

Loop
End

und hier der Code für PureBasic:

#WindowColor=$F0F0F0

Define TxByte.a

Define flags = #PB_Window_ScreenCentered|#PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget
OpenWindow(0,0,0,300,100,"RS-232",flags)
WindowBounds(0,150,150, #PB_Ignore, #PB_Ignore)
SetWindowColor(0,#WindowColor)
TextGadget(1,5,50,48,20, "tx-data:", #PB_Text_Center)
TrackBarGadget (2, 55, 50, 240, 30, 0, 100)
OpenSerialPort(0,"COM9",1200,#PB_SerialPort_NoParity,8,1,#PB_SerialPort_NoHandshake,512,512)

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 2
          TxByte = GetGadgetState(2)
          WriteSerialPortData(0, @TxByte, 1)
      EndSelect
    Case #PB_Event_CloseWindow:CloseSerialPort(0):End
  EndSelect
ForEver

Der COM-Port muss angepasst werden. Nach Installation des USB-RS232 
Adapters wird der im Gerätemanager angezeigt.

Viel Spass beim Experimentieren.
Thomas

[Thomas S. (zeilentrafo)]

ich habe das Programm eben darum erweitert, dass eine RGB-LED 
individuell angesteuert wird. Dabei liegen die Anoden über jeweils 220 Ω 
an den Ports:

Rot   - PortB.6
Grün  - PortB.5
Blau  - PortB.4

Die Helligkeitswerte werden in einem Byte übertragen. Dabei hat die rote 
Led den Bereich von 0 bis 80, die grüne 81 ~ 161 und die blaue 162 ~ 
242. Beide Programme sind in Basic geschrieben (BASCOM und PureBasic, 
beide führen diese Programme auch in der Demo-Version aus).

AVR-Seite (Bascom):

$regfile = "m2560def.dat"
$framesize = 32
$swstack = 32
$hwstack = 32
$crystal = 16000000
$baud = 9600

Config Portb = Output

Rled Alias Portb.6
Gled Alias Portb.5
Bled Alias Portb.4

Dim R As Byte
Dim G As Byte
Dim B As Byte
Dim X As Byte
Dim Y As Byte
Dim Z As Byte

Z = 30
Y = 0

Do

If Ischarwaiting() = 1 Then
Gosub Rgb
End If

While Y < 80
If Y = R Then Rled = 1
If Y = G Then Gled = 1
If Y = B Then Bled = 1
Waitus Z
Incr Y
Wend

While Y > 0
If Y = R Then Rled = 0
If Y = G Then Gled = 0
If Y = B Then Bled = 0
Waitus Z
Decr Y
Wend

Loop
End

Rgb:
Inputbin X
If X <= 80 Then
R = X
R = 80 - R
End If

If X > 80 And X <= 161 Then
G = X
G = G - 81
G = 80 - G
End If

If X > 161 Then
B = X
B = B - 162
B = 80 - B
End If
Return

und auf dem PC läuft in PureBasic:

EnableExplicit

#WindowColor=$F0F0F0

Define TxByte.a

Define flags = #PB_Window_ScreenCentered|#PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget
OpenWindow(0,0,0,300,200,"RGB-Steuerung",flags)
WindowBounds(0,200,200, #PB_Ignore, #PB_Ignore)
SetWindowColor(0,#WindowColor)
TextGadget (0, 70, 5, 190, 20, "RGB-Steuerung", #PB_Text_Center)
TextGadget(1,5,30,30,20, "R: ", #PB_Text_Center)
TextGadget(2, 5, 60, 30, 20, "G:", #PB_Text_Center)
TextGadget(3, 5, 90, 30, 20, "B: ", #PB_Text_Center)
TrackBarGadget (4, 55, 30, 240, 30, 0, 80)
TrackBarGadget (5, 55, 60, 240, 30, 0, 80)
TrackBarGadget (6, 55, 90, 240, 30, 0, 80)

OpenSerialPort(0,"COM9",9600,#PB_SerialPort_NoParity,8,1,#PB_SerialPort_NoHandshake,512,512)
TxByte=0
WriteSerialPortData(0,@TxByte,1)
TxByte=81
WriteSerialPortData(0,@TxByte,1)
TxByte=162
WriteSerialPortData(0,@txbyte,1)
Repeat
  Select WaitWindowEvent()
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 4
          TxByte = GetGadgetState(4)
          WriteSerialPortData(0, @TxByte, 1)
        Case 5
          TxByte=GetGadgetState(5)+81
          WriteSerialPortData(0,@TxByte,1)
        Case 6
          TxByte=GetGadgetState(6)+162
          WriteSerialPortData (0,@TxByte,1)
      EndSelect
    Case #PB_Event_CloseWindow:CloseSerialPort(0):End
  EndSelect
ForEver

Das ist bestimmt nicht alles elegant gelöst, aber es funktioniert und 
man sieht bei drei PWM-Werten den Vorteil des Software-timers.

Gruß

Thomas