addition von std_logic

[dummy_none (Gast)]

mein code synthetisiert nicht. was mache ich da falsch?
xst meldet: Expression in type conversion to std_logic_vector has 2 
possible definitions in this scope, for example, UNSIGNED and 
std_logic_vector.

library ieee;
use ieee.std_logic_1164.all;
use ieee.std_logic_misc.all;
use ieee.std_logic_arith.all;
use ieee.std_logic_unsigned.all;
use ieee.numeric_std.all;

entity gentest is
  generic (
    test              : std_logic
  );
  port(
    -- clk
    clk           : in  std_logic;
    -- data-input
    data_in1      : in std_logic_vector(2 downto 0);
    data_in2      : in  std_logic_vector(2 downto 0);
    -- output
    out_data      : out std_logic_vector(3 downto 0)
  );
end gentest;

architecture behav of gentest is

  signal temp : std_logic_vector(3 downto 0);

begin
  
  process(clk)
  begin
  if rising_edge(clk) then
    if test = '1' then 
      out_data <= std_logic_vector(unsigned(data_in1) + unsigned(data_in2));
    end if;
    if test = '0' then 
      out_data <= std_logic_vector(unsigned(data_in1) - unsigned(data_in2));
    end if;
  end if;
  --out_data <= temp;
  end process;
end behav;

[Duke Scarring (Gast)]

dummy_none schrieb:
> Expression in type conversion to std_logic_vector has 2
> possible definitions in this scope
Ja, ist logisch.

Entweder diese Bibliotheken:
> use ieee.std_logic_arith.all;
> use ieee.std_logic_unsigned.all;

Oder besser diese verwenden:
> use ieee.numeric_std.all;

Aber nur entweder oder, aber nicht beides zusammen.
Und demnächst schaust Du mal in die Quelltexte der verschiedenen 
Bibliotheken, dann verstehst Du auch die Fehlermeldung.

Duke

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

library ieee;
use ieee.std_logic_1164.all;
use ieee.std_logic_misc.all;
use ieee.std_logic_arith.all;
use ieee.std_logic_unsigned.all;
use ieee.numeric_std.all;

Viel hilft viel oder wie?
Lies mal: Beitrag "IEEE.STD_LOGIC_ARITH.ALL obsolete"

Du hast doppelte Definitionen, die der Compiler anmault. Also schreib 
das:

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

Die numeric_std bietet alles, was du brauchst:
http://www.lothar-miller.de/s9y/archives/14-Numeric_Std.html

Du hast noch einen Breitenfehler:
"line 33: Width mismatch. <out_data> has a width of 4 bits but assigned 
expression is 3-bit wide."
3Bit + 3Bit ergeben weiterhin 3 Bit, du mußt vor der Addition noch ein 
Bit anhängen:

  out_data <= std_logic_vector(resize(unsigned(data_in1),4) + resize(unsigned(data_in2),4));

oder gleich den Weg über Integer gehen:

  out_data <= std_logic_vector(to_unsigned(to_integer(unsigned(data_in1)) + to_integer(unsigned(data_in2)),4));

Übrigens:
Synplify (Lattice) bringt keinen Fehler trotz der (zu)vielen Libs... 
;-)