ext. Interrupt mit Inkrementalgeber und 8051-Controller

[Michael L. (eagle87)]

Hallo zusammen,
ich versuch grad mit einem Inkrementalgeber einen Zähler zu verändern 
und den aktuellen Wert des Zählers zur Kontrolle über LEDs wieder 
auszugeben. Als Controller verwende ich den AT89S8253.

Ein Signal des Gebers geht auf Port 3.2 und das andere auf Port 3.3. Der 
Interrupt wird über Port 3.2 ausgelöst. Die LEDs sind an Port 0 
angeschlossen.

Der Geber hat 15 Inkremente und 30 Raststellungen pro Umdrehung. Je 
nachdem in welcher Stelle er sich gerade befindet zeigten die LEDs 
entweder irgend ein Leuchtmuster an oder die LEDs 0 bis 6 leuchten und 
die 7. blinkt. Ich hab im Moment keine Ahnung was ich an dem Programm 
verändern muss und auch m Netz hab ich nichts gefunden.

#include <REG8253.H>

;------------------------------------------------

; Reservierung des Stack-Bereichs

?STACK SEGMENT IDATA    

  RSEG  ?STACK         

  DS  10H  

;------------------------------------------------

; Variablen im int. direkt adressierbaren RAM

Variablen SEGMENT DATA    ;Variablen im direkt adressierbaren internen RAM

  RSEG  Variablen       ;Variablen-Segment waehlen

zahl:  DS  1    ;Reserviere 1Byte

zeit1:  DS  1

zeit100:DS  1

;--------------------------------------------------------------------------
; Auf Adresse 0 im Code-Speicher muss ein LJMP zum Programmanfang stehen

  CSEG    AT  0           ;absolutes Code-Segment bei Adresse 0

  ljmp    start           ;Springe zur Marke start

;--------------------------------------------------------------------------
; Interrupt Vektoren

  cseg at 03h

  ljmp positionierung

;--------------------------------------------------------------------------
; Hier folgt Programmcode (Code-Beginn ueber Linker festgelegt)

program_code   SEGMENT CODE

        RSEG   program_code     ;waehle Code-Segment

        USING   0               ;Zeige Benuetzung von Registerbank 0 fuer den folgenden Programmcode an

;--------------------------------------------------------------------------
;Initialisierung  Stack und I/O-Karte

start:

  mov sp,#?stack-1  ;STACK-Definition

;--------------------------------------------------------------------------


  setb ea      ;Interrupts zulassen



  mov zahl,#0    ;Zahl vordefinieren



loop:

  mov a,zahl    ;Zahl ausgeben

  cpl a

  mov p0,a

  setb ex0    ;Fenster für Interrupt

  nop

  clr ex0



  ljmp loop    ;Hauptschleife



;--------------------------------------------------------------------------


positionierung:      ;externer Interrupt 0

  jb p3.3,invers    ;Drehrichtung

  inc zahl    ;hochzählen

  ljmp positionierung2  ;wieder zusammenführen

invers:

  dec zahl    ;runterzählen

positionierung2:

  lcall t100ms    ;Entprellzeit

  clr ie0      ;Flag löschen

  reti



;--------------------------------------------------------------------------


t1ms:        ;1ms Wartezeit

  mov zeit1,#250

zeitmarke1:

  nop

  nop

  djnz zeit1,zeitmarke1

  ret



t100ms:        ;100ms Wartezeit

  mov zeit100,#100

zeitmarke100:

  djnz zeit100,zeitmarke100

  ret



  END      ;END Of File

[Heinz (Gast)]

Wenn das der P. D. sieht, dann springt er wie das HB-Männchen auf und 
ab.

[Michael L. (eagle87)]

Wer ist P.D.? Und warum sagst du nicht einfach was nicht stimmt? So ist 
auch niemandem geholfen.

[Heinz (Gast)]

Bitte diesen Artikel durcharbeiten: 
http://www.mikrocontroller.net/articles/Drehgeber

[Michael L. (eagle87)]

Ok, das hilft schonmal weiter. Die Auswertung nach einer festen Zeit mit 
einem Timer Interrupt werd ich gleich mal ausprobieren. Aber ich hab 
auch nochmal ins Datenblatt meines Gebers geschaut und leider hab ich 
einen, bei dem der Rastpunkt genau auf der Flanke von Signal B liegt. 
Und der AT89S8253 Mikrocontroller besitzt (so wie ich es bisher aus dem 
Datenblatt verstanden hab) nur externe Interrupts für positive Flanken. 
Daher muss ich das Signal wohl noch hardwaremäßig invertieren um ein 
Interrupt mit der negativen Flanke auslösen zu können.

