16-Bit Zahl durch eine Konstante dividieren (Assembler)

[Anton (Gast)]

Hallo Leute,
ich bräuchte für Umrechnung der Entfernung in cm eine Divisionsroutine, 
die mir eine 16-bit Zahl durch eine konstante 8-Bit Zahl dividieren 
würde (genauer gesagt ist diese Konstante 58).
Ich programmiere in Assembler, auf dem Atmega8.
Habe sehr viele Beiträge bereits gelesen, konnte jedoch keine passende 
Lösung finden.
mfg Anton

[Pitz (Gast)]

Von Atmel gibts ne Appnote für Divisionen/Multiplikationen. Schau dir 
die an, entsprechende Routinen sind dabei (in ASM).

[Peter D. (peda)]

Da der ATmega einen Mul-Befehl hat, ist es einfacher mit dem Reziproken 
zu multiplizieren und das Ergebnis entsprechend nach rechts zu schieben.


Peter

[Anton (Gast)]

Peter Dannegger schrieb:
> Da der ATmega einen Mul-Befehl hat, ist es einfacher mit dem Reziproken
> zu multiplizieren und das Ergebnis entsprechend nach rechts zu schieben.
>
>
> Peter

könntest du das bitte näher erläutern, habe es nicht so ganz verstanden, 
wie es mit mul Befehl gehen soll ..
mfg Anton

[hsb (Gast)]

http://elm-chan.org/cc_e.html

[Peter D. (peda)]

Anton schrieb:
> könntest du das bitte näher erläutern

1/58 * 65536 = 1130

D.h. mit 1130 multiplizieren und um 16 Bits nach rechts schieben.


Peter

[... (Gast)]

Anton schrieb:
> habe es nicht so ganz verstanden, wie es mit mul Befehl gehen soll ..

* 565 shr 15

[eProfi (Gast)]

Du dividierst zuerst durch 64 und addierst einen Korrekturfaktor.

z.B.
10000/58=172,413
10000/64=156   156,25/8=19  /8=2  /4=0 /2=0
156+19-2-0-0=173

anderes Beispiel:
65536/58=1129,931
65536/64=1024   /8=128  /8=16  /4=4  /2=2
1024+128-16-4-2=1130


Oder wie Peter beschrieben hat, nur statt shr16  vom 32-bit-Ergebnis nur 
das upper-word verwenden.


Abhängig vom Eingangsbereich kannst Du vorher noch erweitern, um besser 
runden zu können.

[Martin (Gast)]

Es ginge auch ganz klassisch:
Vom Dividend solange den Divisor abziehen und mitzählen bis das 
Subtraktionsergebnis negativ wird. Dann wieder einen Schritt rückgängig 
machen und du hast dein Ergebnis + Rest.

[Benjamin S. (recycler)]

8bit = 256 Werte
Wenn du genügend Speicher dafür hast, dann kannst du es auch über eine 
Lookuptabelle machen. Ist schneller, erfordert aber Vorarbeit.

[Johann L. (gjlayde)]

Anton schrieb:
> Peter Dannegger schrieb:
>> Da der ATmega einen Mul-Befehl hat, ist es einfacher mit dem Reziproken
>> zu multiplizieren und das Ergebnis entsprechend nach rechts zu schieben.
>>
>> Peter
>
> könntest du das bitte näher erläutern, habe es nicht so ganz verstanden,
> wie es mit mul Befehl gehen soll ..
> mfg Anton

Einfach nem guten C-Compiler bei der Arbeit zuschauen ;-)
 

unsigned int div58 (unsigned int x)
{
    return x/58;
}

 
übersetzt  avr-gcc zu (r24 = r24 / 58):
 

div58:
  movw r18,r24   ;  6  *movhi/1  [length = 1]
  ldi r26,lo8(-97)   ;  7  *movhi/5  [length = 2]
  ldi r27,lo8(70)
  call __umulhisi3   ;  8  *umulhi3_highpart_call  [length = 2]
  swap r25   ;  25  *lshrhi3_const/5  [length = 6]
  swap r24
  andi r24,0x0f
  eor r24,r25
  andi r25,0x0f
  eor r24,r25
  ret   ;  24  return  [length = 1]

 
Für __umulhisi3 siehe

http://gcc.gnu.org/viewcvs/trunk/libgcc/config/avr/lib1funcs.S?view=markup#l357

[Johann L. (gjlayde)]

Und falls es allgemeiner sein soll und langsamer sein darf:

#define VAL     24
#define REST    22
#define CNT     20
#define DIVISOR 21

;; REST <- VAL % DIVISOR
;; VAL  <- VAL / DIVISOR

udivmod16_8:
    clr     REST
    ldi     CNT,    16

2:  lsl     VAL
    rol     VAL+1
    rol     REST
    cp      REST, DIVISOR
    brlo 3f
    inc     VAL
    sub     REST, DIVISOR
3:  dec     CNT
    brne 2b
    ret

[Jürgen (Gast)]

Meine Version.
Die 10 unten in 58 ändern

;--------------------------------------------------------------------------------
  ;    16Bit Division durch 8Bit Konstante. In diesem Fall 10.
  ;    Übergaberegister & Ergebniss in temp2/temp3 (low/high), Rest = temp1
  ;--------------------------------------------------------------------------------
div:ldi    temp4,16    ;16* schieben
  clr    temp1      ;Rest =0
dv1:lsl    temp2      
  rol    temp3
  rol    temp1
  cpi    temp1,10    ;Solange Bits in temp1 (Rest) schieben bis >= 10
  brcs  dv2        ;Wenn der Rest <10 ist, das 0-Bit in temp2 (LSL, oben) stehen lassen
  inc    temp2      ;Ansonsten Bit0 setzen und 10 vom Rest abziehen
  subi  temp1,10    
dv2:dec    temp4      ;Das ganze 16 mal
  brne  dv1  
  ;-------------------------------------------------
  ;        Ende Div Routine.

[Thomas G. (tomatos666)]

Hallo,

sorry das ich das alte Thema ausgrabe.
Der Code von Jürgen Funktioniert aber nur mit Werten unter 100 oder?
Mit 158 kommt bei mir ein Falsches Ergebis raus nämlich statt 414 kommt 
388.

[Peter D. (peda)]

Thomas Gruber schrieb:
> Der Code von Jürgen Funktioniert aber nur mit Werten unter 100 oder?

Nur bis 127.
Willst Du bis 255, mußt Du noch den Übertrag bei "rol temp1" 
berücksichtigen.