RS232 und Tastatur zusammenbringen?

[peter (Gast)]

Hallo, guten Tag.
Ich habe mit diesen beiden Programmen Schwierigkeiten, diese miteinander 
zu verbinden.

Tastatur abfragen und die Daten zu versenden zum PC? Bekomme das 
combinatorisch nicht hin.

Im ersten Programm gebe ich mit dem Switch ein Byte ein (TX_Data) und 
Sende es zum PC mit der Taste key.
Das funktioniert auch.
Im zweiten Programm werte ich die Daten von der Tastaur aus und gebe den 
ASCII-Wert(RxData) auf 8-LED am DE-1 aus.
Auch hier funktioniert es wunderbar.

Ich weiss nicht , wie ich diese beiden Programme verbinde damit sie 
funktionieren.
Beim RS2322 wird ja erst gesendet nach dem Key-Druck und das muss ja 
jetzt geschehen wenn die Tastatur die
Daten ablegt in TX_Data ohne ein Druckschalter zu betätigen.

Wer kann mir mal bitte ausführlich helfen?

Danke.
Gruss

RS232:

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;

entity RS232_tx is

Generic ( Quarz_Taktfrequenz : integer   := 50000000;  -- Hertz 
          Baudrate           : integer   :=  9600      -- Bits/Sec
          ); 
           
port (  TXD     : out  STD_LOGIC;
        CLK     : in   STD_LOGIC; 
        key     : in   std_logic_vector(0 downto 0);  
        TX_Data : in STD_LOGIC_VECTOR (7 downto 0) := (others => '0')
         );
end RS232_tx;

architecture Behavioral of RS232_tx is

signal txstart  : std_logic := '0';
signal txsr     : std_logic_vector  (9 downto 0) := "1111111111";  -- Startbit, 8 Datenbits, Stopbit
signal txbitcnt : integer range 0 to 10 := 10;
signal txcnt    : integer range 0 to (Quarz_Taktfrequenz/Baudrate)-1;
signal tx_start  : STD_LOGIC :='0';

begin

