SDKarte SPI gibt seltsame Antwort

[Leo M. (crashc)]

Hallo,

ich versuche seit einigen Tagen eine SD-Karte mit einem ATMega8 über 
Hardware SPI anzusteuern.
Ich habe bereits mehrere SD-Karten ausprobiert. Der ATMega8 läuft mit 
einer Frequenz von 9,216 MHz. (Der SPI-Vorteiler auf 128 eingestellt)

Meine Idee bisher war:
1. uC startet.
2. einige ms warten (um der SDKarte Zeit zum initialisieren zu geben)
3. einige Male die SCK-Leitung Pulsen (bzw. 0xFF senden)
4. CMD0 senden (0x40,0x00,0x00,0x00,0x00,0x95)
5. auf ein 0x01 der SD-Karte warten (bzw. 0xFF senden)

Diesen ASM-Sourcecode habe ich mal unten angehängt. (Er erzielt kein 
Resultat)

Wenn ich mir die Rückgabe der SD-Karte per UART an den PC senden lasse 
erhalte ich folgendes:
bei Schritt 3: 0x00 ...
bei Schritt 4: 0x00 ...
bei Schritt 5: 0x3F 0xE0 0x3F 0xFF 0xFF 0xFF...

Das Ergebnis bei Schritt 5 entspricht ja keinem "R1 Response", da ich 
dort ja nur ein Byte zurück erhalten würde. Was also antwortet mir die 
SD-Karte dort? Liegt es vielleicht an meiner "Hardware"? Ich habe einen 
Schaltplan meines Pegelwandlers beigefügt.

Ich wäre wirklich froh, wenn mir jemand bei der Interpretation dieser 
Daten helfen könnte oder auch Ideen/Verbesserungen geben, die zur Lösung 
beitragen könnten. Ich besitze leider kein Oszilloskop mit dem ich den 
MISO-Pegel betrachten könnte.

MfG Leonardo

PS:

main.asm

.include "m8def.inc"

.org 0x000
  rjmp main

.include "spi.inc"

.def temp  = R16
.def com_length = R17
.def temp2 = R18
.def temp3 = R19



main:
  ldi temp, HIGH(RAMEND)
  out SPH, temp
  ldi temp, LOW(RAMEND)
  out SPL, temp

  rcall InitSPI

  ; Ein paar Millisekunden warten
  ldi temp, 0xFF
  ldi temp2, 0xFF
  ldi temp3, 0x10

lp:
  dec temp
  brne lp
  dec temp2
  brne lp
  dec temp3
  brne lp

  ; SS auf LOW ziehen
  cbi PORTB, PB1

  ; SCK 255 mal pulsen
  ldi temp, 255
pre:
  ldi sendbyte, 0xFF
  rcall SendSPI
  dec temp
  brne pre

  ; CMD0 senden

  ldi ZH, HIGH(command0*2)
  ldi ZL,  LOW(command0*2)

  ldi com_length, 6
loop:
  lpm
  mov sendbyte, R0
  rcall SendSPI
  adiw ZL, 1
  
  dec com_length
  brne loop

  ; Auf Antwort warten
endl:
  ldi sendbyte, 0xFF
  rcall SendSPI
  
  cpi sendbyte, 0x01  // 0x01 = successful
  breq success

  rjmp endl

success:
  ldi temp, 0xFF
  out DDRD, temp
  out PORTD, temp
  rjmp success



command0:
  .db 0x40, 0x00, 0x00, 0x00, 0x00, 0x95

spi.inc

.include "m8def.inc"

.def sendbyte = R21


InitSPI:
  ; Set MOSI, SCK and PB1 (connected to SS) as Output


  ldi temp , (1<<PB3) | (1<<PB5) | (1<<PB2) | (1<<PB1)
  out DDRB, temp

  
  ; SS auf HIGH ziehen
  sbi PORTB, PB1


  ; Enable SPI, Master, CLK to 1/128 frq, Mode 0

  ldi temp, (1<<SPE) | (1<<MSTR) | (1<<SPR1) | (1<<SPR0)
  out SPCR, temp

  ret

  
SendSPI:
  out SPDR, sendbyte
WaitSPI:
  sbis SPSR, SPIF
  rjmp WaitSPI
  in sendbyte, SPDR
  ret

[Bampi (Gast)]

Uiii. Da wird dir keiner Weiterhelfen.
Lerne C und setze eine fertige Lib ein.

[Sascha W. (sascha-w)]

Hallo Leo,

ich häng dir mal meine mmc.inc an, das hab ich mal aus dem C-Code von 
Ulrich Radig übersetzt und tut schon seit Jahren seinen Dienst.

Sascha

[holger (Gast)]

>Ich besitze leider kein Oszilloskop mit dem ich den
>MISO-Pegel betrachten könnte.

Schade, dann könntest du vieleicht sehen wie schei..e
deine Pegelwandler sind.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Mir scheint die Pegelwandlerschaltung sehr windig für 10MHz SPI Takt...

Probiers mal mit 1MHz.

Es ist übrigens echt unglaublich umständlich, eine solche Schnittstelle 
ohne Oszi in Betrieb zu nehmen. Du weißt ja überhaupt nichts über die 
Signalqualität.

[Jim M. (turboj)]

Leo M. schrieb:
> ; SS auf LOW ziehen
>   cbi PORTB, PB1
>
>   ; SCK 255 mal pulsen
>   ldi temp, 255
> pre:
>   ldi sendbyte, 0xFF
>   rcall SendSPI
>   dec temp
>   brne pre
>
>   ; CMD0 senden

Die Dummy Clocks werden mit CS HIGH gesendet, denn die Karte ist hier 
noch im SD Modus. Es werden mindestens 80 Clocks benötigt, Du sendest 
255*8 - was aber nicht stört.

Erst für das CMD0 muss CS auf Low gezogen werden.

Außerdem fehlt im Schaltplan der Pullup (10k IIRC) an SD_MISO. Diese 
Leitung ist bis zum CMD0 ein Open Drain. Der Pegelwandler ist hier 
sinnfrei, da 3.3 Volt Ausgänge auch für 5 Volt Eingänge ausreichend 
Pegel haben.

[Leo M. (crashc)]

Jim Meba schrieb:
> Erst für das CMD0 muss CS auf Low gezogen werden.

Genau dort scheint der Knackpunkt gelegen zu haben. Vielen Dank, Jim 
Meba!

Vielen Dank auch an alle anderen für euer Feedback zu dem Pegelwandler! 
Bis jetzt arbeite ich ja (mit dem Prescaler 128) nur bei einer Frequenz 
von 72kHz. Wenn ich dann später die Geschwindigkeit erhöhen will, werden 
diese Informationen bestimmt sehr nützlich sein.

MfG Leonardo

PS: Das war mein erster Beitrag in diesem Forum und ich finde die 
Hilfsbereitschaft hier extrem Klasse! Daumen hoch!