String Definieren / mehrere Loops? WEMOS D1

[Sebastian Merz (Gast)]

Hallo liebe Community, hätte mal eine frage und zwar bin ich gerade 
dabei mit einem Wemos D1 mini einen MQTT Client zu bauen, und mir sind 
zwei fragen aufgekommen ^^ ( Neopixels + PubSubclient + BME280 Senor )

1. habe bereits einen bme280 sensor usw drauf die abgefragt werden bei 
änderung ( im loop ), kann ich noch nebenbei eine animation laufen 
lassen für meine Neopixels ? Schedueler Library soll ja nicht bzw nicht 
so toll funktionieren beim ESP8266 ?!

und zweite frage bezieht sich auf den Code, bekomme von dem void 
callback ein hex zugesendet für rgb LEDs wenn ich strPayload = 
"#FFFFFF"; angebe funktioniert es, komme gerade nicht weiter. Wie 
definier ich das richtig ?

Danke schonmal für Antworten :D

#include <ESP8266WiFi.h>
#include <Wire.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>
#include <Adafruit_NeoPixel.h>

//PubSubClient
#define wifi_ssid "xxxx"
#define wifi_password "xxxx"
#define mqtt_server "xxxx"
const char* mqtt_user = "xxxx";
const char* mqtt_password = "xxxx";

//BME280
#define SEALEVELPRESSURE_HPA (1013.25)

//Subcribe Topics
#define humidity_topic "Home/Weatherstation/Humidity"
#define temperature_topic "Home/Weatherstation/Temperature"
#define pressure_topic "Home/Weatherstation/Pressure"
#define altitude_topic "Home/Weatherstation/Altitude"
#define light_topic "Home/Weatherstation/Light"

//Publish Topics
#define ir_topic "/Home/Livingroom/IR"
#define rf_topic "/Home/Livingroom/RF"
#define main_topic "/Home/Livingroom/Light/Main"
#define rgb_topic "/Home/Livingroom/Light/RGB"
#define rgbfunc_topic "/Home/Livingroom/Light/RGBfunc"

#define PIN D8
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(8, PIN, NEO_GRB + NEO_KHZ800);

String strTopic;
String strPayload;

WiFiClient espClient;
PubSubClient client(espClient);

const int analogInPin = A0;
Adafruit_BME280 bme; // configuring as I2C 


void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  //LED
  pinMode(BUILTIN_LED, OUTPUT);
  // Starting i2c;
  Wire.begin(SDA, SCL);
  pixels.begin();
  
  // Starting Sensor
  bool status;

  status = bme.begin();  
    if (!status) {
        Serial.println("Could not find a valid BME280 sensor, check wiring!");
        while (1);
    }
}

void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(wifi_ssid);

  WiFi.begin(wifi_ssid, wifi_password);
  WiFi.mode(WIFI_STA);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  int led;
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    strPayload = String((char)payload[i]);
  }
  Serial.println();
  strTopic = String((char*)topic);
  
  
  if ((strTopic == main_topic) && ((char)payload[0] == '0')) {
    digitalWrite(BUILTIN_LED, LOW);
  }
  else if ((strTopic == main_topic) && ((char)payload[0] == '1')) {
    digitalWrite(BUILTIN_LED, HIGH);
  }
  else if ((strTopic == rgbfunc_topic) && ((char)payload[0] == '1')) {
    setColor(led,255,0,0,100);
  }
  else if ((strTopic == rgbfunc_topic) && ((char)payload[0] == '0')) {
    setColor(led,0,0,0,100);
  }
  else if (strTopic == rgb_topic) {
    String hexstring = strPayload;
    long number = strtol( &hexstring[1], NULL, 16);
    long r = number >> 16;
    long g = number >> 8 & 0xFF;
    long b = number & 0xFF;

    Serial.print("red is ");
    Serial.println(r);
    Serial.print("green is ");
    Serial.println(g);
    Serial.print("blue is ");
    Serial.println(b);    
    Serial.print("");    
    Serial.print(hexstring);
  }

  
  else {
    Serial.print("Subscribed but no function!");
  }

}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    // If you do (not) want to use a username and password, change next line to
    // if (client.connect("ESP8266Client")) { 
    // or (client.connect("ESP8266Client", mqtt_user, mqtt_password)) {
    if (client.connect("Wohnzimmer", mqtt_user, mqtt_password)) {
      Serial.println("connected");
      client.subscribe(ir_topic);
      client.subscribe(rf_topic);
      client.subscribe(main_topic);
      client.subscribe(rgb_topic);
      client.subscribe(rgbfunc_topic);
    }
    else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void setColor(int led, int redValue, int greenValue, int blueValue, int delayValue)
{
  pixels.setPixelColor(led, pixels.Color(redValue, greenValue, blueValue)); 
  pixels.show();
}

bool checkBound(float newValue, float prevValue, float maxDiff) {
  return !isnan(newValue) &&
         (newValue < prevValue - maxDiff || newValue > prevValue + maxDiff);
}

long lastMsg = 0;
float temp = 0.0;
float hum = 0.0;
float pres = 0.0;
float alti = 0.0;
float light = 0.0;
float diff = 0.3;
float diff2 = 1;
float diff3 = 2;

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  long now = millis();
  if (now - lastMsg > 1000) {
    lastMsg = now;

    float newTemp = bme.readTemperature();
    float newHum = bme.readHumidity();
    float newPres = bme.readPressure() / 100.0F;
    float newAlti = bme.readAltitude(SEALEVELPRESSURE_HPA);
    float newLight = analogRead(analogInPin);

    if (checkBound(newTemp, temp, diff)) {
      temp = newTemp;
      Serial.print("Neue Temperatur:");
      Serial.println(String(temp).c_str());
      client.publish(temperature_topic, String(temp).c_str(), true);
    }

    if (checkBound(newHum, hum, diff)) {
      hum = newHum;
      Serial.print("Neue Luftfeuchtigkeit:");
      Serial.println(String(hum).c_str());
      client.publish(humidity_topic, String(hum).c_str(), true);
    }
    
    if (checkBound(newPres, pres, diff)) {
      pres = newPres;
      Serial.print("Neuer Druck:");
      Serial.println(String(pres).c_str());
      client.publish(pressure_topic, String(pres).c_str(), true);
    }
     
    if (checkBound(newAlti, alti, diff2)) {
      alti = newAlti;
      Serial.print("Neue Höhe:");
      Serial.println(String(alti).c_str());
      client.publish(altitude_topic, String(alti).c_str(), true);
    }
    if (checkBound(newLight, light, diff3)) {
      light = newLight;
      Serial.print("Neue Helligkeit:");
      Serial.println(String(light).c_str());
      client.publish(light_topic, String(light).c_str(), true);
    }
  }
}