Umschreiben auf locken MQTT Broker

[arduinoneuling (Gast)]

Hallo,
ich habe folgenden sketch versucht:

/*
    ESP8266 RFID Reader - MQTT Sender
    Copyright 2016 Christian Moll <[e-mail]>
 
    This program is free software: you can redistribute it and/or modify
    it under the terms of the GNU General Public License as published by
    the Free Software Foundation, either version 3 of the License, or
    (at your option) any later version.
 
    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.
 
    You should have received a copy of the GNU General Public License
    along with this program.  If not, see <http://www.gnu.org/licenses/>.
 
    Dieses Programm ist Freie Software: Sie können es unter den Bedingungen
    der GNU General Public License, wie von der Free Software Foundation,
    Version 3 der Lizenz oder (nach Ihrer Wahl) jeder neueren
    veröffentlichten Version, weiterverbreiten und/oder modifizieren.
 
    Dieses Programm wird in der Hoffnung, dass es nützlich sein wird, aber
    OHNE JEDE GEWÄHRLEISTUNG, bereitgestellt; sogar ohne die implizite
    Gewährleistung der MARKTFÄHIGKEIT oder EIGNUNG FÜR EINEN BESTIMMTEN ZWECK.
    Siehe die GNU General Public License für weitere Details.
 
    Sie sollten eine Kopie der GNU General Public License zusammen mit diesem
    Programm erhalten haben. Wenn nicht, siehe <http://www.gnu.org/licenses/>.
*/
 
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <ESP8266HTTPUpdateServer.h>
 
#include <MQTTClient.h>
#include <SPI.h>
#include <MFRC522.h>
 
#define SS_PIN D8 //Pin on WeMos D1 Mini
#define RST_PIN D3 //Pin on WeMos D1 Mini
 
const char* host = "rfid_reader"; // will also be used on shiftr.io
const char* ssid = "ssid";
const char* password = "passphrase";
 
const char* brocker = "broker.shiftr.io";
const char* mqttUser = "mqttuser";
const char* mqttPass = "mqttpassword";
 
ESP8266WebServer httpServer(80);
ESP8266HTTPUpdateServer httpUpdater;
 
WiFiClient wifi;
MQTTClient mqtt;
 
MFRC522 rfid(SS_PIN, RST_PIN); // Instance of the class
MFRC522::MIFARE_Key key;
 
unsigned int batt;
double battV;
unsigned long oldMillis;
 
void connect();
 
void setup(void){
  SPI.begin();
  rfid.PCD_Init();
 
  Serial.begin(115200);
  Serial.println();
  Serial.println("Booting Sketch...");
  WiFi.mode(WIFI_AP_STA);
  WiFi.begin(ssid, password);
 
  mqtt.begin(brocker, wifi);
  mqtt.publish("/rfid_reader/resetReason", ESP.getResetReason());
 
  connect();
 
  MDNS.begin(host);
 
  //Attach handles for different pages.
  httpUpdater.setup(&httpServer);
 
  httpServer.on("/", handleRoot);
 
  httpServer.begin();
 
  MDNS.addService("http", "tcp", 80);
  Serial.println("Up and running!");
}
 
void loop(void){
  if(!mqtt.connected()) {
    connect();
  }
 
  httpServer.handleClient();
  mqtt.loop();
  delay(10);
 
  handleRFID();
 
  //things that should only be transmitted all 60 sec
  if (millis()-oldMillis > 60000) {
    batt = analogRead(A0);
    battV = mapDouble(batt, 0, 1023, 0.0, 6.6);
    mqtt.publish("/rfid_reader/batt", String(battV));
    mqtt.publish("/rfid_reader/battRaw", String(batt));
 
    oldMillis = millis();
  }
}
 
void connect() {
  while(WiFi.waitForConnectResult() != WL_CONNECTED){
    WiFi.begin(ssid, password);
    Serial.println("WiFi failed, retrying.");
  }
 
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
 
  while (!mqtt.connect(host, mqttUser, mqttPass)) {
    Serial.print(".");
  }
  Serial.println("\nconnected!");
}
 
void handleRoot() {
  httpServer.send(200, "text/plain", "It works!!!");
}
 
void messageReceived(String topic, String payload, char * bytes, unsigned int length) {
  Serial.print("incoming: ");
  Serial.print(topic);
  Serial.print(" - ");
  Serial.print(payload);
  Serial.println();
}
 
void handleRFID() {
  if (!rfid.PICC_IsNewCardPresent()) return;
  if (!rfid.PICC_ReadCardSerial()) return;
  mqtt.publish("/rfid_reader/uid", printHex(rfid.uid.uidByte, rfid.uid.size));
  rfid.PICC_HaltA();
  rfid.PCD_StopCrypto1();
}
 
double mapDouble(double x, double in_min, double in_max, double out_min, double out_max)
{
  double temp = (x - in_min) * (out_max - out_min) / (in_max - in_min) + out_min;
  temp = (int) (4*temp + .5);
  return (double) temp/4;
}
 
String printHex(byte *buffer, byte bufferSize) {
  String id = "";
  for (byte i = 0; i < bufferSize; i++) {
    id += buffer[i] < 0x10 ? "0" : "";
    id += String(buffer[i], HEX);
  }
  return id;
}

http://lazyzero.de/elektronik/esp8266/rfid_mqtt/start

ich hab es versucht auf meinen lokalen broker umzuschreiben aber ich 
bekomme es nicht hin. Mein lokaer MQTT Broker mosquito läuft auf 
192.168.178.2:1883 kein passwort oder user.

kann mir jdm helfen??

danke

[Uwe D. (monkye)]

Hast Du schon recherchiert ob es erlaubt ist bei dieser Implementierung 
ohne User/Password zu agieren?

[Michael U. (amiga)]

Hallo,

wie weit kommst Du denn?

Eigentlich sollte es reichen, wenn Du
const char* brocker = "192.168.178.2";

setzt und den Aufruf

  while (!mqtt.connect(host, mqttUser, mqttPass)) {
auf
  while (!mqtt.connect(host)) {
änderst wenn Du kein Passwort benutzt.
Verschlüsselung wird nicht benutzt.

Sag doch mal, wo er hängenbleibt. WiFi connect ist ok?
Broker connect?

Gruß aus Berlin
Michael

[RP6conrad (Gast)]

Ich verwende eine andere MQTT library  : PubSubClient.h  Damit 
functioniert das :

#include <ESP8266WiFi.h>
#include <PubSubClient.h> 
#define mqtt_server "192.168.0.60"
#define mqtt_user "micro"
#define mqtt_password "password"
WiFiClient espClient;
PubSubClient client(espClient);
IPAddress ip(192, 168,0,66);//DHT22 was 69
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0); 
WiFi.config(ip, gateway, subnet);
WiFi.begin(ssid, password);
void loop(){
/*****Every minute, do measurements and dump to MQTT on the Pi*********************/
if (now - lastMillis_MQTT >= MQTT_interval) {
        lastMillis_MQTT = now;  
 if (client.connect("ESP8266Client", mqtt_user, mqtt_password)) {
            Serial.println("connected");
            client.publish(humidity_topic, String(h_dht22).c_str(), true);
            client.publish(temp_topic, String(t_dht22).c_str(), true);
}

Das ist hier nicht komplett, nur ein beispiel. Ich kann sie auch die 
complette code senden bei Interesse. Den Wemos lest DHT22 aus, DS18B20, 
Regenmesser, und jeden stunde wird nach eine MySQL data geschickt, jeden 
Minute nach MQTT auf eine Raspberry.