Ende einer Sprungtabelle ermitteln

[Uwe (Gast)]

Hallo,

ich verwende in meinem Programm eine Sprungtabelle:

 MeinTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine2
    ...

Mit folgendem Code "navigiere" ich durch die Tabelle:

    ldi ZL, LOW(MeinTab)
    ldi ZH, HIGH(MeinTab)
    ...
    adiw    ZH:ZL, 1
    ...

Gibt es eine elegante Lösung um festzustellen, wann das Ende der Tabelle 
erreicht ist, z.B ohne ein Register als Zähler zu verwenden.

Beim SRAM ist dies ja folgendermaßen möglich:

        .equ maxadress = $0070
        ...
  LDI   temp2,low (maxAdress)
  LDI   temp3,high(maxAdress)
  CP    temp2,XL
  CPC   temp3,XH
  BRCC  ENDE
        ...

Gibt es eine Lösung für den Programmspeicher? D.h. kann ich irgendwie 
das Ende der Tabelle definieren?

MfG
Uwe

[Karl H. (kbuchegg)]

Uwe schrieb:

> Beim SRAM ist dies ja folgendermaßen möglich:
>
>         .equ maxadress = $0070
>         ...
>   LDI   temp2,low (maxAdress)
>   LDI   temp3,high(maxAdress)
>   CP    temp2,XL
>   CPC   temp3,XH
>   BRCC  ENDE
>         ...
>
> Gibt es eine Lösung für den Programmspeicher? D.h. kann ich irgendwie
> das Ende der Tabelle definieren?

Du kannst natürlich an das Ende der Tabelle ein Label setzen und dann 
mit der Adresse des Labels operieren.

...

MeinTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine2
MeinTabEnde:


In Anlehung an dein SRAM Beispiel dann eben

   LDI   temp2,low (MeinTabEnde)
   LDI   temp3,high(MeinTabEnde)
   CP    temp2,XL
   CPC   temp3,XH
   BRCC  ENDE


Sieh dir doch mal in der Hilfe zum AVR-Assembler gleich im ersten 
Kapitel 'User's Guide' den Abschnitt 'Expressions' an. Da kann man so 
einiges vom Assembler berechnen lassen.

[Uwe (Gast)]

Hallo Karl Heinz!

Danke!! Werd ich gleich mal ausprobieren!
Ist es sicher dass der Assembler das nächste Label(MeinTabEnde) 
grundsätzlich in die direkt folgende Speicheradresse schreibt?

Gruss
Uwe

[Karl H. (kbuchegg)]

Uwe schrieb:
> Hallo Karl Heinz!
>
> Danke!! Werd ich gleich mal ausprobieren!
> Ist es sicher dass der Assembler das nächste Label(MeinTabEnde)
> grundsätzlich in die direkt folgende Speicheradresse schreibt?

Ich denke du meinst das richtige, auch wenn du dich schlecht ausdrückst. 
Denn bei einem Label wird gar nichts 'geschrieben'. Ein Label ist 
einfach nur ein symbolischer Name für eine bestimmte Speicheradresse. 
Eben die, an der der nächste Befehl im Speicher zu liegen kommt.

Und ja. Der Assmbler baut da KEINE Lücken ein. Im Beispiel:

MeinTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine2
MeinTabEnde:
    NOP

bezeichnet MeinTabEnde die nächste Speicheradresse unmittelbar nach dem 
letzten RJMP, also die Adresse im Speicher, an der der Befehl NOP liegt.
Der Assembler legt alle Befehle immer hintereinander in den Speicher. Er 
darf da nicht nach Gutdünken irgendwelche Lücken lassen.

