Value >255 von Processing zum Ardu und zurück

[Ruediger (Gast)]

Guten Tag die Herrschaften,

ich versuche gerade eine Kommunikation zwischen Arduino und Processing 
herzustellen.
Processing liest ja recht einfach Daten vom Seriellen Port, nur leider 
will der Ardu nicht das lesen was vom Processing kommt.

Ich glaube irgendwas mache ich falsch mit dem Handling der "Datentypen".
Soweit ich das verstanden hab wird "port.write" nur Werte bis 255 auf 
den Port schicken.

Zum Code:
Ein einfacher Slider in Processing soll seinen Wert an den Ardu 
schicken, dort will ich den Sliderwert später zum einstellen eines 
Schwellwertes nutzen.
Mittels Funktionsprüfung soll einfach nur die LED 13 an/aus gehen.


Arudo-Code:

#define PIN13 13
int val;
void setup() 
{
  Serial.begin(9600);  
  pinMode(PIN13, OUTPUT);
}


void loop() {  
 // if(Serial.available() )
 // {
    val = Serial.read();
    Serial.println(val);
    
    
 //}

  if (val > 512)
  { 
    digitalWrite(PIN13, HIGH); // turn the LED on
  }
  else
  {
    digitalWrite(PIN13, LOW); // Otherwise turn it OFF
  }
  /*
  // read all analog ports, split by " " // adjust i<2 --> to is the amount of scanned analog port
   for (int i=0;i<2;i++){
   Serial.print(analogRead(i));
   Serial.print(" ");
   }
   */
  // frame is marked by Linefeed
  //Serial.println();
  //Serial.print (val);
}

Processing Code:

import processing.serial.*;
import controlP5.*;

Serial myPort;
int val;

ControlP5 cp5;
int myColor = color(0, 0, 0);

int sliderValue = 100;
int sliderValueOld = 100;

Slider abc;

void setup() {

  String portName = Serial.list()[1];
  myPort = new Serial(this, portName, 9600);
  myPort.bufferUntil('\n');
  size(700, 400);
  noStroke();
  cp5 = new ControlP5(this);

  // add a horizontal sliders, the value of this slider will be linked
  // to variable 'sliderValue' 
  cp5.addSlider("sliderValue")
    .setPosition(100, 50)
      .setSize(20, 100)
        .setRange(0, 1024)
          ;
}

void draw() {
  //background(sliderTicks1);

  fill(map(sliderValue,0,1024,0,255));
  rect(0, 0, width, 200);

  if (sliderValue != sliderValueOld)
  {
    sliderValueOld = sliderValue;
    println(sliderValue);
    
    if ( myPort.available() > 0) // If data is available,
    {
    sliderValue = sliderValue;  
    myPort.write(sliderValue);

    delay(100);
    int inVal = myPort.read();
    println(inVal);
      }
    }
  }

Beim Printen von "inVal" gibt Processing aber nur "0" aus.
Wie und an welcher Stelle muß ich die Datentypen aneinander anpassen?

[Karl H. (kbuchegg)]

Ruediger schrieb:

> Ich glaube irgendwas mache ich falsch mit dem Handling der "Datentypen".
> Soweit ich das verstanden hab wird "port.write" nur Werte bis 255 auf
> den Port schicken.´

Ganz genau.
Dieser read() bzw. write() Methoden, übrtragen nur jeweils 1 Byte.
Nur weil es dir erlaubt ist, da jeweils einen int (16 Bit) zu benutzen, 
heisst das noch lange nicht, dass da auch 16 Bit übertragen werden.

> Wie und an welcher Stelle muß ich die Datentypen aneinander anpassen?

So einfach ist die Sache nicht.
16 Bit überträgt man, in dem man 2 mal jeweils 8 Bit überträgt.

Nur: woher weiß der Empfänger welches das 1. Byte ist und welches das 
2.te? (Gemeint ist die Reihenfolge. Der Empfänger bekommt Byte auf Byte 
aus der Seriellen raus. Welches ist das jeweils 1. und welches das 2.?)

Und genau an dieser Stelle beginnt das Ganze interessant zu werden und 
du betrittst das Reich der sog. 'Übertragungsprotokolle', die unter 
anderem genau diese Dinge regeln.

