Arduino tone() ohne delay

[Nax (Gast)]

Ich habe es bislang auf keiner der überlichen Wege hinbekommen,

eine Melody über den Piezo Speaker auszugeben ohne die delay Funktion zu 
nutzen.

Die delay Funktion ist während der Widergabe kontraproduktiv für mein 
Programm. Im Internet habe ich so noch keine Lösung gefunden.

Bislang versucht mit der millis() und Metro. Hat aber nicht hingehauen.

Hoffentlich kann mir einer helfen.

Des weiteren würde ich gerne, das es nur einmal durch läuft für jedesmal 
wo ich das Programm aufruf.

void starwars() {
  int i, rhythmDuration;
  for (i = 0; i < rhythmLength; i++) {
    rhythmDuration = rhythmBeats[i] * tempo; 
    if (rhythmNotes[i] == '0') {
      delay(rhythmDuration); 
    }
    else {
      tone(buzzerPin, rhythmNotes[i], rhythmDuration);
      delay(rhythmDuration);
    }
    delay(tempo/10);
  }
}

const int NOTE_AS3 = 233;
const int NOTE_C4 = 262;
const int NOTE_D4 = 294;
const int NOTE_E4 = 330;
const int NOTE_F4 = 349;
const int NOTE_G4 = 392;
const int NOTE_GS4 = 415;
const int NOTE_A4 = 440;
const int NOTE_AS4 = 466;
const int NOTE_B4 = 494;
const int NOTE_C5 = 523;
const int NOTE_CS5 = 554;
const int NOTE_D5 = 587;
const int NOTE_DS5 = 622;
const int NOTE_E5 = 659;
const int NOTE_F5 = 699;
const int NOTE_FS5 = 740;
const int NOTE_G5 = 784;
const int NOTE_GS5 = 831;
const int NOTE_A5 = 880;

const int rhythmLength = 115;
int buzzerPin = 3;

int rhythmNotes[] = {
  NOTE_A4,0,NOTE_A4,NOTE_A4,NOTE_A4,NOTE_A4,0,NOTE_A4,NOTE_A4,NOTE_A4,NOTE_A4,0,
  NOTE_A4,NOTE_A4,NOTE_A4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_C5,NOTE_C5,NOTE_C5,
  NOTE_A4,0,NOTE_A4,NOTE_A4,NOTE_A4,NOTE_A4,0,NOTE_A4,NOTE_A4,NOTE_A4,NOTE_A4,0,
  NOTE_A4,NOTE_A4,NOTE_A4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_C5,NOTE_C5,NOTE_C5,
  NOTE_A4,NOTE_A4,NOTE_A4,NOTE_F4,NOTE_C5,NOTE_A4,NOTE_F4,NOTE_C5,NOTE_A4,
  0,NOTE_E5,NOTE_E5,NOTE_E5,NOTE_F5,NOTE_C5,NOTE_GS4,NOTE_F4,NOTE_C5,NOTE_A4,
  0,NOTE_A5,NOTE_A4,NOTE_A4,NOTE_A5,NOTE_GS5,NOTE_G5,NOTE_FS5,NOTE_F5,NOTE_FS5, 
  0,NOTE_AS4,NOTE_DS5,NOTE_D5,NOTE_CS5,NOTE_C5,NOTE_B4,NOTE_C5, 
  0,NOTE_F4,NOTE_GS4,NOTE_F4,NOTE_A4,NOTE_C5,NOTE_A4,NOTE_C5,NOTE_E5,
  0,NOTE_A5,NOTE_A4,NOTE_A4,NOTE_A5,NOTE_GS5,NOTE_G5,NOTE_FS5,NOTE_F5,NOTE_FS5,
  0,NOTE_AS4,NOTE_DS5,NOTE_D5,NOTE_CS5,NOTE_C5,NOTE_B4,NOTE_C5, 
  0,NOTE_F4,NOTE_GS4,NOTE_F4,NOTE_C5,NOTE_A4,NOTE_F4,NOTE_C5,NOTE_A4};

