Loop mit Delay in Assembler

[chris (Gast)]

Hallo

Ich bin zurzeit dabei eine PWM für LED's mit einem Atmega32 und einem 
16.000MHz takt zu basteln. Die PWM Rutine funktioniert auch ohne 
Probleme, nun will ich mittels einer Schleife alle 255 werte hochlaufen 
lassen und die LED so Dimmen, bis sie schließlich aus ist. Hierzu habe 
ich eine Schleife eingebaut und lasse mittels inc mein Register (r17) 
nach oben zählen. Die delay Funktion habe ich mit dem AVR Warteschleifen 
Generator erstellt. Jedoch genau hier liegt das Problem scheinbar wird 
die Warte schleife nicht ausgeführt und somit ist kein dimm Effekt an 
den LEDs zu sehen.

So sieht mein bisheriger Code aus:

 .include "m32def.inc"

 .def temp       = r17

 ;stack initialisierung 
 ldi temp, LOW(RAMEND) 
 out SPL, temp 
 ldi temp, HIGH(RAMEND)
 out SPH, temp

 ldi temp, 0x00;

 ldi r16, 0x69      ;hilfsregister beschreiben
 out TCCR0, r16      ;8bit Counter
 out TCCR2, r16

 ldi r16, 0xA1      ;16bit counter definition
 out TCCR1A, r16    

 ldi r16, 0x09
 out TCCR1B, r16

 ldi r16, 0x08      
 out DDRB, r16      ;set PB3 as output

 ldi r16, 0xB0
 out DDRD, r16      ;set PD4,5,7 as output


 
 loop:
  inc temp      ;zählen
  
  rcall write
  rcall delay
  
  rjmp loop
  

  
write:
  out OCR0, temp    ;werte an pwm ausgänge schicken
  out OCR2, temp
  out OCR1AH, temp
  out OCR1BH, temp
  out OCR1AL, temp
  out OCR1BL, temp

  ret

delay: ;0.1 Sekunden warten
  ; ============================= 
  ;   Warteschleifen-Generator 
  ;     1600000 Zyklen:
  ; ----------------------------- 
  ; warte 1599999 Zyklen:
        ldi  R17, $F1
  WGLOOP0:  ldi  R18, $0E
  WGLOOP1:  ldi  R19, $9D
  WGLOOP2:  dec  R19
        brne WGLOOP2
        dec  R18
        brne WGLOOP1
        dec  R17
        brne WGLOOP0
  ; ----------------------------- 
  ; warte 1 Zyklus:
        nop
  ; ============================= 

  ret

Vielen Dank für eure Hilfe!

chris

[Stefan E. (sternst)]

Die Warteschleife zerstört dir deinen Dim-Wert.

[Spess53 (Gast)]

Hi

>.def temp       = r17

> loop:
>  inc temp      ;zählen

>write:
>  out OCR0, temp    ;werte an pwm ausgänge schicken
>  out OCR2, temp
>  out OCR1AH, temp

>       dec  R17
>        brne WGLOOP0

Fällt dir etwas auf?

Du must dich entscheiden. Entweder dieses .def-Gedödel oder 
Registernamen. Alles andere ist tödlich.

mfG Spess

[chris (Gast)]

Danke :) manchmal sieht man den Walt vor lauter Bäumen nicht mehr.

[Matthias S. (Firma: matzetronics) (mschoeldgen)]

Und hier wieder mal eine universelle Warteroutine, die enorm weite Delay 
Bereiche abdeckt und nur ein einziges Register braucht:

.def  del  = r17  ; delay counter
; steve wozniak's wait routine - this time for AVR 
; this is the extended routine with del^3 
; this wait routine is ingenious and handles wide ranges of delay 
; as a hommage to steve i port it to all my embedded systems. 
; call it with a value in 'del'
wozwait:  
  push  del
wwait2:  push  del
wwait1:  subi  del,1  
  brne  wwait1
  pop  del
  subi  del,1
  brne  wwait2
  pop  del
  subi  del,1
  brne  wozwait
  ret

Der Dank gebührt Steve Wozniak, die Routine ist aus dem Apple ][ ROM.

[Wegstaben V. (wegstabenverbuchsler)]

Warteschleifen in Asembler zu programmieren ist ne verdamt coole Sache, 
pfeilschnell. So kann man viel schneller warten, als wenn man ne 
Warteschleife in blödem C programmiert, was ja viel langsamer ist.

[Mr. Tom (Gast)]

chris schrieb:
> ie PWM Rutine funktioniert auch ohne
> Probleme, nun will ich mittels einer Schleife alle 255 werte hochlaufen
> lassen und die LED so Dimmen, bis sie schließlich aus ist.

Damit wird die Helligkeit der LED erst gaaanz langsam abnehmen und zu 
den letzten Stufen immer schneller werden.
http://de.wikipedia.org/wiki/Fechnersches_Gesetz