[Ruediger (Gast)]

Ahoi,

Danke für die "Stichworte", bei der Gelegenheit konnte ich direkt 
nochmal üben wie man Funktionen schreibt.
Großer Teil ist leider CopyPaste, aber ich steig einigermaßen durch.

Hier mal der Code.

Ardu:

// BinaryDataFromProcessing
// Diese Definitionen mu¨ssen denen des Senders entsprechen:
const char HEADER = 'H';
const char SLIDER_TAG = 'S';
const char MOUSE_TAG = 'M';
const int TOTAL_BYTES = 6 ; // Gesamtgro¨ße der Nachricht
int schwelle = 0;
int schwellealt = 0;
int ledPin = 13;

void setup()
{
  Serial.begin(9600);
  pinMode(ledPin, OUTPUT); 

}
void loop(){
  Serialpost();  
  halbeschwelle();
}

void halbeschwelle(){
  if (schwelle >= 512)
  { 
    //Serial.println("LED AN");
    digitalWrite(ledPin, HIGH); // turn the LED on
  }
  else
  {
  //  Serial.println("LED AUS");
    digitalWrite(ledPin, LOW); // Otherwise turn it OFF
  }
}

void Serialpost(){
  if ( Serial.available() >= TOTAL_BYTES)
  {
    if( Serial.read() == HEADER)
    {
      char tag = Serial.read();
      if(tag == MOUSE_TAG)
      {
        int x = Serial.read() * 256;
        x = x + Serial.read();

        int y = Serial.read() * 256;
        y = y + Serial.read();
        Serial.print("Maus-Nachricht empfangen, x = ");
        Serial.print(x);
        Serial.print(", y = ");
        Serial.println(y);
      }
      else if(tag == SLIDER_TAG)
      {
        int x = Serial.read() * 256;
        x = x + Serial.read();
        schwelle = x;
        int y = Serial.read() * 256;
        y = y + Serial.read();
        schwellealt = y;
        Serial.print("Slider-Wert wurde geändert, Neu = ");
        Serial.print(x);
        Serial.print(", ALT = ");
        Serial.println(y);
      }
      else
      {
        Serial.print("Unbekannter Tag in Nachricht: ");
        Serial.write(tag);
      }
    }
  }
}

Processing:

import processing.serial.*;
import controlP5.*;
Serial myPort;
public static final char HEADER = 'H';
public static final char SLIDER_TAG = 'S';
public static final char MOUSE_TAG = 'M';
int val;
ControlP5 cp5;
int myColor = color(0, 0, 0);
int sliderValue = 100;
int sliderValueOld = 100;

Slider abc;

void setup() {

  String portName = Serial.list()[1];
  myPort = new Serial(this, portName, 9600);
  //myPort.bufferUntil('\n');
  size(700, 400);
  noStroke();
  cp5 = new ControlP5(this);

  // add a horizontal sliders, the value of this slider will be linked
  // to variable 'sliderValue' 
  cp5.addSlider("sliderValue")
    .setPosition(100, 50)
      .setSize(20, 100)
        .setRange(0, 1024);
}

void draw() {

  fill(map(sliderValue, 0, 1024, 0, 255));
  rect(0, 0, width, 200);
  SliderValueChanged ();
}

void SliderValueChanged () {
  if (sliderValue != sliderValueOld)
  {
    sendMessage(SLIDER_TAG, sliderValue, sliderValueOld);
    sliderValueOld = sliderValue;
  }
}

void mousePressed() {
  sendMessage(MOUSE_TAG, mouseX, mouseY);
}
void serialEvent(Serial p) {
  // handle incoming serial data
  String inString = myPort.readStringUntil('\n');
  if (inString != null) {
    print( inString ); // Textstring vom Arduino ausgeben
  }
}

void sendMessage(char tag, int x, int y) {
  // Sende gegebenen Tag und Wert an seriellen Port
  myPort.write(HEADER);
  myPort.write(tag);
  myPort.write((char)(x / 256)); // MSB
  myPort.write(x & 0xff); //LSB
  myPort.write((char)(y / 256)); // MSB
  myPort.write(y & 0xff); //LSB
}

Schöne Sache :D
Nun muß ich nur noch meine Sensordaten ans Proc schicken und 
visualiersieren.