UART mit Atmega8 und FTDI FT232RL

[DeepSpace (Gast)]

Guten Abend,

ich habe eine Schaltung mit einem Atmega8 uC aufgebaut und will Daten 
mit UART an den PC schicken. Da ich keine RS-232 Schnittstelle habe, 
habe ich einen FTDI FT232RL Driver angeschlossen. Der Simuliert am USB 
eine RS-232 Schnittstelle. Einen MAX232 benötige ich dann ja nicht mehr, 
weil der ja schon mit 5V vom USB aus arbeitet. Jedenfalls habe ich 
versuchshalber den Quellcode aus euerm Tutorial ausprobiert und auf 
hTerm bekomme ich nur kryptische Zeichen. Ein totales durcheinander.

.include "m8def.inc"
 
.def temp    = r16                              ; Register für kleinere Arbeiten
.def zeichen = r17                              ; in diesem Register wird das Zeichen an die
                                                ; Ausgabefunktion übergeben
 
.equ F_CPU = 4000000                            ; Systemtakt in Hz
.equ BAUD  = 9600                               ; Baudrate
 
; Berechnungen
.equ UBRR_VAL   = ((F_CPU+BAUD*8)/(BAUD*16)-1)  ; clever runden
.equ BAUD_REAL  = (F_CPU/(16*(UBRR_VAL+1)))      ; Reale Baudrate
.equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)  ; Fehler in Promille
 
.if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))       ; max. +/-10 Promille Fehler
  .error "Systematischer Fehler der Baudrate grösser 1 Prozent und damit zu hoch!"
.endif
 
    ; Stackpointer initialisieren
 
    ldi     temp, HIGH(RAMEND)
    out     SPH, temp
    ldi     temp, LOW(RAMEND)
    out     SPL, temp
 
    ; Baudrate einstellen
 
    ldi     temp, HIGH(UBRR_VAL)
    out     UBRRH, temp
    ldi     temp, LOW(UBRR_VAL)
    out     UBRRL, temp
 
    ; Frame-Format: 8 Bit
 
    ldi     temp, (1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0)
    out     UCSRC, temp
 
    sbi     UCSRB,TXEN                  ; TX aktivieren
 
loop:
    ldi     zeichen, 'T'
    rcall   serout                      ; Unterprogramm aufrufen
    ldi     zeichen, 'e'
    rcall   serout                      ; Unterprogramm aufrufen
    ldi     zeichen, 's'
    rcall   serout                      ; ...
    ldi     zeichen, 't'
    rcall   serout
    ldi     zeichen, '!'
    rcall   serout
    ldi     zeichen, 10
    rcall   serout
    ldi     zeichen, 13
    rcall   serout
    rcall   sync                        
    rjmp    loop
 
serout:
    sbis    UCSRA,UDRE                  ; Warten bis UDR für das nächste
                                        ; Byte bereit ist
    rjmp    serout
    out     UDR, zeichen
    ret                                 ; zurück zum Hauptprogramm
 
; kleine Pause zum Synchronisieren des Empfängers, falls zwischenzeitlich
; das Kabel getrennt wurde
                                    
sync:
    ldi     r16,0
sync_1:
    ldi     r17,0
sync_loop:
    dec     r17
    brne    sync_loop
    dec     r16
    brne    sync_1  
    ret

Ich verwende einen 16MHz Quarz, entsprechende Fuse-Bits müssten richtig 
gesetzt sein. Ist vielleicht der Systemtakt falsch oder muss ich im Code 
noch etwas ändern? Ein Oszilloskop besize ich leider (noch) nicht.

Danke im Voraus! Gute Nacht!

[Ralf (Gast)]

Und das hTerm ist richtig konfiguriert?

Ralf

[Daniel (Gast)]

Wenn du einen 16MHz Quartz hast, musst du "F_CPU" auch entsprechen 
einstellen (16000000)!!!

[DeepSpace (Gast)]

Habe schon alle möglichen Einstellungen ausprobiert, aber immer noch 
kommt nur Zeichensalat. Was gibts an hTerm außer der Baudrate noch groß 
zu konfigurieren?

Kann es sein, dass der FT232RL die Signale irgendwie verändert, z.B. 
negiert?

[amateur (Gast)]

Hast du mal den originalen FTDI-Treiber mal ausprobiert/installiert?
Außer im Zusammenhang mit Elektrostatik habe ich mit den Teilen noch nie 
Probleme gehabt.
Ist eventuell die COM-Port-Nummer aus den Ruder gelaufen? Bei jedem 
neuen USB-Seriell-Wandler wird der zugeordnete Port erhöht. Wenn mich 
nicht alles täuscht bis COM99. Damit haben allerdings manche Programme 
Schwierigkeiten, wenn sie nur einstellige Ports vorgesehen haben.

[DeepSpace (Gast)]

Der richtige Treiber läuft und die Port-Nummer ist COM2.
Eigentlich alles richtig eingestellt und trotzdem kommen nur Vierecke 
und anderer Salat im Terminal!???

[Stefan F. (sfrings)]

Kreise den Fehler ein, anstatt herum zu raten. Vorschlag:

Nimm den AVR aus dem Sockel heraus und stecke eine Drahtbrücke von RxD 
nach Txd. Sende damm im Terminal Programm ein paar Zeichen und prüfen, 
ob sie als Echo zurück kommen.

Wenn DU dann immer noch falsche Zeichen empfängst, dass liegt das 
Problem nicht beim AVR.

[Teddynator (Gast)]

Daniel schrieb:
> Wenn du einen 16MHz Quartz hast, musst du "F_CPU" auch entsprechen
>
> einstellen (16000000)!!!

den Hinweis schon beachtet? Hier wird dein Problem liegen. Das musst du 
im Code ändern

[DeepSpace (Gast)]

Ich habe alles im Code geändert, mit verschiedenen Einstellungen am 
Quarz experimentiert, verschiedene Baud-Raten eingestellt, den internen 
RC-Resonator ausprobiert... nichts hilft.

Wenn ich TXD und RXD verbinde empfange ich richtige Symbole. Ich probier 
jetzt noch einen anderen Atmega8 aus und wenn das dann immer noch nichts 
bringt hab ich halt pech.

Trotzdem Danke für eure Bemühungen!!!

[DeepSpace (Gast)]

Hat auch nichts genützt. Ich hab absolut keine Ahnung mehr.

[Stefan++ (Gast)]

DeepSpace schrieb:
> Kann es sein, dass der FT232RL die Signale irgendwie verändert, z.B.
> negiert?

Ja, das kann man eistellen !!!
Hole dir die geeignete Software FT_PROG von FTDI und schau nach !

[Eumel (Gast)]

Prüfe doch 'mal den Takt (Ausgang toggeln) und schauen ob die Zeit 
stimmt.

[DeepSpace (Gast)]

Oh mann,

die Aus- und Eingänge waren negiert und noch einige andere Einstellung 
daneben geraten!!! Jetzt kommt das was ich wollte!

Vielen Dank für eure umfangreiche und schnelle Hilfe!!! Hochachtung...!