(Aufpassen auf den Unterschied zwischen Byteadressierung und 
Wortadressierung. Aber den Unterschied kennst du ja ohnehin, weil du ihn 
ja beim Aufbau der Sprungtabelle auch berücksichtigen musstest. Ein 
Label ist eine Wortadresse. Demzufolge ergibt dann auch der Ausdruck
    MeinTabEnde - MeinTab
die Anzahl der Einträge in deiner Sprungtabelle. Denn ein kompletter 
RJMP ist ja 2 Bytes - 1 Wort - groß.

    ldi r16, MeinTabEnde - MeinTab

....

MeinTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine2
MeinTabEnde:

R16 wird mit dem Wert 3 geladen, weil die Tabelle aus 3 RJMP besteht.
Du hättest genausogut

    ldi r16, 3

schreiben können. De facto ist das sogar dasselbe, nur eine andere 
Schreibweise. Nur brauch ich dir sicherlich nicht erzählen, warum die 
Variante 'der Assembler soll das ausrechnen' besser ist als 'ich als 
Programmierer zähle die RJMP'. Denn anderst du die 'Tabelle' ab auf

MeinTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine2
    RJMP Routine2
    RJMP Routine2
MeinTabEnde:

dann wird r16 mit dem Wert 5 geladen, ohne dass du am LDI was ändern 
musst. Der Assembler rechnet dir aus der Differenz der beiden Adressen 
aus, wieviele Worte (und damit wieviele RJMP) dazwischen liegen.

Lass den Assembler für dich arbeiten!

[Uwe (Gast)]

Karl Heinz schrieb:

"...MeinTabEnde die nächste Speicheradresse unmittelbar nach dem
letzten RJMP, also die Adresse im Speicher, an der der Befehl NOP liegt.
Der Assembler legt alle Befehle immer hintereinander in den Speicher. Er
darf da nicht nach Gutdünken irgendwelche Lücken lassen."

Genau das meinte ich mit meiner Frage. Vielen Dank für ausführliche 
Erklärung!

Grüsse
Uwe

[Cube (Gast)]

Karl Heinz Buchegger schrieb:
> Er
> darf da nicht nach Gutdünken irgendwelche Lücken lassen.

Wobei es durchaus Direktiven zur Steuerung des "Layouts" gibt, z.B. 
"ORG".

[Uwe (Gast)]

Nachdem ich den Code ausprobiert habe ist mir etwas Seltsames 
aufgefallen! Solange sich die Sprungtabelle am Ende der des Quelltextes 
(ca 700 Zeilen) befand, hat der BRCC Sprung nicht funktioniert:
   ...
   LDI   temp2,low (MeinTabEnde)
   LDI   temp3,high(MeinTabEnde)
   CP    temp2,XL
   CPC   temp3,XH
   BRCC  ENDE
   ...

Erst als ich die Tabelle in unmittelbare Nähe (genau genommen über die 
o.g Subroutine) verschoben habe, hat der Code funktioniert. Verhält es 
sich hier wie mit mit dem brsh-Befehl (nur maximal 63 Worte weit 
springen). Oder evtl. buggy??

Mfg
Uwe

[Spess53 (Gast)]

Hi

>Verhält es
>sich hier wie mit mit dem brsh-Befehl (nur maximal 63 Worte weit
>springen). Oder evtl. buggy??

Alle bedingte relative Sprünge haben diese Beschränkung.

MfG Spess

[Jürgen (Gast)]

Uwe schrieb:
> ich verwende in meinem Programm eine Sprungtabelle:
>
>  MeinTab:
>     RJMP Routine1
>     RJMP Routine2
>     RJMP Routine2
>     ...
>
> Mit folgendem Code "navigiere" ich durch die Tabelle:
>
>     ldi ZL, LOW(MeinTab)
>     ldi ZH, HIGH(MeinTab)
>     ...
>     adiw    ZH:ZL, 1
>     ...
>
> Gibt es eine elegante Lösung um festzustellen, wann das Ende der Tabelle
> erreicht ist, z.B ohne ein Register als Zähler zu verwenden.

Außer die Endadresse der Tabelle zu vergleichen, gibt es auch noch die 
Möglichkeit, ans Ende der Tab eine Null anzuhängen. Diese kann dann 
einfach mit tst überprüft werden.

Oder -

Als letzten Tabelleneintrag rjmp ResetTab, welcher deinen Tabellenzeiger 
zurücksetzt.

Welche Möglichkeit für dich am besten ist, hängt natürlich vom weiteren 
Aufbau deines Programms ab.

[Sascha W. (sascha-w)]

@Uwe,

was ich nicht verstehe - warum schreibst du Sprungbefehle in die 
Sprungtabelle? So wie du es jetzt hast, springst du mit ijmp in die 
Tabelle und dort gehts weiter zum eigentlichen Ziel.

Mach es so, das in der Tabelle nur die Zieladressen stehen, denn mit 
deinen jrmp in der Tabelle wirst du auf Dauer auch nicht weit kommen.

Bsp:

MeinTab:   .dw  Routine1,Routine2,Routine2,0


Nav:
        ldi   zl,low(MeineTab*2)
        ldi   zh,high(MeineTab*2)

  ;zum nächsten Element
        adiw  Z,2

  ;Element holen
        lpm   xl,Z+
        lpm   xh,Z+       ;Sprungziel laden
        mov   r16,xl
        or    r16,xh      ;Ziel 0x0000? -> ENDE
        breq  tab_Overflow
  ;Element aufrufen
        movw  z,x
        ijmp

das Ende in dieser Form an die Tabelle anzuhängen, bringt natürlich nur 
was, wenn mann die Elemente nacheinander abruft. Es nützt nichts, wenn 
du 3 Sprungziele hast und versuchst das Ziel 5 abzurufen.

Sascha

[Uwe (Gast)]

Danke Sascha für die Alternative, aber ich will es erstmal mit der 
ersten Variante versuchen!

Im Moment hab ich folgendes Problem (ich hab den Code abgeändert bzw. 
stark vereinfacht um das Problem besser beschreiben zu können):

main:
  rcall TabDurchlaufen
rjmp main



TabDurchlaufen:
        push  temp2
        push  temp3
  adiw    ZH:ZL, 1
  LDI   temp2,low (MeineTabEnde)
  LDI   temp3,high(MeineTabEnde)
  CP    temp2,ZL
  CPC   temp3,ZH
  BRCC  ENDE
  ldi ZL, LOW(MeinTab)
        ldi ZH, HIGH(MeinTab)
loop:
  ldi temp1, 'k'  ;Text am LCD ausgeben wenn TabEnde erreicht
        rcall lcd_data  ;LCD Ausgabe
  rjmp loop
ENDE:
        pop  temp3
        pop  temp2
  ret



MeineTab:
    RJMP Routine1
    RJMP Routine2
    RJMP Routine3
    RJMP Routine4
MeineTabEnde:

Funktioniert so perfekt, die Tabelle wird durchlaufen und das Programnm 
endet in der "loop"-Schleifen bzw. Text wird am LCD ausgegeben. Sobald 
ich jedoch den "icall"-Befehl hinzufüge, um die einzelnen Routinen 
aufzurufen, wird das Tabellenende nicht mehr erkannt, d.h. das Programm 
endet nicht in der "loop"-Schleife.
...
main:
  rcall TabDurchlaufen
  icall  ;diesmal mit icall
rjmp main
...

Hat vielleicht jemand eine Idee?
MfG
Uwe

[Sascha W. (sascha-w)]

Hallo,

sind die Routinen auch mit ret abgeschlossen?
Wird zwischen "TabDurchlaufen" und icall noch was anderes gemacht was 
dir Z verändert?
Wird Z innerhalb der Routinen verändert?

Es währe es sowieso besser am Ende von "TabDurchlaufen" kein ret, 
sondern ein ijmp zu setzen, das ret aus der Routine führt dann direkt 
zurück zu Main.

Sascha

[Uwe (Gast)]

Hi,

das Z Register wird durch die Routinen definitiv nicht verändert. Hab 
testweise den kompletten Code aus den Routinen gelöscht um 
sicherzugehen.

Ich hab es auch mal mit ijmp versucht. Gleiches Resultat. Sobald ich 
ijmp oder icall aufrufe, wird das Ende der Tabelle nicht erkannt.

Grüsse
Uwe

[Karl H. (kbuchegg)]

Uwe schrieb:
> Hi,
>
> das Z Register wird durch die Routinen definitiv nicht verändert. Hab
> testweise den kompletten Code aus den Routinen gelöscht um
> sicherzugehen.
>
> Ich hab es auch mal mit ijmp versucht. Gleiches Resultat. Sobald ich
> ijmp oder icall aufrufe, wird das Ende der Tabelle nicht erkannt.

Und was ergibt ein Single Step durch den Code?

Im Simulator vom AVR-Studio hast du doch eine Anzeige aller Register und 
wie sie sich von Schritt zu Schritt verändern. Geh halt mal den Teil in 
Einzelschritten durch (F11) und sieh dir an, was die Register machen, 
was am Stack liegt etc. etc.

[Sascha W. (sascha-w)]

> Uwe schrieb:
>> Hi,
>> Ich hab es auch mal mit ijmp versucht. Gleiches Resultat.
na was denn nun - sind die Routinen die du aufrufst mit ret 
abgeschlossen oder nicht!? Wenn ja hat ijmp ja keinen Sinn, wenn nein 
was passiert dann am Ende der Routinen.
Was willst du überhaupt mit dem Program und diesem Aufbau bezwecken?

Sascha

[Uwe (Gast)]

Ja, die Routinen sind mit ret abgeschlossen.
Mit der Tabelle möchte ich ein Menü realisieren.

Uwe

[Sascha W. (sascha-w)]

Uwe schrieb:
> Im Moment hab ich folgendes Problem (ich hab den Code abgeändert bzw.
> stark vereinfacht um das Problem besser beschreiben zu können):

vielleicht solltest du doch wieder etwas mehr Code zeigen um das Problem 
besser lösen zu können.

Sascha

[Spess53 (Gast)]

Hi

Mit ein paar Korrekturen ist dein Programm auch mit 'ijmp' lauffähig:

.include "m8def.inc"

RESET:
  ldi r16,high(RAMEND)
  out SPH,r16
  ldi r16,Low(RAMEND)
  out SPL,r16

  LDI   ZL,low (MeineTab-1)
  LDI   ZH,high(MeineTab-1)

main:
  rcall TabDurchlaufen
rjmp main

TabDurchlaufen:
  push  r17
  push  r18
  adiw    ZH:ZL, 1
  LDI   r17,low (MeineTabEnde)
  LDI   r18,high(MeineTabEnde)
  CP    ZL,r17
  CPC   ZH,r18
  BRCC  ENDE

  icall
  rjmp return

ende:
  LDI   ZL,low (MeineTab-1)
  LDI   ZH,high(MeineTab-1)

return:
  pop  r18
  pop  r17
  ret

MeineTab:
  RJMP Routine1
  RJMP Routine2
  RJMP Routine3
  RJMP Routine4
MeineTabEnde:

Routine1:          ret
Routine2:          ret
Routine3:          ret
Routine4:          ret

MfG Spess

[Uwe (Gast)]

Danke! Werde ich gleich mal ausprobieren.

Mir ist in der AVR Studio Simulation aufgefallen, dass die Carry Flag 
nicht gesetzt wird, auch wenn die Registerpaare temp2,temp3 und ZL,ZH 
die gleichen Werte haben. Also der Sprung Brcc wird jedesmal ausgeführt, 
da die Carry Flag nie gesetzt wird!
  ...
  LDI   temp2,low (MeineTabEnde)
  LDI   temp3,high(MeineTabEnde)
  CP    temp2,ZL
  CPC   temp3,ZH
  BRCC  ENDE
  ...


Gruss
Uwe

[Spess53 (Gast)]

Hi

>Also der Sprung Brcc wird jedesmal ausgeführt,
>da die Carry Flag nie gesetzt wird!

Deswegen habe ich die Vergleiche auch umgedreht.

MfG Spess

[Sascha W. (sascha-w)]

Uwe schrieb:
> Mir ist in der AVR Studio Simulation aufgefallen, dass die Carry Flag
> nicht gesetzt wird, auch wenn die Registerpaare temp2,temp3 und ZL,ZH
> die gleichen Werte haben.
was anderes ist auch nicht zu erwarten:
Gleichheit der Werte erzeugt nun mal keinen Übertrag, der entsteht erst, 
wenn der zweite Operand größer als der erste ist (bei cp, sub, ...).


Sascha

[Uwe (Gast)]

Danke! hat auf Anhieb funktioniert!

Mit Vergleich umgedreht meinst du:


  CP    ZL,r17
  CPC   ZH,r18

  statt

  CP    r17, ZL
  CPC   r18, ZH

Den Fehler hatte ich glatt übersehen.
Danke Nochmals!!!


Grüsse
Uwe