[Peter D. (peda)]

phase_a         equ     p3.2
phase_b         equ     p3.3
led_port        equ     p0

        dseg    at 30h
enc_delta:      ds 1
enc_last:       ds 1

        cseg

main:
        call    poll_encoder
        call    read_encoder2
        add     a, led_port
        mov     led_port, a
        jmp     main

poll_encoder:
        clr     a
        mov     c, phase_a              ; input phase_a
        rlc     a
        jnb     phase_b, _poen1         ; input phase_b
        xrl     a, #3                   ; convert gray to binary
_poen1:
        xch     a, enc_last             ; store new as next last
        subb    a, enc_last             ; difference last - new
        jnb     acc.0, _poen3           ; bit 0 = value (1)
        jnb     acc.1, _poen2           ; bit 1 = direction (+/-)
        inc     enc_delta
        ret
_poen2:
        dec     enc_delta
_poen3:
        ret

read_encoder2:                          ; read two phase encoder
        mov     a, enc_delta            ; read delta counts
        anl     enc_delta, #1           ; clear all bits except debouncing bit
        mov     c, acc.7                ; copy sign bit
        rrc     a                       ; / 2
        ret

end

Peter

[Ralf (Gast)]

> so wie ich es bisher aus dem Datenblatt verstanden hab) nur externe
> Interrupts für positive Flanken.
Soweit ich weiss besitzt er eher welche für negative Flanken... kann 
mich aber auch täuschen...

Ralf

[Michael L. (eagle87)]

@ Peter:
Ich hab versucht deinen Code zu verstehen und auf meinem Controller zum 
laufen zu bringen, aber beides ist mir leider nicht gelungen. Was die 
Funktion "poll_encoder" in etwa macht konnte ich noch einigermaßen 
nachvollziehen, aber bei der Funktion "read_encoder2" und bei der 
Ausgabe auf den LEDs klappt das nicht. Im Anhang ist der Code so wie ich 
ihn kompiliert hab.

@ Ralf:
Das wäre auch möglich. Aber zumindest dürfte es nicht beides geben. Von 
daher bleibt das Problem das gleiche.

[Peter D. (peda)]

Michael L. schrieb:
> Ausgabe auf den LEDs klappt das nicht.

Du solltest versuchen, sinnvolle Fehlerbeschreibungen zu machen.
klappt nicht ist voll für die Tonne, damit kann keiner was anfangen.

read_encoder2 gibt nur bei jedem 2.Puls was aus, damit pro Rastung nur 
einmal gezählt wird.
Du kannst zu Testzwecken aber auch direkt enc_delta auf die LEDs 
ausgeben.


Peter

[Michael L. (eagle87)]

Naja, "klappt nicht" war auch keine Fehlerbeschreibung, sondern nur die 
Aussage, dass ich den Teil des Programms nicht versteh. Aber ich muss 
zugegeben dass ich wirklich noch hätte schreiben sollen was auf dem 
LED-Port passiert: Alle LEDs flackern und wenn ich am Geber drehe ändert 
sich auch nichts.
Wenn ich enc_delta direkt auf die LEDs geb passiert das Gleiche.

Inzwischen hab ich aber ein eigenes Programm zum laufen gebracht. Das 
läuft jetzt über ein Timer-Interrupt, welches alle 10ms auslöst. Dabei 
werden auch nur die Flanken der Spur A und die Zustände der Spur B 
ausgewertet. Das Programm ist vermutlich nicht so effizient wie deines, 
aber zumindest hab ich jetzt ein Programm bei dem ich weiß was es macht.

Übrigens war der hauptsächliche Fehler dass das erste Programm nicht 
funktioniert hat der, dass der externe Interrupt voreingestellt 
zustands- und nicht flankengesteuert arbeitet. Das steht aber nicht im 
Datenblatt, sondern in einem anderen Dokument das allgemein die 
8051-Architektur beschreibt. Dort stand außerdem, dass es wirklich 
fallende Flanken sind, die ein Interrupt auslösen.

Michael