AVR ASM Pin schaltet einfach so

[Anonymous U. (gastt)]

Hallo liebes Forum!

Ich bin ein wenig am verzweifeln, hab schon den halben Tag gesucht und 
nix gefunden: An meinem Attiny13 hängt ein Schieberegister. Mein 
Programm funktioniert wie es soll. Nun habe ich das Problem, dass nach 
(zufälliger?) Zeit die Pins beim SIPO kurz anschalten.

Was ich schon versucht habe:
-im Programm nur Sipo angesteuert: funktioniert, deswegen muss auch SIPO 
funktionieren

-Widerstand an Strobe von SIPO gehalten: funktioniert nicht, AVR-Pins 
gehen also nicht in tristate.

-Bei rcall AUSGABE die Ausgabe ans SIPO auf einen bestimmten Wert 
gezwungen: funktioniert nicht: der Fehler kann nicht bei meinem 
Unterprogramm rcall AUSGABE liegen.

-Es werden aber sonst keine Portpins geschalten!?!?

-Es tritt auch kein Reset auf.

Ich würde mich freuen wenn noch jemand eine Idee hat!!!

[Anonymous U. (gastt)]

oh, und der code natürlich:

/*
 * Garagentoranzeige.asm
 *
 *  Created: 28.04.2013 09:48:12
 *   Author: Meister x.
 *  128kHz, Div: 0
 *
 *
 */ 


;Konstanten
.equ kErinnerung = 10    ;2ms
.equ kAnzeigemodus = 100    ;1s


;Definitionsdatei für Attiny13 Einbinden
.include "tn13def.inc"


.CSEG    ;ab hier beginnt Programm => Flash


;Interruptvektoren setzen
.org 0x0000      ;Reset Handler
  rjmp RESET
.org 0x0002      ;PCINT (Taster)
  rjmp TESTMODUS
.org 0x0003      ;Timer0 overflow für Clock
  rjmp CLOCK
.org 0x0008      ;WD interrupt
  rjmp MESSUNG
.org 0x0009      ;ADC Conversion Complete
  //rjmp ADC_READY

   
;Variablen deklarieren
.def rClock2ms = r1
.def rClock100ms = r2
.def rClock1s = r3

.def rTemp1 = r16
.def rTemp2 = r17
.def rTemp3 = r18
.def rTemp4 = r19
.def rTemp5 = r20
.def rTemp6 = r21
.def rSIPO = r22
.def rZustand = r23

RESET:
  
  cli ;Global Interrupt disable


  ;Ein- und Ausgänge festlegen (0=EIN, 1=AUS)
  ldi rTemp1, 0b00000111
  out DDRB, rTemp1
  ;Ausgänge aus- und Pullups einschalten
  ldi rTemp1, 0b00001000
  out PORTB, rTemp1


  ;Stackpointer ans Ende von SRAM setzen
  ldi rTemp1, LOW(RAMEND)
  out SPL, rTemp1


  ;Variablen rücksetzen
  clr rClock2ms
  clr rClock100ms
  clr rClock1s
  ldi rZustand, 0b10001111
  wdr


  ;Sleepmode einstellen (Power Down)
  ldi rTemp1, (1<<SE)|(1<<SM1)
  out MCUCR, rTemp1
  
  ;Timer0 (für Clock 8bit) konfigurieren
  ldi rTemp1, (1<<CS00)        ;Vorteiler /1
  out TCCR0B, rTemp1
  ldi rTemp1, (1<<TOIE0)        ;Interupt bei overflow erlauben
  out TIMSK0, rTemp1
  
  ; ADC konfigurieren: Vcc als Referenz, Single Conversion
    ldi rTemp1, (1<<MUX1)                  ; Kanal PB3, Referenzspannung Vcc
    out ADMUX, rTemp1
    ldi rTemp1, (1<<ADPS2)      ; VT /16
    out ADCSRA, rTemp1      
  ldi rTemp1, (1<<ADC2D)|(1<<ADC1D)            ;Disable DigPIN bei adc01
  out DIDR0, rTemp1

  ;Watchdog konfigurieren
  ldi rTemp1, (1<<WDTIE)|(1<<WDP2)|(1<<WDP0)        ;Interrupt mode, WD bei 0,5s
  out WDTCR, rTemp1

  ;PCINT konfigurieren
  ldi rTemp1, (1<<PCIE)                  ;PC Interrupt enable
  out GIMSK, rTemp1
  ldi rTemp1, (1<<PCINT3)                  ;PCINT3: PB3
  out PCMSK, rTemp1
  

  sei  ;Global interupt enable
  wdr
  ldi rSIPO, 0b00100000  ;SV erstmal an
  rcall AUSGABE
  
