ATmega32 Interrupt fehlerhaft

[Mathias D. (pfmd86)]

Hallo,
ich will bei einem Overflow von Timer0 einen Interrupt auslösen. 
Blöderweise springt der im Programm aber an die falsche Stelle. 
Eigentlich sollte er bei Overflow doch zum TIM0_OVF springen. In echt 
landet er aber auf dem letzen reti deer Interrupttabelle. Kann mir 
jemand sagen warum?

.include "m32def.inc"
.def  temp = r16
.def  leds = r18

jmp   RESET     ; Reset Handler
reti          ; IRQ0 Handler
reti          ; IRQ1 Handler
reti          ; IRQ2 Handler
reti          ; Timer2 Compare Handler
reti          ; Timer2 Overflow Handler
reti          ; Timer1 Capture Handler
reti          ; Timer1 CompareA Handler
reti          ; Timer1 CompareB Handler
reti          ; Timer1 Overflow Handler
reti          ; Timer0 Compare Handler
jmp   TIM0_OVF   ; Timer0 Overflow Handler
reti          ; SPI Transfer Complete Handler
reti          ; USART RX Complete Handler
reti          ; UDR Empty Handler
reti          ; USART TX Complete Handler
reti          ; ADC Conversion Complete Handler
reti          ; EEPROM Ready Handler
reti          ; Analog Comparator Handler
reti         ; Two-wire Serial Interface Handler
reti          ; Store Program Memory Ready Handler


RESET:
  ldi temp, HIGH(RAMEND)   ;Initialisierung Stackpointer
  out SPH,temp
  ldi  temp, LOW(RAMEND)
  out SPL, temp

  ldi temp, 0xff      ;PortB als Ausgang definieren
  out DDRB, temp
  
  ldi temp, 0b00000001
  out TIMSK, temp
  ldi temp, 0b00000001  ;Timer Teiler 1024
  out TCCR0, temp
    
  sei            ;Interrupt freigeben

  ldi leds,0xff
  out PORTB,leds

  jmp mainloop

mainloop:

  jmp mainloop


TIM0_OVF:
  dec leds
  out PORTB, leds
  reti

[spess53 (Gast)]

Hi

Deine Interruptvektortabelle ist falsch. 'reti' belegt nur 1 Word. Beim 
ATMega32 werden aber an jeder Stelle 2 Word (jmp xyz) erwartet. Mach 
einfach nach jedem reti noch ein nop.

MfG Spess

[Mathias D. (pfmd86)]

spess53 schrieb:
> Hi
>
> Deine Interruptvektortabelle ist falsch. 'reti' belegt nur 1 Word. Beim
> ATMega32 werden aber an jeder Stelle 2 Word (jmp xyz) erwartet. Mach
> einfach nach jedem reti noch ein nop.
>
> MfG Spess

 Super... und schon geht das...
Ist das generell so beim ATMega32?

Wenn ich aber im Programm nur einen Zyklus warten will kann ich doch ein 
einzelnes "nop" setzen oder? Also ich will den Hintergrund verstehen und 
nicht nur abschreiben.

[spess53 (Gast)]

Hi

>Ist das generell so beim ATMega32?

Gilt für alle AVRs mit Flash >=16k

>Wenn ich aber im Programm nur einen Zyklus warten will kann ich doch ein
>einzelnes "nop" setzen oder? Also ich will den Hintergrund verstehen und
>nicht nur abschreiben.

Im dem Fall nicht. Da wird einfach der Abstand der RETIs um ein Word 
vergrößert.

MfG Spess

[Lueger (Gast)]

Große AVR haben einen Adressraum, der mit relativen Sprungbefehlen nicht 
mehr ganz zugänglich ist. Bei diesen hat die Sprungliste Einträge mit 
jeweils zwei Worten Länge. Etwa so:

   jmp Main ; Reset, Sprung zur Initiierung
   jmp Int0Sr ; Externer Interrupt an INT0, Sprung zur Service-Routine
   reti ; Irgendein anderer Interrupt, nicht benutzt
   nop
   jmp IntTc0OvflwSr ; Überlauf Timer 0, Behandlungsroutine
   reti ; Irgendwelche anderen Interrupts, nicht benutzt
   nop
   reti ; Und noch mehr Interrupts, auch nicht benutzt
   nop

Bei Ein-Wort-Einträgen (z.B. RETI) sind die NOP-Instruktionen eingefügt, 
um ein weiteres Wort zu ergänzen, damit die Adressierung der 
nachfolgenden Sprungziel-Einträge wieder stimmt.

siehe http://www.avr-asm-tutorial.net/avr_de/interrupts/int_vektor.html

[Lueger (Gast)]

Mit dem AVR Studio Simulator siehst du das sofort...

[Fabian (Gast)]

Nimm statt des Reti lieber ein

jmp  UnhandledInterruptHandler

Dann siehst Du wenigstens gleich, wenn ein Interrupt auslöst, mit dem Du 
nicht rechnest.