Schaltung zum Fotoapparat auslösen -> Softwareproblem

[Mathias H. (Firma: keine) (matze_2)]

Hallo zusammen!

Ich hoffe ich finde hier Hilfe. Hier mein Problem:

Ich habe eine Schaltung gebaut mit der ich einen Optpkoppler ansteuere 
der meinen Fotoapparat auslöst. Dies soll regelmäßig für Zeitraffer- und 
HDR-Aufnahmen erfolgen. Das ganze wird mit einem Attiny13 (Atmel 
ATTINY13-20PU) gesteuert. Je nach Belegung einzelner "Eingangs-Pins" mit 
High oder Low sollen unterschiedliche Frequenzfolgen durchlaufen. Die 
Hardware steht und sollte soweit auch fehlerfrei sein. Meine Software 
macht mir jedoch immer das selbe Signal: 1 Sekunde Auslösen 1 Sekunde 
Pause, egal was en den Eingangspins anliegt.

Die Beschaltung des Kontrollers sieht wie folgt aus:

 Pin 1 - PB5 - RESET (steht auf High=5V)
 Pin 2 - PB3 - Schalter (High <-> Low)
 Pin 3 - PB4 - Schalter (High <-> Low)
 Pin 4 - GND
 Pin 5 - PB0 - Schalter (High <-> Low)
 Pin 6 - PB1 - Ausgang -> Optokoppler (über Widerstand)
 Pin 7 - PB2 - nicht belegt
 Pin 8 - VCC (5V)

Und hier der verwendete Quellcode:

/*
* AVRSimpleTrigger.asm
*
*  Created: 06.01.2012 23:43:25
*   Author: Mathias
*
* Dieses Programm steuert einen Auslöser für meine DSLR.
* Vom Prinzip ist es nur ein einfacher Rechteck-Signal-Generator
* der einen Optokoppler ansteuert. Je nach Beschaltung der 
* "Eingangspins" (Pinbelegung siehe unten) werden unterschiedliche
* Rechtecksignale erzeugt.
*/

.include "tn13def.inc"         ; Definitionsdatei für den Prozessortyp einbinden

.def temp = r16        ; temporäres Register
.def temp2 = r22     ; zweites temporäres Register

.def warten1 = r17     ; Register für Pauseschleife
.def warten2 = r18     ; Register für Pauseschleife
.def warten3 = r19     ; Register für Pauseschleife

.def warten4 = r23     ;Register für Pauseschleife
.def abfrage = r20     ; Register um Taster einzulesen
.def hilfsregister = r21    ;  zweites Register um Taster einzulesen


// Interrupts

.org 0x000
       rjmp main
.org INT0addr
        reti        ;External Interrupt0
.org PCI0addr
        reti    ;External Interrupt Request 0
.org OVF0addr
        reti    ;Timer/Counter0 Overflow
.org ERDYaddr
        reti        ; EEPROM Ready
.org ACIaddr
        reti        ; Analog Comparator
.org OC0Aaddr
        reti    ; Timer/Counter Compare Match A
.org OC0Baddr
        reti    ; Timer/Counter Compare Match B
.org WDTaddr
        reti        ; Watchdog Time-out
.org ADCCaddr
        reti        ; ADC Conversion Complete

.org INT_VECTORS_SIZE



// Hauptprogramm
main:

// Initialisierung

    cli                 ;Interrupts ausschalten

    // Stack initialisieren
    ldi temp, RAMEND    ; Stackpointer initialisieren
    out SPL, temp

    //Prescaller
    ldi temp, (1<<CS02) | (0<<CS01) | (0<<CS00) ; Prescaler auf 256 gestellt
    out TCCR0B, temp

    //Pinbelegung

  // Verwendeter Kontroller: Attiny 13
  // Pin 1 - PB5 - RESET (steht auf High)
  // Pin 2 - PB3 - Schalter (High <-> Low)
  // Pin 3 - PB4 - Schalter (High <-> Low)
  // Pin 4 - GND
  // Pin 5 - PB0 - Schalter (High <-> Low)
  // Pin 6 - PB1 - Ausgang -> Optokoppler
  // Pin 7 - PB2 - nicht belegt
  // Pin 8 - VCC

    //Ein- und Ausgänge festlegen (PB1 -> Ausgang, PB0 und PB3 - PB5 -> Eingänge)
    ldi temp, 0b11000110
    out DDRB, temp

    //PB liegen allesamt auf Vcc (PB2 und PB3 - PB5 -> Pullupwiderstände deaktiviert)
    ldi temp, 0b11000110
    out PORTB, temp

  sei          ; Interrupts aktivieren

     //Rechtecksignalerzeugung