;------------------------------------------------------------------------------------------------------------------------------------------------------


MAIN:


;Modus-Flags abfragen
sbrc rZustand, 6  ;Sleep?
  rjmp SLEEPP
sbrs rZustand, 7  ;Anzeige/Erinnerung?
  rjmp ERINNERUNG

ANZEIGE:
  ;Timer rücksetzen
  clr rClock100ms
  clr rClock1s
  ANZ_LOOP:
    ;Zustand ausgeben
    mov rSIPO, rZustand
    cbr rSIPO, 0b11000000  ;flags aus SIPO entfernen
    sbr rSIPO, 0b00100000  ;SV an lassen
    rcall AUSGABE
    ;prüfe ob Anzeigemodus zuende
    mov rTemp1, rClock1s
    cpi rTemp1, kAnzeigemodus
    brlo ANZ_LOOP
  rjmp SLEEPP

ERINNERUNG:
  ;Zustand ausgeben
  mov rSIPO, rZustand
  cbr rSIPO, 0b11000000  ;flags aus SIPO entfernen
  sbr rSIPO, 0b00100000  ;SV an lassen
  rcall AUSGABE
  ;Timer rücksetzen
  clr rClock2ms
  ERI_LOOP:
    ;prüfe ob Erinnerung zuende
    mov rTemp1, rClock2ms
    cpi rTemp1, kErinnerung
    brlo ERI_LOOP
    ;LEDs erst aus
    ldi rSIPO, 0b00100000
    rcall AUSGABE

SLEEPP:
  ;Sleepflag
  sbr rZustand, 0b01000000
  cbr rZustand, 0b10000000
  ;SV und LEDs Aus
  ldi rSIPO, 0b00000000
  rcall AUSGABE
  sleep
rjmp MAIN

;------------------------------------------------------------------------------------------------------------------------------------------------------


CLOCK:
  push rTemp1      ;SREG und rTemp1 sichern
  in rTemp1, SREG
  push rTemp1

  inc rClock2ms
  ldi rTemp1, 50
  cp rClock2ms, rTemp1
    brsh INCR100ms
    rjmp CLOCKENDE
  INCR100ms:
    clr rClock2ms
    inc rClock100ms
    ldi rTemp1, 10
    cp rClock100ms, rTemp1
      brsh INCR1s
    rjmp CLOCKENDE
  INCR1s:
    clr rClock100ms
    inc rClock1s
    ldi rTemp1, 60
    cp rClock1s, rTemp1    ;max Anzahl s erreicht?
      brlo CLOCKENDE
      clr rClock1s
  CLOCKENDE:

  pop rTemp1      ;SREG und rTemp1 widerherstellen
  out SREG, rTemp1
  pop rTemp1
reti


AUSGABE:  ;(rSIPO=Data)
  push rTemp1      ;SREG und rTemp sichern
  in rTemp1, SREG
  push rTemp1
  push rTemp2
    
    mov rTemp2, rSIPO
    ldi rTemp2, 0b00100000
    ldi rTemp1, 8
    AUSGABE_NEXT:
      cbi PORTB, 0
      cbi PORTB, 1
      rol rTemp2
      brcc AUSGABE_0
      sbi PORTB, 1
      AUSGABE_0:
      sbi PORTB, 0
      dec rTemp1
      brne AUSGABE_NEXT
    sbi PORTB, 2
    cbi PORTB, 2

  pop rTemp2
  pop rTemp1      ;SREG und rTemp wiederherstellen
  out SREG, rTemp1
  pop rTemp1
ret


TESTMODUS:
  push rTemp1      ;SREG und rTemp sichern
  in rTemp1, SREG
  push rTemp1

ldi rSIPO, 0b00101111  ;SV und LEDs ein
rcall AUSGABE
TES_LOOP:
  wdr
  sbis PINB, 3    ;Taster noch gedrückt?
    rjmp TES_LOOP

  pop rTemp1      ;SREG und rTemp wiederherstellen
  out SREG, rTemp1
  pop rTemp1
