ASM Inkrement Fehler

[Matthias (Gast)]

Hallo zusammen,

ich stehe auf dem Schlauch und weiss echt nicht mehr weiter. Ich habe 
ein kleines ASM Programm für einen Attiny10 geschrieben. Soll einfach 
bei Tastendruck den PWM ändern. Der erste Tastendruck funktioniert auch. 
Erster Wert wird gesetzt. Jetzt kommt der Fehler, wiederholtes Drücken 
führt zu keiner Änderung. Hab schon überprüft ob in den Interrupt 
gesprungen wird und in die SetzFunktion, wird alles korrekt ausgeführt. 
Ich habe dann festgestellt das pstate durch wiederholtes Aufrufen nicht 
geändert wird, es hat immer den Anfrangswert. Im AVR Studio mit 
Simulator funktioniert das ganze, nur auf dem Tiny selber nicht. Ich 
weiss echt nicht mehr was es sein könnte.
Jemand einen Ahnung woran das liegen kann?

.include "tn10def.inc"
.def temp = r18
.def temp1 = r17
.def pstate = r16
.def voltproof = r19

.org 0x000
rjmp main            ; Reset Handler

.org INT0addr
rjmp int0_handler    ; IRQ0 Handler

.org OVF0addr
rjmp    timer0_overflow       ; Timer Overflow Handler

main:
  ldi      temp, HIGH(RAMEND)     ; Stackpointer initialisieren
  out      SPH, temp
  ldi      temp, LOW(RAMEND)
  out      SPL, temp

  //Ausgangspin für PWM
  ldi temp, (1<<DDB0) | (1<<DDB1);
  out DDRB , temp

  //Ausgangspin Pullup für PWM
  ldi temp, (1<<PUEB0);
  out PUEB , temp

  ;INTO Interrupt einstellen LowLevel Interrupt
  ldi temp, (1<<ISC01); INT0 und INT1 auf fallende Flanke konfigurieren
  out EICRA , temp
  ldi temp, (1<<INT0)
  out EIMSK, temp

  ;Pullup INT0
  ldi temp, (1<<PUEB2);
  out PUEB, temp

  ;Variablen nullen
  ldi pstate, 0

  ;ADC init
  ldi     temp, (1<<ADEN)
  out     ADCSRA, temp
  ;Interrupts an
  sei
mainloop:
  rjmp mainloop

timer0_overflow:
  reti

;Interrupt durch Taster
;in pstate
int0_handler:
  ;Interrupts aus
  cli
  inc pstate
  start_vergleich:
    cpi     pstate,1
    brne    zweig_0
    //10%
    ldi temp1, 21
    rjmp    ende_vergleich
  zweig_0:
    cpi     pstate,2
    brne    zweig_1
    //25%
    ldi temp1, 63
    rjmp    ende_vergleich
  zweig_1:
    cpi     pstate,3
    brne    zweig_2
    //50%
    ldi temp1, 127
    rjmp    ende_vergleich
  zweig_2:
    cpi     pstate,4
    brne    zweig_3
    //75%
    ldi temp1, 192
    rjmp    ende_vergleich
  zweig_3:
    cpi     pstate,5
    brne    kein_Treffer
    //100%
    ldi temp1, 255
    rjmp    ende_vergleich
  kein_Treffer:
    ldi temp1, 0
    ldi pstate, 0
  ende_vergleich:

  rcall setpwm;setzen der pwm mit dem in temp1 gespeicherten wert
  ;Interrupts an
  sei
  reti ;Return aus Interrupt

;setzen der pwm mit dem wert aus temp1
;in:temp1
setpwm:
  ;Ausschalten zum ändern
  ldi temp, 0;
  out TCCR0A, temp
  out TCCR0B, temp

  out OCR0AL, temp1
  
  cpi     pstate,0
  BREQ    no_ea_pwm
  ;Einschalten
  ldi temp, (1<<OCIE0A)
  out TIMSK0 , temp
  ldi temp, (1<<COM0A1) | (1<<WGM00); FastPWN auf ChA, Clock/128 = 500Hz
  out TCCR0A, temp
  ldi temp, (1<<WGM02) | (1 << CS01); FastPWN auf ChA, Clock/128 = 500Hz
  out TCCR0B, temp
  no_ea_pwm:
  ret

[Spess53 (Gast)]

Hi

Ein Taster am Interruptpin ist eine dumme Idee. Sieh dir mal die 
Entprellroutinen 
http://www.mikrocontroller.net/articles/AVR-Tutorial:_Tasten
an.

MfG Spess

[Matthias (Gast)]

Der Taster ist soweit schon hardwareseitig entprellt. Aber das ist 
schließlich nicht mein Problem.

mfg Matthias

[Sascha W. (sascha-w)]

Matthias schrieb:
> Der Taster ist soweit schon hardwareseitig entprellt.
Wie?
> Aber das ist
> schließlich nicht mein Problem.
dass kann man so nicht sagen, prellt der Taster, so wird pstate in 
kurzer Zeit mehrmals erhöht. Mach doch testweise mal eine delay-Scheife 
rein.


UND
1) Ein cli am Anfang einer ISR, und ein sei vorm Ende kannst du dir 
sparen, mit dem Eintritt in die ISR sind weitere INT's sowiso gesperrt.

2) Wenn du nur die PWM verstellen willst, dann schalte sie nicht erst 
jedesmal vorher aus.

Sascha

[Stefan E. (sternst)]

rjmp main            ; Reset Handler

.org INT0addr
rjmp int0_handler    ; IRQ0 Handler

.org OVF0addr
rjmp    timer0_overflow       ; Timer Overflow Handler

main:
...
...
  ldi temp, (1<<OCIE0A)
  out TIMSK0 , temp

Das ist die Ursache deines Problems.

[Matthias (Gast)]

Oh ja, danke das war wirklich mein Problem.

[Matthias (Gast)]

@ Sascha:
hab deinen Tipp gerade ausprobiert, leider geht das scheinbar nicht mit 
dem AVR Studio Simulator. Das geht dort nur wenn ich vor dem Setzen 
ausschalte und danach wieder einschalte.

mfg Matthias

Sascha Weber schrieb:
> 2) Wenn du nur die PWM verstellen willst, dann schalte sie nicht erst
> jedesmal vorher aus.

[amateur (Gast)]

Deine ISR ist ein klassisches Beispiel dafür wie man es nicht machen 
soll.

Nicht nur, dass man keine Tasten in einer ISR abfragen soll. Auch kann 
es in 99,994% bis 100% aller Fälle nicht schaden, das eine oder andere 
Register zu sichern. Und wenn's nur der aktuelle Status ist.

[Karl H. (kbuchegg)]

und ein cli/sei in einer ISR ist auch nichts was man selber machen will.