-- Senden
process(clk)
begin
if rising_edge(clk) then
  
  if key(0) = '0' then
     tx_start <= '1' ;
  else
     tx_start <= '0';
  end if;
  
  txstart <= TX_Start;
  if (TX_Start='1' and txstart='0') then -- steigende Flanke, los gehts
    txcnt    <= 0;                       -- Zähler initialisieren
    txbitcnt <= 0;                      
    txsr     <= '1' & TX_Data & '0';     -- Stopbit, 8 Datenbits, Startbit, rechts gehts los
  else
    if(txcnt<(Quarz_Taktfrequenz/Baudrate)-1) then
      txcnt <= txcnt+1;
    else  -- nächstes Bit ausgeben  
      if (txbitcnt<10) then
        txcnt    <= 0;
        txbitcnt <= txbitcnt+1;
        txsr     <= '1' & txsr(txsr'left downto 1);
      end if;
    end if;
  end if;
end if;
end process;

TXD  <= txsr(0);  -- LSB first  
end Behavioral;

Tastatur:

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;

entity PS2_Keyboard is
    Port ( PS2_Data    : in  std_logic;
           PS2_Clk     : in  std_logic;
           CLK         : in  std_logic;
           RxData      : out std_logic_vector(7 downto 0);
           RxActive    : out std_logic;
           DataReady   : out std_logic -- Handshake-Signal: Daten bereit     
          );           
end PS2_Keyboard;

architecture Behavioral of PS2_Keyboard is

signal RxTimeout   : integer range 0 to 500000 := 0; -- max. 10ms
signal RxRegister  : std_logic_vector(10 downto 0) := (others=>'1');
signal DataSR      : std_logic_vector(1 downto 0)  := (others=>'1');
signal ClkSR       : std_logic_vector(1 downto 0)  := (others=>'1');
signal DataFetched : std_logic :='1'; -- Handshake-signal: Daten übernommen

type PS2RXStateType is (IDLE, RECEIVE, READY); 
signal PS2RXState : PS2RXStateType := IDLE;

begin
process(clk) 
begin
if rising_edge(clk)then
  RxTimeout <= RxTimeout+1;
  
  DataSR    <= DataSR(0) & PS2_Data;
  ClkSR     <= ClkSR(0)  & PS2_Clk;
  
  if (ClkSR = "10") then -- fallende Flanke am PS2_CLK
    RxRegister <= DataSR(1) & RxRegister(10 downto 1);
  end if;

  case PS2RXState is
  when IDLE =>
    RxRegister <= (others=>'1');
    RxActive   <= '0';
    DataReady  <= '0';
    RxTimeout  <= 0;
    if (DataSR(1) = '0' and ClkSR(1) = '1') then -- STARTBIT erkannt
      PS2RXState <= RECEIVE;
      RxActive   <= '1';       
    end if;
    
  when RECEIVE =>
    if (RxTimeout = 500000) then     -- 10 ms
      PS2RXState <= IDLE;
    elsif (RxRegister(0) = '0') then -- Startbit ganz durchgeschoben?
      DataReady  <= '1';             -- SCANCODE empfangen
      RxData     <= RxRegister(8 downto 1);
      PS2RXState <= READY;
    end if;
    
  when READY =>                      -- warten, bis Daten abgeholt sind
    if (DataFetched='1') then
      PS2RXState <= IDLE;
      DataReady  <= '0';
      RxActive   <= '0';            
     end if;
  end case;
end if;    
end process;
 
end Behavioral;

[Uwe (Gast)]

Indem du in der PS2 Statemachine im RECEIVE State in einen weiteren 
State weiterschaltest der darauf wartet das Jemand die Daten abholt. 
Dieses muß dieser Jemand aber Signalisieren (das die Daten abgeholt 
wurden), erst dann wird wieder in den READY State weitergeschaltet. Die 
RS232 sollte auch als Statemachine implemtiert werden, diese wartet auf 
DataReady=1 und holt die Daten ab und Signalisiert, daß sie die Daten 
abgeholt hat.
Dies könnte man noch mit einem FIFO erweitern damit keine Daten verloren 
gehen, aber soweit ich weiß hat ne PS2 Tastatur schon einen FIFO drin.
Dann solltest du noch nen Busy Signal  (bzw. Ready Signal) in der RS232 
drin haben damit die PS2 solange wartet bis die RS232 ihre Daten 
gesendet hat.

[peter (Gast)]

Hmm.., danke.
Das hört sich ja nicht einfach an.


Gruss

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

peter schrieb:
> Ich weiss nicht , wie ich diese beiden Programme verbinde damit sie
> funktionieren.
Es sind keine Programme und sie funktionieren ja schon. Du könntest 
übrigens wenigstens erwähnen, woher du die Beschreibungen kopiert hast, 
dann müsste man nicht raten...
http://www.lothar-miller.de/s9y/archives/48-RS232.html
http://www.lothar-miller.de/s9y/archives/75-PS2-Tastatur.html

> Ich weiss nicht , wie ich diese beiden Programme verbinde damit sie
> funktionieren.
Du brauchst jetzt ein Toplevel Modul, in dem diese beiden Komponenten 
instantiiert werden (Zu finden im VHDL Buch unter dem Stichwort 
"component").

> Beim RS2322 wird ja erst gesendet nach dem Key-Druck und das muss ja
> jetzt geschehen wenn die Tastatur die
> Daten ablegt in TX_Data ohne ein Druckschalter zu betätigen.
Ich würde es mit meinen originalen Beschreibungen im ersten Anlauf so 
probieren:

  TX_Data     <= RxData;    -- Daten vom PS2 an RS232 geben
  Tx_Start    <= DataReady; -- Übertragung starten, wenn PS2 Daten hat
  DataFetched <= DataReady; -- PS2 gibt sich selber den Handshake

[peter (Gast)]

Jup danke.
Es kommen jetzt Daten am PC an, aber noch nicht der gedrückte ASCII.

Danke.

GRuss

[Uwe (Gast)]

Jo ne Tastatur gibt Scancodes aus.
http://www.marjorie.de/ps2/ps2_keyboard.htm

[peter (Gast)]

JUp danke Lothar, deine 3 Zeilen waren entscheidend.
Es kommt am PC der "Keyboard Scan Codes: Set 2" von hier (Hilfe von Uwe) 
http://www.marjorie.de/ps2/scancode-set2.htm an.
Dauertastendruck funktioniert sauber und beim loslassen kommt Hex"F0".

Danke.
Gruss

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;

entity PS2_Keyboard_tx is
 Generic ( Quarz_Taktfrequenz : integer   := 50000000;  -- Hertz 
           Baudrate           : integer   :=  9600      -- Bits/Sec
         ); 
         
    Port ( PS2_Data  : in  std_logic;
           PS2_Clk   : in  std_logic;
           CLK       : in  std_logic;
           TXD       : out  STD_LOGIC
          );           
end PS2_Keyboard_tx;

architecture Behavioral of PS2_Keyboard_tx is

signal RxTimeout   : integer range 0 to 500000 := 0; -- max. 10ms
signal RxRegister  : std_logic_vector(10 downto 0) := (others=>'1');
signal DataSR      : std_logic_vector(1 downto 0)  := (others=>'1');
signal ClkSR       : std_logic_vector(1 downto 0)  := (others=>'1');
signal DataFetched : std_logic :='1'; -- Handshake-signal: Daten übernommen
signal RxActive    : std_logic;
signal DataReady   : std_logic; -- Handshake-Signal: Daten bereit    
signal RxData      : std_logic_vector(7 downto 0);

signal txstart     : std_logic := '0';
signal txsr        : std_logic_vector  (9 downto 0) := "1111111111";  -- Startbit, 8 Datenbits, Stopbit
signal txbitcnt    : integer range 0 to 10 := 10;
signal txcnt       : integer range 0 to (Quarz_Taktfrequenz/Baudrate)-1;
signal TX_Data     : STD_LOGIC_VECTOR (7 downto 0); 
signal TX_Start    : STD_LOGIC;
signal TX_Busy     : STD_LOGIC;

type PS2RXStateType is (IDLE, RECEIVE, READY); 
signal PS2RXState : PS2RXStateType := IDLE;

begin

process(clk) 

begin
if rising_edge(clk)then
  RxTimeout <= RxTimeout+1;
  
  DataSR    <= DataSR(0) & PS2_Data;
  ClkSR     <= ClkSR(0)  & PS2_Clk;
  
  if (ClkSR = "10") then -- fallende Flanke am PS2_CLK
    RxRegister <= DataSR(1) & RxRegister(10 downto 1);
  end if;

  case PS2RXState is
  when IDLE =>
    RxRegister <= (others=>'1');
    RxActive   <= '0';
    DataReady  <= '0';
    RxTimeout  <= 0;
    if (DataSR(1) = '0' and ClkSR(1) = '1') then -- STARTBIT erkannt
      PS2RXState <= RECEIVE;
      RxActive   <= '1';       
    end if;
    
  when RECEIVE =>
    if (RxTimeout = 500000) then     -- 10 ms
      PS2RXState <= IDLE;
    elsif (RxRegister(0) = '0') then -- Startbit ganz durchgeschoben?
      DataReady  <= '1';             -- SCANCODE empfangen
      RxData     <= RxRegister(8 downto 1);
      PS2RXState <= READY;
    end if;
    
  when READY =>                      -- warten, bis Daten abgeholt sind
    if (DataFetched='1') then
      PS2RXState <= IDLE;
      DataReady  <= '0';
      RxActive   <= '0';         
     end if;
  end case;
end if;    
end process;

process(clk)
  begin
    if rising_edge(clk) then 
      txstart <= TX_Start;
      if (TX_Start='1' and txstart='0') then -- steigende Flanke, los gehts
         txcnt    <= 0;                      -- Zähler initialisieren
         txbitcnt <= 0;                      
         txsr     <= '1' & TX_Data & '0';    -- Stopbit, 8 Datenbits, Startbit, rechts gehts los
      else
         if(txcnt<(Quarz_Taktfrequenz/Baudrate)-1) then
            txcnt <= txcnt+1;
         else  -- nächstes Bit ausgeben  
            if (txbitcnt<10) then
              txcnt    <= 0;
              txbitcnt <= txbitcnt+1;
              txsr     <= '1' & txsr(txsr'left downto 1);
            end if;
         end if;
      end if;
    end if;  
  end process;
   
   Tx_Start   <= DataReady; -- Übertragung starten, wenn PS2 Daten hat    
   DataFetched <= DataReady; -- PS2 gibt sich selber den Handshake
   TX_Data    <= RxData;    -- Daten vom PS2 an RS232 geben
   
   TXD     <= txsr(0);  -- LSB first
   TX_Busy <= '1' when (TX_Start='1' or txbitcnt<10) else '0';
 
end Behavioral;