reti


MESSUNG:
sbr rSIPO, 0b00110000  ;SV und Messstrom ein
rcall AUSGABE
  push rTemp1      ;SREG und rTemp sichern
  in rTemp1, SREG
  push rTemp1
  push rTemp2
  push rTemp3
  push rTemp4
  push rTemp5
  push rTemp6

    wdr
    //evtl. warten
    ldi rTemp1, (1<<ADEN)|(1<<ADSC)  ;ADC aktivieren und starten
    out ADCSRA, rTemp1
    MES_NFERTIG:
      in rTemp1, ADCSRA
      sbrc rTemp1, ADSC    ;fertig?
      rjmp MES_NFERTIG
    cbr rSIPO, 0b00010000  ;Messtrom aus
    rcall AUSGABE
    in rTemp2, ADCL
    in rTemp3, ADCH
    ldi rTemp1, (0<<ADEN)  ;ADC deaktivieren
    out ADCSRA, rTemp1

    ;LOOKUP ergebnis in rTemp6
    clr rTemp6        ;erster Torwert
    ldi ZL, low(LOOKUP*2)    ;laden des ersten Vergleichwertes
    ldi ZH, high(LOOKUP*2)
    MES_NEXTVAL:
      inc rTemp6      ;nächster Torwert
      lpm rTemp4, Z+    ;Vergleichwert Low
      lpm rTemp5, Z+    ;Vergleichwert High
      cp rTemp2, rTemp4  ;prüfe ob drunter
      cpc rTemp3, rTemp5
      brlo MES_NEXTVAL
    dec rTemp6    ;wieder eins zurück
    cbr rTemp6, 0b11110000

    ldi rTemp6, 0b00001001

    ;Alle Tore aus?
    cpi rTemp6, 0b00000000
    breq MES_SLEEPMODUS    ;Ja
    ;Nein:

    ;Anderungen?
    mov rTemp2, rZustand
    cbr rTemp2, 0b11000000  ;evtl Flags entfernen
    cp rTemp6, rTemp2
    brne MES_ANZEIGEMODUS  ;Ja
    ;Nein:

    ;war Anzeigemodus aktiv?
    sbrs rZustand, 7
    rjmp MES_ERINNERMODUS  ;Nein
    ;Ja

    rjmp MES_ENDE

    MES_SLEEPMODUS:
      ;Sleepflag, Zustand 0000
      ldi rZustand, 0b01000000
      rjmp MES_ENDE

    MES_ANZEIGEMODUS:
      ;Zustand übernehmen
      mov rZustand, rTemp6
      ;Anzeigeflag
      sbr rZustand, 0b10000000  ;Anzeigemodusflag setzen
      cbr rZustand, 0b01000000  ;Sleepflag aus
      rjmp MES_ENDE

    MES_ERINNERMODUS:
      ;Erinnerungsflag
      cbr rZustand, 0b11000000

MES_ENDE:
  pop rTemp6
  pop rTemp5
  pop rTemp4
  pop rTemp3
  pop rTemp2
  pop rTemp1      ;SREG und rTemp wiederherstellen
  out SREG, rTemp1
  pop rTemp1
  reti


  
;------------------------------------------------------------------------------------------------------------------------------------------------------


LOOKUP:
  .dw 978
  .dw 891
  .dw 818
  .dw 751
  .dw 694
  .dw 652
  .dw 616
  .dw 568
  .dw 526
  .dw 504
  .dw 484
  .dw 464
  .dw 445
  .dw 430
  .dw 417
  .dw 0

[Anonymous U. (gastt)]

Was ich noch weiß:

Attiny ist im sleep. Er wird durch WD-Timer geweckt (ca. 0,5s). Bei 
wecken (WD-interrupt) wird was mit adc gemessen... Danach wird Flag für 
Anzeigemodus gesetzt. Danach reti. Jetzt springt er ins Hauptprogramm 
Main. Dort wird Flag ausgewertet und er springt wieder zum Anzeigemodus.
Diese falsche SIPO-Ausgabe muss zwischen dem Flag setzen und dem 
Anzeigemodus passieren.

[Anonymous U. (gastt)]

Ich hab noch was rausgefunden: Es muss mit den Interrupts 
zusammenhängen: wenn ich in meinem Unterprogramm Interrupts verbiete 
(cli und zum schluss sei), so hab ich diese Probleme nicht.