ende:
    // Exteren Schalter abfragen
    nop
    nop
    in abfrage, PORTB
    nop
    nop


    //Auswahl (Durch externe Schalter)
  // der unterschiedlichen Rechtecksignale.
  // Eine Sekunde wird ein Schalter gedrückt, dann eine
  // bestimmte Zeit lang pause gedrückt.

  // Pausezeit eine Sekunde
    andi abfrage, 0b00011001
  mov temp2, abfrage
  ldi temp, 1
    cpi  abfrage, 0b00000000
    breq PWM

  // Pausezeit 2 Sekunden
  mov abfrage, temp2
  ldi temp, 2
    cpi  abfrage, 0b00000001
    breq PWM

  // Pausezeit 4 Sekunden
  mov abfrage, temp2
  ldi temp, 4
  cpi  abfrage, 0b00010000
    breq PWM

  // Pausezeit 8 Sekunden
  mov abfrage, temp2
  ldi temp, 8
  cpi  abfrage, 0b00001000
    breq PWM

  // Pausezeit 15 Sekunden
  mov abfrage, temp2
  ldi temp, 15
  cpi  abfrage, 0b00010001
    breq PWM

  // Pausezeit 30 Sekunden
  mov abfrage, temp2
  ldi temp, 30
  cpi  abfrage, 0b00001001
    breq PWM

  // Pausezeit 60 Sekunden
  mov abfrage, temp2
  ldi temp, 60
  cpi  abfrage, 0b00011000
    breq PWM

  // Hier wird ein Signal für eine Belichtungsreihe erzeugt.
  // Die werden für die Aufnahme von HDR-Bilder benötigt.

  mov abfrage, temp2
  cpi  abfrage, 0b00011001
    breq HDR

  rjmp ende


  // Erzeugung des Rechtecksignals
    PWM:
    cbi PORTB, 1 // PB2 wird auf GND gesetzt (Schalter geschlossen)
    rcall PWMWait_1Sekunde
    sbi PortB, 1  // PB2 wird auf Vcc gesetzt (Schalter offen)
        loop:
      rcall PWMWait_1Sekunde
      dec temp
      brne loop
    rjmp ende

  // Rechtecksignal für HDR
  HDR:
  // 1/60 - 1/15 - 1/4 - 1/1 - 4/1 - 16/1 Sekunden

    //--- (1/60)
    cbi PORTB, 1 //(Schalter geschlossen)
    rcall PWMWait_60zigstel_Sekunde //(1/60)
    sbi PortB, 1  //(Schalter offen)
    rcall PMWWait_4Sekunden
  
    //--- (1/15)
    cbi PORTB, 1 //(Schalter geschlossen)
    ldi temp, 4 //(1/15)
    loop3:
      rcall PWMWait_60zigstel_Sekunde
      dec temp
      brne loop3
    sbi PortB, 1  //(Schalter offen)
    rcall PMWWait_4Sekunden

    //--- (1/4)
    cbi PORTB, 1 //(Schalter geschlossen)
    ldi temp, 16
    loop4:
      rcall PWMWait_60zigstel_Sekunde //(1/4)
      dec temp
      brne loop4
    sbi PortB, 1  //(Schalter offen)
    rcall PMWWait_4Sekunden

    //--- (1/1)
    cbi PORTB, 1 //(Schalter geschlossen)
    rcall PWMWait_1Sekunde //(1/1)
    sbi PortB, 1  //(Schalter offen)
    rcall PMWWait_4Sekunden

    //--- (4/1)
    cbi PORTB, 1 //(Schalter geschlossen)
    ldi temp, 4 //(4/1)
    loop5:
      rcall PWMWait_1Sekunde
      dec temp
      brne loop5
    sbi PortB, 1  //(Schalter offen)
    rcall PMWWait_4Sekunden

    //--- (16/1)
    cbi PORTB, 1 //(Schalter geschlossen)
    ldi temp, 16 //(16/1)
    loop6:
      rcall PWMWait_1Sekunde
      dec temp
      brne loop6
    sbi PortB, 1  //(Schalter offen)
  loop11: rjmp loop11

