ADC Problem Attiny 45

[Lukas (Gast)]

Hallo habe ein Problem beim Einlesen einer ADC. Ich sehe im I/O View 
dass die Register ADCL und ADCH upgedatet werden nach jeder ADC kann sie 
aber nicht in meine Register auslesen.

ADCinit

  ldi    temp, 0b10000001    ;Prescaler
  out    ADCSRA,temp

  ldi    temp, 0b00100000
  out    DIDR0,temp

  ret


ADCstart2:

      ldi  temp,0b00000001
      out    ADMUX,temp

      ldi    temp, 0b11000001

      out    ADCSRA, temp
      ;clr    ADCH
      ;clr    ADCL

complete2:
      ldi    temp,ADCSRA
      sbrc   temp,ADSC
      rjmp  complete2


      lds    r16,ADCH
      lds    r17,ADCL



      ret


Ich hänge gerade.
Sieht wer den Fehler?

LG

[LostInMusic (Gast)]

"in" statt "lds" ist richtig:

in     r16,ADCH
in     r17,ADCL

[LostInMusic (Gast)]

Und Du musst auch noch ein "ldi" in ein "in" abändern. Finde selbst 
heraus, welches.

Vielleicht solltest Du Dir die genauen Unterschiede zwischen "ldi", 
"lds" und "in" nochmal klarmachen.

[Lukas (Gast)]

Oh

in temp,ADCSRA

Ja die Unterschiede sind mir klar, nur ist das ja wieder vom 
Prozessorabhängig, bzw. abhängig wo das Register liegt im Prozessor

[Peter II (Gast)]

Lukas schrieb:
> Ja die Unterschiede sind mir klar, nur ist das ja wieder vom
> Prozessorabhängig, bzw. abhängig wo das Register liegt im Prozessor

bei ASM ist immer vom Prozessor abhängig. Wenn du es mit C 
Programmierst, dann musst du so etwas nicht beachten.

[c-hater (Gast)]

Lukas schrieb:

> Ja die Unterschiede sind mir klar, nur ist das ja wieder vom
> Prozessorabhängig, bzw. abhängig wo das Register liegt im Prozessor

Richtig. Und wenn man zu faul ist, das jeweils nachzuschlagen, schreibt 
man sich einfach zwei Macros, die einem die Arbeit abnehmen. Am besten 
mit Warnung, falls lds/sts statt in/out benutzt werden muß, damit man 
bei timingkritischen Sachen keine unangenehmen Überraschungen erlebt.

.EQU WARN_MMIO=1 ;oder 0 zum Unterdrücken der Warnungen

;->@0: Zielregister (MCU)
;  @1: Quellregister (IO)
.MACRO UNI_IN
.IF @1 < $40
  in @0,@1
.ELSE
  lds @0,@1
  .IF WARN_MMIO
    .WARNING "One extra tick for MMIO"
  .ENDIF
.ENDIF
.ENDMACRO

;->@0: Zielregister (IO)
;  @1: Quellregister (MCU)
.MACRO UNI_OUT
.IF @0 < $40
  out @0,@1
.ELSE
  sts @0,@1
  .IF WARN_MMIO
    .WARNING "One extra tick for MMIO"
  .ENDIF
.ENDIF
.ENDMACRO

Alternativ könnte man auch zwei Macros schreiben, die immer MMIO 
benutzen (und damit ggf. einen Takt mehr verbraten als nötig). Das hätte 
immerhin den Vorteil, daß das Timing Device-unabhängig wird und sähe 
dann so aus:

;->@0: Zielregister (MCU)
;  @1: Quellregister (IO)
.MACRO MMIO_IN
.IF @1 < $40
  lds @0,@1+$20
.ELSE
  lds @0,@1
.ENDIF
.ENDMACRO

;->@0: Zielregister (IO)
;  @1: Quellregister (MCU)
.MACRO MMIO_OUT
.IF @0 < $40
  sts @0+$20,@1
.ELSE
  sts @0,@1
.ENDIF
.ENDMACRO

Benutzen kann man die Macros dann genau wie von in bzw. out gewohnt, 
also z.B.:

  UNI_IN R16,ADCH

oder

  MMIO_OUT ADCSRA,R20

[der alte Hanns (Gast)]

> in    r16,ADCH
> in    r17,ADCL


Die Reihenfolge ist falsch:

"ADCL must be read first, then ADCH."