Wo liegt die Ursache? ich hab doch alle register schön gesichert?!?!

[chris (Gast)]

na denn simuliere es doch mal richtig wenn du es schon auf die 
INTroutine eingrenzen konntest

[Helmut H. (helmuth)]

Hi

.org 0x0008      ;WD interrupt
  rjmp MESSUNG
.org 0x0009      ;ADC Conversion Complete
  //rjmp ADC_READY

Was passiert wenn der ADC Conversion Complete Interrupt auftritt?
würde das auskommentierte mal durch ein RETI ersetzen.

[Anonymous U. (gastt)]

Das Problem ist, dass es zufällig passiert.

[Anonymous U. (gastt)]

Helmut H. schrieb:
> Was passiert wenn der ADC Conversion Complete Interrupt auftritt?
> würde das auskommentierte mal durch ein RETI ersetzen.

dieser Interrupt ist disabled. Und ich hab auch schon mal das ganze 
adc-Zeugs auskommentiert: hilft leider nichts.

[Karl H. (kbuchegg)]

GLeich vorweg.
Dein Code ist zu umfangreich, als das ich ihn hier im Kopf auf alle 
Eventualitäten abklopfen könnte.

Aber hier ist mir, im Zusammenhang  mit deinem letzten Posting, etwas 
aufgefallen

Du rufst

TESTMODUS:
  push rTemp1      ;SREG und rTemp sichern
  in rTemp1, SREG
  push rTemp1

ldi rSIPO, 0b00101111  ;SV und LEDs ein
rcall AUSGABE
TES_LOOP:
  wdr
  sbis PINB, 3    ;Taster noch gedrückt?
    rjmp TES_LOOP

  pop rTemp1      ;SREG und rTemp wiederherstellen
  out SREG, rTemp1
  pop rTemp1
reti

die Funktion AUSGABE aus dem Interrupt heraus auf.
Was, wenn die Funktion Ausgabe gerade läuft, die ersten Bits 
rausgetaktet hat, dann kommt der Interrupt und leiert seinerseits wieder 
die Ausgabe an.

Dann kommt alles durcheinander.
Stell sicher, dass du für Shared Resources (also alles was es nur ein 
einziges mal gibt, so wie das Schieberegister) immer einen einzigen 
gesicherten Pfad hast, der einzig und ausschliesslich benutzt wird. 
Nicht so wie hier, dass eine Ausgabe durch einen Interrupt unterbrochen 
werden kann, der dann selbst wieder eine Ausgabe macht. Das ist ein 
Garant für Ärger.

[Karl H. (kbuchegg)]

Selbiges hier

MESSUNG:
sbr rSIPO, 0b00110000  ;SV und Messstrom ein
rcall AUSGABE
...

Tus nicht. Du öffnest die Büchse der Pandora.
Es gibt nur eine Stelle, an der Aufrufe an AUSGABE gemacht werden 
dürfen. Und das ist die Hauptschleife. Oder alternativ: es gibt nur und 
ausschliesslich Aufrufe dieser Funktion in ISR-Routinen.
Aber auf keinen Fall in beidem: Hauptschleife und ISR.

[Anonymous U. (gastt)]

Karl Heinz schrieb:
> die Funktion AUSGABE aus dem Interrupt heraus auf.
> Was, wenn die Funktion Ausgabe gerade läuft, die ersten Bits
> rausgetaktet hat, dann kommt der Interrupt und leiert seinerseits wieder
> die Ausgabe an.

Ja klaaar! Ich bin ja ein Depp! Der halbe Tag fürn A... :-D Das passiert 
mir mit sicherheit nicht nochmal!

Karl Heinz schrieb:
> Tus nicht. Du öffnest die Büchse der Pandora.
> Es gibt nur eine Stelle, an der Aufrufe an AUSGABE gemacht werden
> dürfen. Und das ist die Hauptschleife. Oder alternativ: es gibt nur und
> ausschliesslich Aufrufe dieser Funktion in ISR-Routinen.
> Aber auf keinen Fall in beidem: Hauptschleife und ISR.

Ok, du hast absolut recht. Ich denke ich machs hier mal quick and dirty 
und disable die Interrupts am Anfang der Ausgabe und enable sie am ende 
wieder.

Ein herzliches Dankeschön!