rjmp ende

//---- 
// Hier stehen jede Menge Schleifen, die Zeit verbruachen um die
// gewünschten Pausen zu realisieren.
PWMWait_1Sekunde:
    ldi warten1, 255
    wait:
    nop
    nop
    nop
    nop
    nop
        ldi warten2, 206
        wait2:
            ldi warten3, 5
      nop
            wait3:
                dec warten3
                brne wait3
            dec warten2
            brne wait2
        dec warten1
        brne wait
ret

//
//PWMWait_60erSekunde

 PWMWait_60zigstel_Sekunde:
    nop
  nop
  nop
  nop
   ldi warten3, 15
      wait7:
                dec warten3
                brne wait7

  ldi warten1, 248
    wait4: 
        ldi warten2, 4
        wait5:
            ldi warten3, 4
      nop
            wait6:
                dec warten3
                brne wait6
            dec warten2
            brne wait5
        dec warten1
        brne wait4
   ret

// 4 Sekundenpause
  PMWWait_4Sekunden:
    ldi temp, 4 //(4sec Pause)
    loop8:
      rcall PWMWait_1Sekunde
      dec temp
      brne loop8
  ret

Da ich hier neu bin weiß ich nicht ob dieser Quellcode als lang gilt und 
habe ihn einfach in den Beitrag kopiert.

Bin für jede Idee dankbar. Kompilieren läßt sich das Ganze ohne Fehler.

VG
Matze

[Herr M. (herrmueller)]

Auf die Schnelle:

Du musst PINB abfragen , nicht   -   in abfrage, PORTB  -

mehr hab ich noch nicht gesehen


gruss HerrMueller

[Werner (Gast)]

Als erstes würde ich da die Schleiferei durch eine kleine Timer 
Zeitbasis ersetzen

Mathias Hoffmann schrieb:
> Meine Software macht mir jedoch immer das selbe Signal: 1 Sekunde
> Auslösen 1 Sekunde Pause, egal was en den Eingangspins anliegt.

Bist du sicher, dass der Prozessor nicht dauern einen Reset bekommt, zB. 
durch den Watchdog? Was sagt der Simulator zu deinem Programm? Verhält 
es sich da genauso?

[Mathias H. (Firma: keine) (matze_2)]

Danke für die Antworten!

Das mit PINB ist sicherlich eine, wenn nicht die Fehlerquelle.
Timer Sequenzen wären sicherlich schöner, aber da ich erst am Anfang 
stehe habe ich jetzt einfach mit Schritten Laufzeit verbraucht. 
Interrupts habe ich bewusst nichts angelegt. Ich kann sie natürlich über 
mein ganzes Programm über 'cli' ausschalten. Im Simulator sah das ganze 
bisher gut aus. Aber vielleicht habe ich da auch etwas falsch gemacht. 
Ich werde das mit dem PINB ausprobieren und mal sehen ob das ganze 
funktioniert.

Vielen Dank
Mathias

[Herr M. (herrmueller)]

> Das mit PINB ist sicherlich eine, wenn nicht die Fehlerquelle

Da die Tasten keine Reaktion zeigen, ist das 'Nicht Abfragen' der Tasten 
schon eine Fehlerquelle.

[Mathias H. (Firma: keine) (matze_2)]

Um mal nachzufragen: In der Simulation in AVRStudio kann ich einen 
'Physisch existierenden PIN' mit dem PINB-Register simulieren? Ist das 
korrekt?

[Magnus M. (magnetus)]

Ja.