xmega eeprom - kompakter code

[Martin (Gast)]

Hallo alle miteinander. Ich habe mich bisher kaum mit EEPROMs
beschäftigt und suche eine einfache Variante, wie ich ein paar Variablen
fix und fest abspeichern kann. Das Forum habe ich schon durchforstet,
aber eine kopakte Variante hab ich noch nicht gefunden. Ich Suche nen
Codebeispiel für den Xmega, weil der EEPROM dort in pages organisiert
ist...

kann mir jemand nen Tip geben?

[Warhawk (Gast)]

Hallo,

hast du dir schonmal die Application-Notes bei Atmel zum XMega 
angeschaut?

Da gibt es gleich einige Beispiele mit. Such einfach mal nach: "AVR1315"
Weiterhin könnten für dich auch die Notes "AVR1008" und "AVR101" 
interessant sein.

[Vlad T. (vlad_tepesch)]

Martin schrieb im Beitrag #2280251:
> kann mir jemand nen Tip geben?

ja:
Doppelposter mag niemand
https://www.mikrocontroller.net/topic/226649#2280251

[Timmo H. (masterfx)]

Wenn du mit AVRGCC arbeitest kannst du dich einfach hier nach richten: 
AVR-GCC-Tutorial: EEPROM
Geht geht beim Xmega genauso wie beim Atmega/Tiny

[xmega (Gast)]

Hallo,

Timmo H. schrieb:
> Geht geht beim Xmega genauso wie beim Atmega/Tiny

EEPROM bleibt EEPROM.. das ist richtig. Aber das EEPROM des XMEGA 
funktioniert etwas anders, es ist pageweise organisiert.

Der alten Atmega-Befehlssatz funktioniert 100-prozentig nicht mehr.

Gruß XMEGA

[Martin (Gast)]

xmega schrieb:
> EEPROM bleibt EEPROM.. das ist richtig. Aber das EEPROM des XMEGA
> funktioniert etwas anders, es ist pageweise organisiert.

Genau das ist ja mein Problem ;-)

[Timmo H. (masterfx)]

xmega schrieb:
> Der alten Atmega-Befehlssatz funktioniert 100-prozentig nicht mehr.
>
> Gruß XMEGA

Doch wenn man die lib nutzt schon.
Steht ja auch so im Comment vom eeprom.h:

For Xmega the EEPROM start address is 0, like other architectures. The reading functions add the 0x2000 value to use EEPROM mapping into data space.

Darum kümmert sich eben avrgcc.

Man kann natürlich auch direkt durch das mapping darauf zugreifen.

So wirds in der libc gemacht:

Register usage of internally-used functions, XMEGA arch:
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

    eeprom_mapen:
  Input:
      r25,r24  - EEPROM address
  Output:
      ZH,ZL  - EEPROM address + 0x2000 (to use mapping)
  Scratch:
      r19

    eeprom_update_r18:
  Input:
      r18    - byte to write
      r25,r24  - EEPROM address
  Output:
      r25,r24  - decremented EEPROM address
  Scratch:
      r31,r30,r19,r18,r0

    eeprom_update_byte:
  Input:
      r22    - byte to write
      r25,r24  - EEPROM address
  Output:
      r25,r24  - decremented EEPROM address
  Scratch:
      r31,r30,r19,r18,r0

    eeprom_write_r18:
  Input:
      r18    - byte to write
      r25,r24  - EEPROM address
  Output:
      r25,r24  - incremented EEPROM address
  Scratch:
      r31,r30,r19,r18

    eeprom_write_byte:
  Input:
      r22    - byte to write
      r25,r24  - EEPROM address
  Output:
      r25,r24  - incremented EEPROM address
  Scratch:
      r31,r30,r19,r18

[Timmo H. (masterfx)]

Ups, falscher Code, das kam aus der Readme. Also hier aus eewr_byte.S, 
ist also alles drin für den xmega:

#include <avr/io.h>

#if  E2END && __AVR_ARCH__ > 1