int rhythmBeats[] = {
  1,2,1,1,1,1,2,1,1,1,1,2,1,1,1,1,1,1,1,1,1, 
  1,2,1,1,1,1,2,1,1,1,1,2,1,1,1,1,1,1,1,1,1,
  4,4,4,3,1,4,3,1,4, 
  4,4,4,4,3,1,4,3,1,4, 
  4,4,3,1,4,3,1,1,1,1, 
  3,2,4,3,1,1,1,1, 
  3,2,4,3,1,4,3,1,4, 
  3,4,3,1,4,3,1,1,1,1, 
  3,2,4,3,1,1,1,1, 
  3,2,4,3,1,4,3,1,4};

int tempo = 150;

void setup()
{
  
}

void loop()
{
  starwars();
}

[jojo (Gast)]

> Bislang versucht mit der millis() und Metro. Hat aber nicht hingehauen.

warum nicht? guck dir den Besipielcode von Blink without delay an und 
model dir das um.

[Nax (Gast)]

tone(buzzerPin, rhythmNotes[i], rhythmDuration);

Entspricht hier nicht bereits die ryhtmDuration einem delay?

[Jens K. (jens_k)]

Geht ganz einfach, musste aber selbst was machen.
Mit DDS... dazu braucht man einen schnellen Timer mit Interrupt. Der 
Interrupt muss mit der doppelten Frequenz getriggert werden wie die 
maximale Frequenz die man widergeben möchte.

In der Interrupt-Routine hat man dann folgendes...

Zaehler = Zaehler + Set
If Delay > 0
    Portpin = MSB von Zaehler
    Delay = Delay - 1
Else
    Portpin = 0


Wenn man "Set" auf die hälfte von der Bitbreite von Zaehler setzt 
bekommt man am Portping 1/2 Frequenz vom Interrupt. Reduziert man den 
Wert von "Set" Sinkt auch die Frequenz mit der der Portpin toggelt...
Das Delay setzt man auf einen Wert X und der Portpin gibt bis ablauf die 
Frequenz aus.
Das schöne daran ist das kann man auf Polyphonien erweitern und braucht 
trotzdem nur einen Timer... Das einzige was beschränkt ist die 
Rechenleistung vom AVR....

[Nax (Gast)]

