eigentümliches Verhalten eines Übungsprog. in Asm.

[Fritz B. (kleinfritzchen)]

Hallo,
hab grad mal eine kleine Übung gemacht und hab hier ein eigentümliches 
Verhalten das eine Led so halb leuchtete obwohl sie von de logic 
eigentlich aus angehen soll wenn ein Taster nicht gedrückt ist.
Kann mir das mal jemand erklären?
Unser Lehrer auf der VHS hat uns das als aufgabe mitgegeben mal 
irgendwas neben dem Interrupt zu machen, aber er wusste anscheinend das 
das Probleme gibt.
Hier der Code:

;----------------------------------------------------------------------
; Title    : myAVR Beispiel "Signalton mit Timer0" für den ATmega8
;----------------------------------------------------------------------
; Funktion    : Ausgabe des Kammertion A
; Schaltung    : PORTB.0=Summer, PORTB.1=LED-Rot
;----------------------------------------------------------------------
; Prozessor    : ATmega8
; Takt    : 3,6864 MHz
; Sprache    : Assembler
; Datum    : 09.11.2007
; Version    : 1.0
; Autor    : Renaldo Badke
; Programmer  :
; Port    :
;----------------------------------------------------------------------
.equ  F_CPU,  1000000
.include  "avr.h"
;-----------------------------------------------------------------------
;Reset and Interruptvectoren  ;VNr.  Beschreibung
begin:
  rjmp  main  ; 1    POWER ON RESET
  reti    ; 2    Int0-Interrupt
  reti    ; 3    Int1-Interrupt
  reti    ; 4    TC2 Compare Match
  reti    ; 5    TC2 Overflow
  reti    ; 6    TC1 Capture
  reti    ; 7    TC1 Compare Match A
  reti    ; 8    TC1 Compare Match B
  reti    ; 9    TC1 Overflow
  rjmp  onTC0  ;10    TC0 Overflow
  reti    ;11    SPI, STC Serial Transfer Complete
  reti    ;12    UART Rx Complete
  reti    ;13    UART Data Register Empty
  reti    ;14    UART Tx Complete
  reti    ;15    ADC Conversion Complete
  reti    ;16    EEPROM Ready
  reti    ;17    Analog Comperator
  reti    ;18    TWI (I²C) Serial Interface
  reti    ;19    Strore Program Memory Ready
;------------------------------------------------------------------------
;Start, Power ON, Reset
main:
  ldi  r16,lo8(RAMEND)
  out  ioSPL,r16  ;Init Stackpointer LO
  ldi  r16,hi8(RAMEND)
  out  ioSPH,r16  ;Init Stackpointer HI

  sbi  ioDDRB,0  ;OUT Summer
  sbi  ioDDRB,1  ;OUT LED
  cbi  ioDDRD,2  ;Taster als eingang
  sbi  ioDDRC,0  ;Led

  ldi  r16,0b0000101
  out  ioTCCR0,r16  ;Timer0 setup 1/14 Sekunde 3686400/1024
  ldi  r16,0b0000001
  out  ioTIMSK,r16  ;Interrupt Timer0 bei overflow

  ldi  r17,190  ;Timer0 Init
  out  ioTCNT0,r17  ;ausgeben
  ldi  r16,0  ;Ausgabewert LOW
  sei
;------------------------------------------------------------------------
mainloop:
  wdr
  sbis  ioPIND,2  ;Taster offen
  rjmp  end
  cbi  ioPORTC,0  ;Led aus
  rjmp  raus
end:  sbi  ioPORTC,0  ;Led an
raus:  rjmp  mainloop
;------------------------------------------------------------------------
onTC0:
  cli    ;Interrupts sperren
  push  r16
  push  r17
  in  r16,ioPORTB  ;PORTB einlesen
  com  r16  ;Einerkomplement, Bitweise Negation
  out  ioPORTB,r16  ;PORTB umschalten (Signalwechsel)
  ldi  r17,19  ;berechneter Reinit-Wert
  out  ioTCNT0,r17  ;Timer Reinit
  pop   r17
  pop  r16
  sei    ;Interrupt freigeben
  reti    ;Rücksprung
;------------------------------------------------------------------------

[c-hater (Gast)]

Fritz Bie schrieb:

> hab grad mal eine kleine Übung gemacht und hab hier ein eigentümliches
> Verhalten das eine Led so halb leuchtete obwohl sie von de logic
> eigentlich aus angehen soll wenn ein Taster nicht gedrückt ist.
> Kann mir das mal jemand erklären?

Nö, eigentlich sollte das so funktionieren, wie du es gepostet hast. 
Ansonsten gäbe es aber trotzdem eine Menge an dem Programm zu bemeckern.

> mainloop:
>   sbis  ioPIND,2  ;Taster offen

Der Kommentar ist schonmal Mist, bei einer Verzweigung sollte man 
insbesondere so kommentieren, daß nachvollziehbar ist, welcher der 
beiden möglichen Wege unter welcher Bedingung genommen wird

>   rjmp  end
>   cbi  ioPORTC,0  ;Led aus
>   rjmp  raus
> end:  sbi  ioPORTC,0  ;Led an
> raus:  rjmp  mainloop

Zwei der drei Sprünge sind völlig überflüssig und wenn schon 
überflüssige Sprünge (für ein Lernprogramm ist sowas durchaus 
akzeptabel), dann sollte man aber wenigstens sinnvolle Namen für die 
Labels der Sprungziele vergeben.

Also die langsame Variante mit den überflüssigen Sprüngen sollte 
ungefähr so aussehen:

mainloop:
  sbis ioPIND,2     ;Taster offen?
  rjmp led_an       ;ja
  cbi ioPORTC,0     ;nein: LED aus
  rjmp mainloop_end
led_an:
  sbi ioPORTC,0
mainloop_end:
  rjmp mainloop


> ; Takt    : 3,6864 MHz
> .equ  F_CPU,  1000000

Das widerspricht sich fürchterlich, das ist aber im Rahmen dieses 
Programms irrelevant. Allerdings würde die zweite Zeile überhaupt nicht 
assembliert werden können. Diese Tatsache läßt mich stark vermuten, daß 
das gepostete Programm mal wieder nicht mit dem identisch ist, was du 
tatsächlich auf deinem Controller laufen lassen hast...

> onTC0:
>   cli    ;Interrupts sperren

Unnötig, beim Eintritt in eine ISR sind die Interrupts ohnehin gesperrt.

>   sei    ;Interrupt freigeben

Das ist genauso unnötig (wird sowieso vom nachfolgenden reti erledigt)

[Rainer V. (rudi994)]

Falls für myAVR Board-MK2: Muß da nicht der Pull-up für den Taster 
eingeschaltet werden? Also hinter cbi ioDDRD,2 noch ein sbi ioPORTD, 2

[Detlef K. (adenin)]

Hängt an Port C überhaupt eine LED? ;)
Also die an Port B leuchtet ganz sicher und logisch nur "halb".

[Fritz B. (kleinfritzchen)]

Hallo, danke für die Hinweise!!!!
werd ich gleich mal umsetzen.
Fehler gefunden!
es war tatsachlich der fehlende PUll-UP Befehl. Mit funktioniert es wie 
es soll!
Danke an alle!!!
MfG Fritz