rlf Befehl bei PIC16F887 klappt nicht!

[DasSauerkraut (Gast)]

Hallo Leute,

habe hier folgenden Quellcode:

    list        p=16f887            ; list definiert den Controller 
    #include    <p16f887.inc>      ; Headerdatei mit Registernamen 
    __CONFIG      _CONFIG1, _LVP_OFF&_FCMEN_OFF&_IESO_OFF&_BOR_OFF&_CPD_OFF&_CP_OFF&_MCLRE_ON&_PWRTE_ON&_WDT_OFF&_INTRC_OSC_NOCLKOUT 
    __CONFIG    _CONFIG2, _WRT_OFF&_BOR21V 
;---------------------------------------------------------------------- 
; Configuration Word Register1:          
;         Low Voltage Programming -> LVP_OFF(disabled)                 
;         Monitor Clock Fail-safe -> FCMEN_OFF(disabled)                      
;         Internal External Switch Over Mode -> IESO_OFF(disabled)         
;         Brown Out Detect -> BOR_OFF(disabled)     
;         Data EE Read Protect -> CPD_OFF (disabled) 
;         Code Protect -> CP_OFF 
;         Master Clear Enable -> MCLRE_ON (enabled) 
;         Power Up Timer -> PWRTE_ON (enabled) 
;         Watchdog Timer -> WDT_OFF (disabled) 
;         Oscillator -> INTRC_OSC_NOCLKOUT (Internal RC No Clock)             
; Configuration Word Register2:  
;         Flash Memory Write Protection off -> WRT_OFF (disabled) 
;         Brown-out Reset Voltage -> BORV21 (2,1 V) 
 
          ORG         0x000    ; Anfangsadresse 0x000 
ResetVector    movlw     high(main) 
            movwf     PCLATH 
            goto      main
;----------------------------------------------------------------------
; Variablen Definition
;----------------------------------------------------------------------
ms1   equ 0x22
ms100   equ 0x23

;---------------------------------------------------------------------- 
; Hauptprogramm: main 
;---------------------------------------------------------------------- 
main         
        bsf     STATUS, RP0     ; auf Bank 1 umschalten 
    movlw  0x00       ; PORTA ist Ausgang
    movwf  TRISA  
        clrf   STATUS       ; auf Bank 0 umschalten
    movlw  b'00000001'
    movwf  PORTA
    bcf     STATUS, C


;---------------------------------------------------------------------- 
; Lauflicht
;----------------------------------------------------------------------  
mainloop      
    call   delay_100ms
    rlf    PORTA,f
    goto   mainloop

;----------------------------------------------------------------------
; delay Funktion 100ms
;----------------------------------------------------------------------
delay_100ms
    movlw  d'100'      ;Zeitkonstante 100ms
    movwf  ms100
wait2  movlw  d'100'            ;Zeitkonstante 1ms
    movwf  ms1        
wait1  nop            ;1µS
    nop            ;1µS
    nop            ;1µS
    nop            ;1µS
    nop            ;1µS
    nop            ;1µS
    nop            ;1µS
    decfsz  ms1        ;1µS
    goto   wait1      ;2µs
    decfsz  ms100
    goto  wait2      
    return 

;---------------------------------------------------------------------- 
        END                    ; Programmende 
;----------------------------------------------------------------------

Das Problem hierbei ist das der rlf PORTA, f Befehl nicht funktioniert.

Der Ausgang sieht wie Folgt aus:

1. Durchlauf: 00000001
2. Durchlauf: 00000000

wenn ich das bitmuster Manuell durchlaufenlasse also jedes mal den Wert 
manuell ins Register schreibe für den nächsten Schritt klappt es. Also 
Zeitschleife und alles geht. nur diese blöden rotationsbefehle klappen 
nicht. Kann mir jemand sagen woran das liegt?

[Chris B. (dekatz)]

Wie in 99% solcher Fälle:
Ich würde mal den PortA von ANALOG (das ist die Defaulteinstellung nach 
einem Reset) auf DIGITAL umschalten --> Datenblatt 3.0

[Teo D. (teoderix)]

http://www.sprut.de/electronic/pic/fallen/fallen.html

[DasSauerkraut (Gast)]

BANKSEL ANSEL   ;
clrf  ANSEL   ;PORTA to digital I/O
clrf   STATUS

Hat in der Tat Funktioniert.

Bist du so nett mir zusagen wo der genau Unterschied besteht? Habe die 
Ports ja vorher schon als Ausgang festgelegt. Warum muss ich dann 
nochmal die Analogeingänge ausschalten? geschieht das nicht automatisch?

[Chris B. (dekatz)]

DasSauerkraut schrieb:
> BANKSEL ANSEL   ;
> clrf  ANSEL   ;PORTA to digital I/O
> clrf   STATUS
>
> Hat in der Tat Funktioniert.
>
> Bist du so nett mir zusagen wo der genau Unterschied besteht? Habe die
> Ports ja vorher schon als Ausgang festgelegt. Warum muss ich dann
> nochmal die Analogeingänge ausschalten? geschieht das nicht automatisch?

