ATmega4809 TCA Input Event Counter

[Veit D. (devil-elec)]

Hallo,

ich muss euch mal fragen ob das Verhalten von TCA normal ist oder nicht. 
Im Manual lese ich nichts von der Notwendigkeit das TCA CNT Register auf 
1 setzen zu müssen statt auf 0 nach Reset zu belassen. Den Testcode habe 
ich für die Gemeinde in Barmetall umgeschrieben damit es jeder 
ausprobieren kann wer möchte.

Der Code soll die Overflows der RTC zählen. Alles im Sekundentakt. Das 
wird über das Eventsystem angebunden. Alles wie gehabt. TCA wurde wegen 
Arduinovoreinstellungen komplett resetet und dann neu konfiguriert. Wer 
die Arduino IDE verwendet muss allerdings den MegaCoreX von MCUdude 
verwenden. Er hat TCA komplett freigeschaufelt. Ohne dessen CorePackage 
funktioniert millis nicht, da hängt der TCA noch mit drin.

Ich musste jedenfalls feststellen das TCA nur beginnt zu zählen wenn ich 
CNT auf 1 nach Reset setze und nicht auf 0. Ich kann mir nicht erklären 
warum man das machen muss. Ist das bei euch auch so? Mit einem AVRxDB 
gibt es keine solchen Probleme. Im Errata lese ich davon auch nichts. 
Mach ich was falsch oder ist das so?

Was ich auch soeben getestet habe ist, wenn ich den nächsten TCA 
Überlauf provoziere mit Einstellung 65530 nach Reset, dann zählt er bis 
65535, geht auf 0 und bleibt auf 0. Man müßte hier auch wieder 
nachhelfen und auf 1 setzen.

/* 
  IDE 1.8.19
  Arduino Nano Every
  MegaCoreX erforderlich
  TCA0 zählt über den Event Eingang die Überläufe der RTC
*/

#include <avr/io.h>
#include <avr/interrupt.h>
#include <util/atomic.h>

void setup (void)
{                     
  Serial.begin(9600);             
  Serial.println("\nuReset ### ###");
  initRTC();
  initTCA0();
  initEventSystem();
}

void loop (void)
{  
  readCounter(Serial, 1000);
}

void readCounter(Stream &cout, const uint32_t interval)
{
  static unsigned long lastMillis {0};
  
  if (millis() - lastMillis >= interval) {
    lastMillis += interval;
    cout.print("count ");
    cout.println(TCA0.SINGLE.CNT);
  } 
}

void initEventSystem (void)
{
  EVSYS.CHANNEL7 = EVSYS_GENERATOR_RTC_OVF_gc;    // Generator 'RTC OVF' mit Channel 7 verbinden
  EVSYS.USERTCA0 = EVSYS_CHANNEL_CHANNEL7_gc;     // Channel 7 mit User 'TCA0' verbinden, damit reagiert TCA0 auf RTC OVF
}

void initTCA0 (void)
{
  // alles reseten wegen Arduino Voreinstellungen
  TCA0.SINGLE.CTRLA    = 0;
  TCA0.SINGLE.CTRLB    = 0;
  TCA0.SINGLE.CTRLC    = 0;
  TCA0.SINGLE.CTRLD    = 0; 
  TCA0.SINGLE.CTRLESET = TCA_SINGLE_CMD_RESET_gc;
  TCA0.SINGLE.EVCTRL   = 0;
  TCA0.SINGLE.INTCTRL  = 0;
  TCA0.SINGLE.INTFLAGS = 0xFF;
  TCA0.SINGLE.DBGCTRL  = 0;
  TCA0.SINGLE.CNT      = 1; // größer 0 erforderlich
  TCA0.SINGLE.PERBUF   = 0;
  TCA0.SINGLE.PER      = 0;
  TCA0.SINGLE.CMP0     = 0;
  TCA0.SINGLE.CMP1     = 0;
  TCA0.SINGLE.CMP2     = 0;
      
  TCA0.SINGLE.CTRLA = TCA_SINGLE_CLKSEL_DIV1_gc;
  TCA0.SINGLE.EVCTRL = TCA_SINGLE_EVACT_POSEDGE_gc;
  // TCA0.SINGLE.EVCTRL = TCA_SINGLE_EVACT_ANYEDGE_gc;
  TCA0.SINGLE.EVCTRL = TCA0.SINGLE.EVCTRL | TCA_SINGLE_CNTEI_bm;  
  TCA0.SINGLE.CTRLA = TCA0.SINGLE.CTRLA | TCA_SINGLE_ENABLE_bm; 
}

void initRTC (void)
{
  while (RTC.STATUS > 0) { ; }          // warten auf Register Syncronisierung
  RTC.CLKSEL = RTC_CLKSEL_INT32K_gc;    // Periodendauer 30,518µs
  RTC.PER = 64;                         // = 1000ms / 15,625ms
  // RTC.CTRLA Bug, see Errata
  byte temp {0};
  temp |= RTC_PRESCALER_DIV512_gc;      // Prescaler 512 -->> 30,518µs * 512 = 15,625ms
  temp |= RTC_RTCEN_bm;                 // RTC aktivieren  
  RTC.CTRLA = temp;
}

[S. Landolt (Gast)]

> TCA wurde ... komplett resetet

Das stimmt nun nicht, der Reset-Wert von TCA0_PER ist nicht 0, sondern 
0xFFFF.

[Veit D. (devil-elec)]

Hallo,

hmmm, dass hatte ich übersehen. Habe nun PER und PERBUF mit 0xFFFF 
initialisiert und jetzt funktioniert es auch mit CNT Startwert 0 und er 
zählt nach Überlauf weiter. Danke. Das heißt selbst wenn PER nicht 
benötigt wird wird damit verglichen und ein CNT "Reset" ausgeführt?

[S. Landolt (Gast)]

During normal operation, the counter value is continuously compared to 
zero and the period (PER) value to determine whether the counter has 
reached TOP or BOTTOM. The counter value can also be compared to the 
TCAn.CMPn registers.

[Veit D. (devil-elec)]

Hallo,

das erklärt Einiges, habe ich nicht beachtet.
Vielen Dank. Wünsche schattiges WE.

[S. Landolt (Gast)]

Danke, Ihnen auch.
  Und vielleicht gibt es ja am Sonntag endlich etwas Regen hier im 
Südwesten.