SPM-Instruction beim Atmega328p

[Glenn (Gast)]

Hallo,
ich bin gerade dabei, den Atmega328p näher kennenzulernen, indem ich 
einen Arduino Uno über einen ISP-Programmer (Diamex) und AVR-Studio 4 in 
Assembler programmiere. Es sind meine ersten Gehversuche in Assembler.
Da ich perspektivisch einen kleinen programmierbaren 
Kommando-Interpreter (Forth-ähnlich) schreiben möchte, möchte ich auch 
die Technik beherrschen, User-Input remanent ins Flash zu schreiben - 1 
KB EEPROM ist mir einfach zu wenig. Und je mehr Programmspeicher ein 
Atmega hat, desto mehr macht eine solche Möglichkeit auch Sinn.
Ich habe also eine kleine Testroutine geschrieben, die den Temporary 
Buffer mit ansteigenden Werten füllt, diesen in die entsprechende, vom 
Z-Pointer indizierte Page schreibt und diese Page dann ausliest - für 
den Simulator etwas abgespeckt, die Subroutines getbyte und sendbyte 
sind hier funktionslos.
Der Simulatorlauf funktioniert, egal wo im 'Flash' spm-execute steht.
Auf dem Controller selbst sieht es anders aus: steht spm-execute in der 
Bootloader-Section scheint der Controller dort festzuhängen, denn das 
Auslesen der Page funktioniert dann nicht.
Schreibe ich spm-execute einfach irgendwo in die Application-Section 
hinein, wird die Seite zwar ausgelesen, aber erkennbar ist der Temporary 
Buffer dort vorher nicht hineingeschrieben worden - was ja zu erwarten 
war.
Mich interessiert also, warum der Controller in der Bootloader-Section 
festhängt. Darf man vom Applikationsbereich nicht einfach eine 
Subroutine aufrufen, die in der Bootloader-Section steht?
Für Erklärungen oder Vorschläge wäre ich dankbar.
Viele Grüße
Glenn

;------------------------------------ Testprogram for SPM Storage Checking ------------------------------------------------

.include "M328pDEF.INC"
.org 0000

.def  char = r17
.def  char1 = r18
.def  wordcounter = r22

ldi   r16, low(RAMEND)
out   SPL, r16
ldi   r16, high(RAMEND)
out   SPH, r16

ldi   r16, 0b00011000  ;getbyte Enable (RXEN) + sendbyte Enable (TXEN) = (11)
sts   UCSR0B,r16            
ldi   r16, 0b00000110  ;USART Mode Select Asynchronuos (URMSEL01:0) = (00), 8-bit Character Size (UCSZ1:0) = (11)  
sts   UCSR0C,r16    ;No Parity, No Stop-Bit (000)
ldi   r16, 0x33      ;Baud Rate Register = 0x33, 19200 at 16 MHz 
sts   UBRR0L,r16

;----------------------------------------------------------------------------------------------------------------------

ldi    wordcounter,64  ; 64 words
ldi   char,0

ldi   ZL,low(25600)
ldi   ZH,high(25600)

word_to_buffer:
mov    r0,char
inc   char
mov    r1,char
inc   char
ldi    r16,0b00000001
call  spm_execute
adiw  Z,2
dec    wordcounter
brne  word_to_buffer

ldi   ZL,low(25600)
ldi   ZH,high(25600)  
ldi    r16, 0b00000011  ; page erase
call  spm_execute      
ldi    r16, 0b00000101  ; page write
call  spm_execute    
ldi    r16, 0b00010001  ; section re-enable
call  spm_execute

ldi   ZL,low(25600)
ldi   ZH,high(25600)
ldi    wordcounter,128  ; 128 bytes
word_send:
lpm   char1,Z
;call  sendbyte
adiw  Z,1
dec   wordcounter
brne  word_send

halt: rjmp halt

;------------------------------------------------ subroutines ---------------------------------------------------------

getbyte: 
lds   r16,UCSR0A
sbrs  r16,RXC0
rjmp  getbyte
lds   char,UDR0
ret

sendbyte: 
lds   r16,UCSR0A
sbrs  r16,UDRE0
rjmp  sendbyte
sts   UDR0,char
ret

.org 0x3C00
spm_execute:    
out SPMCSR,r16
spm
complete:  
in   r16,SPMCSR
sbrc r16,SELFPRGEN
rjmp complete
ret

[bitflipser (Gast)]

Das 328/P Datenblatt liefert in
"30. BTLDR - Boot Loader Support – Read-While-Write Self-Programming"
ein paar Hinweise:
SPM wird aus dem Anwendungsspeicher, glaube ich, ignoriert und während 
einer Lösch- oder Schreibaktion im RWW-Speicherbereich (i.d.R. der 
Anwendungsspeicher) darf darauf nicht zugegriffen werden.
Kurz:
Dieser Teil sollte komplett im NRWW-/Bootloaderbereich laufen (zusammen 
mit spm_execute):

ldi   ZL,low(25600)
ldi   ZH,high(25600)  
ldi    r16, 0b00000011  ; page erase
call  spm_execute      
ldi    r16, 0b00000101  ; page write
call  spm_execute    
ldi    r16, 0b00010001  ; section re-enable
call  spm_execute