Als reiner Ausgang würde der Port auch in der Analogkonfiguration 
funkteonieren.

<rlf PORTA, f> ist aber ein "read-modify-write" Vorgang: PortA wird 
Gelesen, nach Links verschoben und wieder Geschrieben. Und der 
Lesevorgang läuft ohne Umschaltung über den Analogpfad und dessen 
Verhalten ist nicht vorhersehbar (in Bezug auf definiertes 0 oder 1´).

Im DB findet man unter 3.2.3. die Blockdiagramme der einzelnen Portpins 
und kann den Signalweg dort nachvollziehen.

[DasSauerkraut (Gast)]

So ein kleines Problem gibt es aber noch:

Ich habe folgenden Init code:

        BANKSEL  TRISA
  clrf  TRISA  
        clrf   STATUS       ; auf Bank 0 umschalten
  BANKSEL ANSEL       ;
        clrf  ANSEL       ;PORTA to digital I/O
  clrf   STATUS
  bcf  STATUS, C
  clrf   PORTA
  bsf  PORTA, 0

das Problem ist jetzt das ich den PIC ein paar mal neu sarten muss bis 
das lauflicht mit nur einer LED durchläuft. Es scheint als würde der 
PORTA nicht richtig gelöscht werden, bevor der Wert B'00000001' 
geschrieben wird. Bzw. es wird ein falscher Wert reingeschrieben keine 
Ahnung. xD Kann mir jemand erklären wieso? Der Port wird doch mit clrf 
PORTA gelöscht?

[Chris B. (dekatz)]

???? nur ein Schuß ins Blaue, aber initialisiere mal die Register in der 
Reihenfolge wie im DB

BANKSEL PORTA ;
CLRF    PORTA ;Init PORTA
BANKSEL ANSEL ;
CLRF    ANSEL ;digital I/O
BANKSEL TRISA ;
CLRF    TRISA ;

[W.S. (Gast)]

Warum zum Kuckuck gönnst du deinem kleinen Programm nicht eine 
RAM-Zelle, wo du dein ominöses Lauflicht zelebrierst und anschließend 
nur noch auf den Port kopierst?

W.S.

[DasSauerkraut (Gast)]

Bin erst seit ein paar Tagen dabei mich mit den PICs und Assembler 
auseinander zu setzen. =) Learning by doing =)

[Ottmar K. (wil1)]

Hallo
Dein Programm hat in "Main" einen grundsätzlichen Fehler. Ein neuer 
Durchlauf kann nur erfolgen wenn Bit 0 wieder gesetzt wird (vgl. meinen 
Code wieter unten)

Beim Erlernen des Programmierens, sollte das Datenblatt des verwendeten 
Prozessors stets Schritt für Schritt zu Rate gezogen werden, das hilft 
viel gegen "Verirrungen" und Fehlschlüsse!

Dazu gibt es in MPLAB den Simulator "MPLAB-SIM" mit welchem man (fast) 
alle Möglichkeiten der PICs durchspielen kann.

-Datenblatt-

4.1 PORTA and the TRISA Register
PORTA is a 6-bit wide, bidirectional port. The corresponding data 
direction register is TRISA.
...Other PORTA pins are multiplexed with analog inputs and the analog 
VREF input for both the A/D converters and the comparators.

-Datenblatt Ausszug Ende-

Kurzum: Am PORTA stehen nicht 8, sondern nur 6 Bits zur Verfügung. Daher 
kann  "RLF" - ein 8bit-Schiebefehl an PORTA nicht ohne weiteres zum 
Durchschieben eines einzelnen Bits verwendet werden! Zudem werden einige 
Pins nach Reset/Neustart nicht als digitale I/O sonder als analoge 
Eingänge konfiguriert.

Besser ist es da schon PORTB oder PORTC zu verwenden. Dann klappt auch 
der Übertrag des letzten Bits "RB7" ins Carrybit als Indikator, dass 
jetzt alle Bits durchgeschoben sind. So kann RB0 erneut gesetzt werden.

-Alternativer Code-

Nachstehend habe ich Deinen Code mal entsprechend korrigiert (Die 
Initialisierung von PORTB habe ich mir geschenkt:

Main
    movlw  b'00000001' ;erstmal RB0=1 setzen
    movwf  PORTB
Main_Loop
    call    Delay100ms ;LED kurz zeigen, dann weiterschalten
    bcf     STATUS,C  ;Carry=0 (wird automatisch nach PORTB,RB0 kopiert)
    rlf      PORTB,f  ;LED um 1 bit weiter nach links schieben
    btfss   STATUS,C  ;Carry=1? letztes Bit von RB7 nach Carry
                      ;geschoben? Dann sind jetzt alle LEDs aus!
    GOTO   Main_Loop  ;NEIN, weiter mit bitshift left
    GOTO   Main       ;JA, wieder von vorn, dazu RB0=1 setzen

mfG Ottmar