Frage zu Enumerations

[Didi (Gast)]

Hallo,

in meinem Design habe ich ein Signal und ein Register definiert vom Typ 
color_type. color_type ist eine enumeration (so wie in C):

type color_type is (RED, GREEN, BLUE);

Gegenüber einem std_ulogic_vector erhöht es die Lesbarkeit. Ich würde 
deshalb auch in Entity-Ports color_type verwenden wollen.

Ist das eigentlch unproblematisch für die Synthese? Es sollte doch 
intern auf einen std_ulogic_vector mit 2 Bit abgebildet werden, oder? 
Was mich irritiert ist, das Quartus mir das Register von diesem Typ bei 
der Ressourcenanzeige unter "State Machines" auflistet...

[user (Gast)]

Ja, das ist kein Problem für die Synthese.

Wahrscheinlich beschreibst du damit eine "State Machine", deswegen wird 
das als solche ausgewiesen. Wie es dargestellt wird kannst du einstellen 
-> one hot / binary usw

[Klaus F. (kfalser)]

Didi schrieb:
> type color_type is (RED, GREEN, BLUE);
> Es sollte doch intern auf einen std_ulogic_vector
> mit 2 Bit abgebildet werden, oder?

Nein, darauf kann man sich so nicht verlassen, das hängt auch von den 
Compiler-Optionen ab.
Inbesonders wäre es nicht sauber, sich darauf zu verlassen dass RED auf 
0, GREEN auf 1 usw. gemappt wird.

Eine Möglichkeit wäre:

Subtype color_type is std_ulogic_vector(1 downto 0);
constant RED   : color_type := "00";
constant GREEN : color_type := "01";
constant BLUE  : color_type := "10";

[P. K. (pek)]

Klaus Falser schrieb:
> Eine Möglichkeit wäre:
> Subtype color_type is std_ulogic_vector(1 downto 0);
>
> constant RED   : color_type := "00";
> constant GREEN : color_type := "01";
> constant BLUE  : color_type := "10";

Allerdings mit dem unschönen Nebeneffekt, dass die Simulation dann 
wieder "00", "01" und "10" anzeigt, statt der leserlichen Fraben...

[Sven P. (Gast)]

Es funktioniert, wenn du den Aufzählungstyp dann auch konsequent 
benutzt. Solltest du irgendwo dann wieder Bitmasken benötigen, mach ein 
'case' oder eine LUT draus. Um den Rest darf sich die Synthese wieder 
kümmern, dafür ist die ja da.

Bei Xilinx kannst du die Kodierung beispielsweise mit dem 
ENUM_ENCODING-Attribut erzwingen. Ist aber vermutlich nicht portabel.

type ENUM_TYPE is (FIRST, SECOND, THIRD);

-- Xilinx:
attribute ENUM_ENCODING: STRING;
attribute ENUM_ENCODING of ENUM_TYPE: type is "00 01 10";

-- Portabel:
type ENUM_TYPE_ENCODING_VECTOR is array(ENUM_TYPE) of STD_LOGIC_VECTOR(1 downto 0);
constant ENUM_TYPE_ENCODING: ENUM_TYPE_ENCODING_VECTOR := ("00", "01", "10");

-- Benutzen:
signal ENU: ENUM_TYPE;
signal VEC: STD_LOGIC_VECTOR(1 downto 0);
VEC <= ENUM_TYPE_ENCODING(ENU);

[Thomas W. (donka)]

Deshalb erstellt man sich am besten eine Konversationsfunktion und 
weisst dann das "color signal" durch diese Funktion den Ausgangsports 
zu!
 z.B.

function color_2_slv(color : color_type) return std_logic_vector is
    variable slv    : std_logic_vector(1 downto 0);
begin
    case color is
        when RED =>   slv := "00";
        when GREEN => slv := "01";
        when BLUE =>  slv := "10";
    end case;
    return slv;
end function;

...

color_output_port <= color_2_slv(color_signal);

Somit hat man definierte Werte und es ist portabel.