Das versteh ich kein bisschen von :(

Ich hätte gehofft, iwas Richtung millis() wäre machbar.

Weiß aber nicht, wie ich die Verschachtelung passend umschreiben kann.

[vibrator (Gast)]

Lese Dich in Timer und Interrupts ein.
Dann verstehst Du um was es geht.

[jojo (Gast)]

> tone(buzzerPin, rhythmNotes[i], rhythmDuration);
>
> Entspricht hier nicht bereits die ryhtmDuration einem delay?

das müsste natürlich noch geklärt werden, währe aber sehr unschick und 
dann kannst du tone() ja eh vergessen.

hier:
http://code.google.com/p/rogue-code/wiki/ToneLibraryDocumentation#Ugly_Details

ist beschrieben wie die Timer verwendet werden, und es scheint so, als 
ob Timer0 für millis() frei bleiben würde.

> Ich hätte gehofft, iwas Richtung millis() wäre machbar.
> Weiß aber nicht, wie ich die Verschachtelung passend umschreiben kann.
was hast du denn versucht? Vestehst du den Code von blink without delay?

AVR-Tutorial: Timer

Interrupt

[Nax (Gast)]

Die millis Variante kennt ich,

hab sie im Hauptsketch in verwendung an einigen Stellen

   if(aktuelleZeit - vorherigeZeit > wartezeit)
    {
      digitalWrite(pumpePin, LOW);
      pumpeStatus = digitalRead(pumpePin);
      vorherigeZeit = aktuelleZeit;
      Serial.print("Ende 0");
      i++;
    }


Weiß aber nicht, wie ich das in der verschachtelte Variante von dem 
Melody Sketch machen soll.

[jojo (Gast)]

> Weiß aber nicht, wie ich das in der verschachtelte Variante von dem
> Melody Sketch machen soll.

na dann überleg's dir, scheinst ja alle Hilfsmittel zu kennen, 
verschachteln, ja, da muss man sich was überlegen

[Karl H. (kbuchegg)]

Hinweis:

Das hier

  for (i = 0; i < rhythmLength; i++) {

geht schon mal gar nicht.
Du musst weg von dieser Überlegung, dass du hier alle Noten abspielen 
sollst.

Deine Denkweise muss so wie hier sein

void loop()
{
  ....

  if(aktuelleZeit - vorherigeZeit > wartezeit)
  {

     Zack! die vereinbarte Zeit für die Note die gerade spielt, ist um.
     Die nächste Note ist drann!

     Welches ist die nächste Note?
     Die Werte holen und mittels Dauer-tone() dudeln lassen
     den Wert für wartezeit bestimmen (also die Notendauer)
     und die die aktuelle Zeit als vorherige Zeit merken,
     damit obiger vergleich zum Übergang auf die nächste
     Note dann wieder funktioniert
  }

  ....
}

[Nax (Gast)]

Bin noch nicht weitergekommen. Gibts kein fertigen Sketch? Habe bei 
github nur welche basierend auf delays gefunden. Muss man immer das Rad 
neu erfinden? Es ist eine kleine Spielerei funktion später in meiner 
Steuerung die rein soll, habe mir aber schon derzeit so den Kopf drum 
zerbrochen, dass ich fast denke, es ist so einfach nicht realisierbar. 
Denn ansonsten wären die Tuts damit  voll.

[PittyJ (Gast)]

Manche Sachen sind eben komplizierter, und es gibt keine fertige Lösung 
im Internet, und auch keinen im Forum, der das mal schnell schreibt.
Da muss man dann doch selber ein paar Stunden prokeln.

Falls das zu teuer ist: die Arduinos sind doch so günstig, dass man 
einfach einen zweiten nimmt. Kommunikation über einen IO-Pin, und schon 
wird parallel die Musik gespielt.

20 Euro für einen Arduino sind billiger als eine Stunde Arbeitszeit.

[Karl H. (kbuchegg)]

Nax schrieb:
> Bin noch nicht weitergekommen. Gibts kein fertigen Sketch? Habe bei
> github nur welche basierend auf delays gefunden. Muss man immer das Rad
> neu erfinden?

In deinem Fall ja.
Wer radfahren will, muss eben radfahren lernen.

Zumal das nun wirklich keine Raketentechik ist.

> zerbrochen, dass ich fast denke, es ist so einfach nicht realisierbar.

Es ist sogar recht trivial.
Aber: Vor das Wollen haben die Götter das Können gesetzt. Und das muss 
man eben lernen. Mussten wir alle. Und nein. Stundelang nach fertigem 
Code googeln hat auf diesem Schwierigkeitslevel nichts mit lernen zu 
tun. In der Zeit hättest du schon längst mit einer blinkenden Led als 
Ausgangspunkt dir die notwendige Technik selber beigebracht und Schritt 
für Schritt um die Dinge ergänzt, die anders sein sollen.

int notenNr = 0;
int noten[] = { 440, 880, 600 };
int dauer[] = { 1000, 500, 500 };

unsigned long aktuell = 0;
unsigned long tonBeginn = 0;
unsigned long tonDauer = 0;

void loop()
{
  aktuell = millis();

  if(aktuell - tonBeginn > tonDauer )
  {
     tone( buzzerPin, noten[notenNr] );
     tonDauer = dauer[notenNr];

     notenNr++;
     if( notenNr == 3 )
       notenNr = 0;

     tonBeginn = aktuell;
  }
}

und das ist jetzt vom Prinzip her so wahnsinnig schwer?
Noch dazu, wo ich es dir schon vorgekaut habe, bzw. du dir an einem 
LED-Blink Beispiel die Grundtechnik hättest anschauen können?
Den Rest musst du jetzt alleine einbauen. Wenigstens das wirst du ja 
wohl hoffentlich können.

[Karl H. (kbuchegg)]

PittyJ schrieb:
> Manche Sachen sind eben komplizierter, und es gibt keine fertige Lösung
> im Internet, und auch keinen im Forum, der das mal schnell schreibt.
> Da muss man dann doch selber ein paar Stunden prokeln.
>
> Falls das zu teuer ist: die Arduinos sind doch so günstig, dass man
> einfach einen zweiten nimmt. Kommunikation über einen IO-Pin, und schon
> wird parallel die Musik gespielt.


Ich hoffe, das war als Satire gemeint.

[Peter D. (peda)]

Wenn Du eine Melodie spielen willst, ohne das Main zu stoppen, mußt Du:
1. einen PWM-fähigen Ausgangspin nehmen.
2. im Timerinterrupt die Tondauer zählen und den nächsten Tonwert in die 
PWM laden.

Die Tonerzeugung über Delays ist dazu völlig ungeeignet.

[Natz (Gast)]

Gibt es eine Möglichkeit einen Ton auf leise zu stellen. Habe im Sketch 
3 Pausen drin von 250ms.
Der "Ton" pause defeniert mit 0 gibt aber so ein kleines rattern auf den 
Piezo.

const int buzzerPin = 3;

#define c 261
#define d 294
#define e 329
#define f 349
#define g 391
#define gS 415
#define a 440
#define aS 455
#define b 466
#define cH 523
#define cSH 554
#define dH 587
#define dSH 622
#define eH 659
#define fH 698
#define fSH 740
#define gH 784
#define gSH 830
#define aH 880
#define pause 0

int notenNr = 0;
int noten[] = { 
  a, a, a, f, cH, a, f, cH, a, eH, eH, eH, fH, cH, gS, f, cH, a, aH, a, a, aH, gSH, gH, fSH, fH, fSH, 
  pause, f, gS, f, a, cH, a, cH, eH, aH, a, a, aH, gSH, gH, fSH, fH, fSH, 
  pause, aS, dSH, dH, cSH, cH, b, cH, 
  pause, f, gS, f, cH, a, f, c, a
};

int dauer[] = { 
  500, 500, 500, 350, 150, 500, 350, 150, 1000, 500, 500, 500, 350, 150, 500, 350, 150, 1000, 500, 350, 150, 500, 250,250, 125, 125, 250, 
  /*pause*/  250, 125, 500, 375, 125, 500, 375, 125, 1000, 500, 320, 150, 500, 250, 250, 125, 125, 250, 
  /*pause*/  250, 250, 500, 250, 250, 125, 125, 250, 
  /*pause*/  250, 250, 500, 375, 125, 500, 375, 125, 1000
};

unsigned long aktuell = 0;
unsigned long tonBeginn = 0;
unsigned long tonDauer = 0;

void setup() {
  pinMode(buzzerPin, OUTPUT);
}

void loop()
{
  aktuell = millis();


  if(aktuell - tonBeginn > tonDauer )
  {
    tone( buzzerPin, noten[notenNr] );
    tonDauer = dauer[notenNr];

    notenNr++;
    if( notenNr == 61 )
      notenNr = 0;

    tonBeginn = aktuell;
  }
}

[Karl H. (kbuchegg)]

Siehe Doku bei Arduino.

Um tone() abzudrehen, noTone() aufrufen.

....
   if( noten[notenNr] == pause )
     noTone( buzzerPin );
   else
     tone( buzzerPin, noten[notenNr] );

 ...

Besser du gewöhnst dich gleich daran: Die Arduino-Doku wird deine zweite 
Bibel.
Also lies gefälligst nach. Ich hab in meinem ganzen Leben noch nie einen 
Arduino programmiert, geschweige denn einen in der Hand gehabt. Ich 
finde die Dinge raus und du nicht? Das kanns ja wohl nicht sein.