#include <avr/eeprom.h>
#include "asmdef.h"
#include "eedef.h"

ENTRY  eeprom_write_byte
  mov  r18, r22

ENTRY  eeprom_write_r18

#if  __AVR_XMEGA__  /* --------------------------------------------  */

# ifndef CCP_IOREG_gc
#  define CCP_IOREG_gc  0xD8  /* IO Register Protection  */
# endif
# ifndef NVM_CMD_READ_EEPROM_gc
#  define NVM_CMD_READ_EEPROM_gc    0x06
# endif
# ifndef NVM_CMD_LOAD_EEPROM_BUFFER_gc
#  define NVM_CMD_LOAD_EEPROM_BUFFER_gc    0x33
# endif
# ifndef NVM_CMD_ERASE_WRITE_EEPROM_PAGE_gc
#  define NVM_CMD_ERASE_WRITE_EEPROM_PAGE_gc  0x35
# endif
# ifndef  NVM_CMD_ERASE_EEPROM_BUFFER_gc
#  define NVM_CMD_ERASE_EEPROM_BUFFER_gc  0x36
# endif

  ; Prepare base address of NVM.
  ldi  ZL, lo8(NVM_BASE)
  ldi  ZH, hi8(NVM_BASE)

  ; Wait until NVM is not busy.
1:  ldd  r19, Z + NVM_STATUS - NVM_BASE
  sbrc  r19, NVM_NVMBUSY_bp
  rjmp  1b

  ; Disable EEPROM mapping into data space.
  ldd  r19, Z + NVM_CTRLB - NVM_BASE
  andi  r19, ~NVM_EEMAPEN_bm
  std  Z + NVM_CTRLB - NVM_BASE, r19

  ; Check the clearance of EEPROM page buffer.
  ldd  r19, Z + NVM_STATUS - NVM_BASE
  sbrs  r19, NVM_EELOAD_bp
  rjmp  3f      ; erase is not required

  ; Note that we have only four clock cycles to write to the CCP
  ; protected register NVM_CTRLA, after writing to CCP.  The 'ldi'
  ; instruction always takes one clock to execute and 'std' instruction takes
  ; two clock cycles.  We fall within the four cycles that the CCP leaves
  ; us to write the command execution start bit to the NVM_CTRLA
  ; register.  Note that r18 must be preserved until written to NVM_DATA0

  ; Issue EEPROM Buffer Erase:
  ldi  r19, NVM_CMD_ERASE_EEPROM_BUFFER_gc
  std  Z + NVM_CMD - NVM_BASE, r19
  ldi  r19, CCP_IOREG_gc
  out  CCP, r19
  ldi  r19, NVM_CMDEX_bm
  std  Z + NVM_CTRLA - NVM_BASE, r19

  ; Wait until NVM is not busy.
2:  ldd  r19, Z + NVM_STATUS - NVM_BASE
  sbrc  r19, NVM_NVMBUSY_bp
  rjmp  2b

  ; Issue EEPROM Buffer Load command.
3:  ldi  r19, NVM_CMD_LOAD_EEPROM_BUFFER_gc
  std  Z + NVM_CMD - NVM_BASE, r19
  std  Z + NVM_ADDR0 - NVM_BASE, addr_lo
  std  Z + NVM_ADDR1 - NVM_BASE, addr_hi
  std  Z + NVM_ADDR2 - NVM_BASE, __zero_reg__
  std  Z + NVM_DATA0 - NVM_BASE, r18

  ; Issue EEPROM Erase & Write command.
  ldi  r18, NVM_CMD_ERASE_WRITE_EEPROM_PAGE_gc
  std  Z + NVM_CMD - NVM_BASE, r18
  ldi  r18, CCP_IOREG_gc
  ldi  r19, NVM_CMDEX_bm
  out  CCP, r18
  std  Z + NVM_CTRLA - NVM_BASE, r19

  ; Increment address.
  adiw  addr_lo, 1

  ret