Wie Verfügbare COM-Ports unter Lazarus + Synaser heraus bekommen?

[Steffen H. (avrsteffen)]

Hallo Leute,

Ich beschäftige mich gerade mit dem Delphi angelegtem freien Lazarus 
mit freiem Pascal Compiler.

Ich habe jetzt schon eine Kommunikation zwischen PC und µC hin bekommen. 
Dazu hab ich die ebenfalls freie Unit/Package Synaser verwendet. Also 
dies funktioniert schon mal.

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, LResources, Forms, Controls, Graphics, Dialogs,
  StdCtrls, ExtCtrls, synaser;

  var
  serv:TBlockSerial;
  memoLineIndex: integer= 0;

type

  { TForm1 }

  TForm1 = class(TForm)
    Beenden: TButton;
    Memo1: TMemo;
    Verbinden: TButton;
    Senden: TButton;
    Edit1: TEdit;
    Edit3: TEdit;
    Timer1: TTimer;
    Transmit: TLabel;
    Receive: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    procedure BeendenClick(Sender: TObject);
    procedure VerbindenClick(Sender: TObject);
    procedure SendenClick(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);

  private
    { private declarations }
    connected: Boolean;

  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TForm1 }

procedure TForm1.Timer1Timer(Sender: TObject);
var
  signal : string;

begin
  if not connected then exit;
  signal := serv.Recvstring(Timer1.Interval div 2);
  if serv.LastError <> 0 then exit;
  Memo1.Lines[memoLineIndex] := signal;
  memoLineIndex := memoLineIndex +1;
end;


procedure TForm1.BeendenClick(Sender: TObject);
begin
  serv.free;
  ShowMessage('ComPort muss freigeschalten werden! Jetzt freischalten?');
  sleep(1000);
  close;
end;


procedure TForm1.VerbindenClick(Sender: TObject);
var
portnr : string;
parity : char;
baud,bits,stop : integer;
softflow : boolean;
hardflow : boolean;

  begin
    if connected then
    begin
    ShowMessage('Verbindung ist bereits vorhanden');
    exit;
    end;
    serv:=TBlockSerial.create;
    portnr := 'COM3';
    parity := 'N';
    baud := 9600;
    bits := 8;
    stop := SB1;
    softflow := false;
    hardflow := false;
    serv.Connect(portnr);
    sleep(1000);
    serv.Config(baud, bits, parity, stop, softflow, hardflow);
    sleep(1000);
    if serv.LastError = 0 then
    begin
    connected := True;
    ShowMessage('Verbindung erfolgreich');
    end
    else
    ShowMessage('Verbindung konnte nicht hergestellt werden');
  end;


procedure TForm1.SendenClick(Sender: TObject);
var
befehl, data : string;

const
CR = #$0d;
begin
  befehl := edit1.text;
  data   := befehl+CR;
  serv.SendString(data);
end;

initialization


{$R *.lfm}

end.

So, jetzt möchte ich aber beim Öffnen des Programmes im TEdit Edit2 die 
unter Windows verfügbaren COM-Ports anzeigen und daraus auswählen 
können.

Also benötige ich irgendwie eine Information von Windows oder über 
Synaser von Windows, welche COM-Ports gerade verfügbar sind.

Welche Funktionen/Prozeduren/Units kann man dafür nehmen? Wer kann mir 
weiter helfen?


Gruß Steffen

[Proxxon (Gast)]

google doch mal ein bisschen

http://www.delphipraxis.net/85992-auflistung-aller-verfuegbaren-comports.html

oder schau mal wie ftdi das macht

Beitrag "Serial-Port Name auselsen"

[Christian (Gast)]

schau Dich da mal um, in dem Projket findest Du alles was Du brauchst.

http://www.leo-andres.de/2012/09/updateloader-benutzeroberflache-fur-avr-bootloader/

[Steffen H. (avrsteffen)]

Ich hab es gefunden, In der Unit synaser gibt es die Funktion:

function GetSerialPortNames: string;
Returns list/ of existing computer serial ports. Working properly only 
in Windows!

Jetz bekomm ich die gegenwärtig zur Verfügung stehenden COMs als string 
mit Komma getrennt zurück.

Beispiel:

procedure TForm1.ComboBox1DropDown(Sender: TObject);
var
  ports : string;

begin
  ports := GetSerialPortNames;
  Memo2.Text := ports;
end;

Jetzt muss ich die nur noch sortieren, und in die ComboBox eintragen. 
Lerne aber gerade erst Pascal.. kann also dauern :)



Gruß Steffen

[Steffen H. (avrsteffen)]

Christian schrieb:
> schau Dich da mal um, in dem Projket findest Du alles was Du brauchst.
>
> 
http://www.leo-andres.de/2012/09/updateloader-benutzeroberflache-fur-avr-bootloader/

Danke Christian. Das hilft mir bestimmt auch weiter.

[PascalUser (Gast)]

Hallo,

CommaText ist das was du zum "sortieren" suchst
(Beispiel mit ListBox):

procedure TfrmMain.EnumCOMPorts;
var
  sl: TStringList;
begin
  ListBox.Clear;
  sl := TStringList.Create;
  try
    sl.CommaText := GetSerialPortNames;
    ListBox.Items := sl;
  finally
    sl.Free;
  end; 
end;

MfG

[Robert L. (lrlr)]

naja

 ListBox.Items.CommaText := GetSerialPortNames;


tut das selbe..