Was muss ich bitte bei "clock" ändern, es kommt eine Fehlermeldung.

[peter (Gast)]

Hallo, guten Tag.
Ich bekomme diese Fehlermeldung:
Error (10822): HDL error at ram_ram.vhd(58): couldn't implement 
registers for assignments on
this clock edge.

Ich weis nicht, was ich da ändern soll?

Danke.
Gruss

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
use ieee.std_logic_arith.all;

entity ram_ram is port(
  clock : in  std_logic;
  led_g : out STD_LOGIC_VECTOR(7 downto 0);
  sw0   : in  STD_LOGIC;
  sw1   : in  STD_LOGIC;
  sw2   : in  STD_LOGIC
  ); 
end ram_ram; 
            
architecture Behavioral of ram_ram is

signal we1      : STD_LOGIC :='0';
signal address1 : integer range 0 to 255 := 0; 
signal datain1  : STD_LOGIC_VECTOR(7 downto 0);
signal dataout1 : STD_LOGIC_VECTOR(7 downto 0);

signal we2      : STD_LOGIC;
signal address2 : integer range 0 to 255 := 0; 
signal datain2  : STD_LOGIC_VECTOR(7 downto 0);
signal dataout2 : STD_LOGIC_VECTOR(7 downto 0);

signal cnt      : integer range 0 to 50000000 := 0;

component ram1 port(
  we1      : in  STD_LOGIC; 
  address1 : in  integer range 0 to 255 := 0; 
  datain1  : in  STD_LOGIC_VECTOR(7 downto 0);
  dataout1 : out STD_LOGIC_VECTOR(7 downto 0);
  clock    : in  std_logic
 );
end component;

component ram2 port(
  we2      : in  STD_LOGIC; 
  address2 : in  integer range 0 to 255 := 0; 
  datain2  : in  STD_LOGIC_VECTOR(7 downto 0);
  dataout2 : out STD_LOGIC_VECTOR(7 downto 0);
  clock    : in  std_logic
 );
end component;

begin
io1 : ram1  port map(we1,address1,datain1,dataout1,clock);
io2 : ram2  port map(we2,address2,datain2,dataout2,clock);

process(clock)
variable address_z3 : integer range 0 to 255 := 0; 
variable address_z2 : integer range 0 to 255 := 0; 
variable address_z1 : integer range 0 to 255 := 0; 

begin
  if rising_edge(clock) then
    if (cnt<20000000 and sw2='1') then        
      cnt <= cnt+1;     
    else  
      cnt <= 0;
      we2<='0';
      if address_z1 <= 255 then     
        address_z1 := address_z1 +1;
        address2  <=address_z1;
      end if;  
    end if;  
  end if;
  
  if sw0='1' then
    address_z1:=0;
    address_z2:=0;
    address_z3:=0;
  end if; 
  
  if sw1='1' then
    we2<='1';
    if address_z2 <= 255 then   
      address_z3 := address_z3 +1;    
      address_z2 := address_z2 +1;
      address1<=address_z2;
      address2<=address_z3;
      
      datain2<=dataout1;
    end if;  
  end if; 
end process;  

led_g <= dataout2;
end Behavioral;

[Patrick (Gast)]

peter schrieb:
> if address_z1 <= 255 then
>         address_z1 := address_z1 +1;
>         address2  <=address_z1;
>       end if;
>     end if;

Kann sein, dass das das Problem ist. Du fragst die Adresse mit 
rising_edge ab und inkrementierst sie darauf hin. Da es sich dabei um 
eine Variable handelt, wird diese "sofort" geupdatet und nicht erst zum 
nächsten Takt.

variable address_z3 : integer range 0 to 255 := 0;
variable address_z2 : integer range 0 to 255 := 0;
variable address_z1 : integer range 0 to 255 := 0;

ändere diese variablen mal in signale um, dann sollte es gehn.

[Roger S. (edge)]

Patrick schrieb:
> Kann sein, dass das das Problem ist. Du fragst die Adresse mit
> rising_edge ab und inkrementierst sie darauf hin. Da es sich dabei um
> eine Variable handelt, wird diese "sofort" geupdatet und nicht erst zum
> nächsten Takt.

nope, das waer im Prinzip legitim.

Das Problem ist dass der address_z2 / address_z3 Ramsch nicht im 
getakteten Teil des Prozesses stattfindet, sondern im kombinatorischen.

Zeigt wiedermal ein Vorteil der

wait until rising_edge(clock);

Schreibweise.

Cheers, Roger

[Schlumpf (Gast)]

Du beschreibst Register, deren Ausgänge sich zum einen mit der 
Taktflanke ändern sollen, aber gleichzeitig auch unabhängig von der 
Taktflanke sein sollen.
Sowas gibt es nicht

z.B. hier:

  if rising_edge(clock) then
  ...  address2 <= address_z1;
  end if;
  if sw1='1' then
  ...  address2 <= address_z3;
  end if;

[peter (Gast)]

Danke für eure mühe.

---------------------
      ......
      datain2<=dataout1;
    end if;
  end if;
end if;
end process;
----------------------

Da hatte ich ein "end if;"vergessen.
jetzt werden die Rams beschrieben gelesen und angezeigt mit Led's.

Die Fehlermeldung war für mich nicht nachvollziehbar.

Danke.
Gruss

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

peter schrieb:
> Die Fehlermeldung war für mich nicht nachvollziehbar.
Du hättest es aber recht leicht anhand der Identebenen (Einrückungen) 
sehen können:

process(clock)
begin
  if rising_edge(clock) then
  end if;
  
  if sw0='1' then
  end if; 
  
  if sw1='1' then
  end if; 
end process;  

led_g <= dataout2;
end Behavioral;

Die kann man nämlich gut nutzen, um seinen Quelltext verständlich und 
lesbar darzustellen...

peter schrieb:
> Da hatte ich ein "end if;"vergessen.
Mitnichten! Es  hat nicht gefehlt (das hätte der Synthesizer shcon 
angemeckert, probiers aus), sondern es war an der falschen Stelle, so 
dass du Hardware beschrieben hast, die der Synthesizer nicht umsetzen 
kann.

[peter (Gast)]

Hmm.., verstehe ich jetzt nicht.

so war es mit der Fehlermeldung:
---------------------
      ..........
      datain2<=dataout1;
    end if;
  end if;
end process;
---------------------

so ist es ohne der Fehlermeldung:
---------------------
      ..........
      datain2<=dataout1;
    end if;
  end if;
end if;
end process;
---------------------

Danke.
Gruss

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Also, nehme ich mal deine originale VHDL Beschreibung und bekomme damit:

WARNING:Xst:819 - "C:/..."  line 51: One or more signals are missing in 
the process sensitivity list. ... The missing signals are:
<sw0>, <sw1>, <dataout1>

ALARM! Das hätte man bei einem getakteten Prozess nicht erwartet! Denn 
da gehört nur der Takt in die Sensitivliste.

Und dann

WARNING:Xst:737 - Found 8-bit latch for signal <address_z2>. Latches 
may be generated from incomplete case or if statements. We do not recommend
the use of latches in FPGA/CPLD designs, as they may lead to timing problems.
WARNING:Xst:737 - Found 8-bit latch for signal <address_z3>. Latches ....
WARNING:Xst:737 - Found 8-bit latch for signal <datain2>. Latches ....
WARNING:Xst:737 - Found 8-bit latch for signal <address1>. Latches ....

ALARM, ALARM, ALARM!!! Warum sollte es bei einem getakteten Prozess 
Latches geben? Da muss irgendwas nicht passen!


Und wenn ich jetzt einfach hinten ein "end if;" anhänge, dann bekomme 
ich wie erwartet einen Fehler, der genau dieses if anmeckert:

ERROR:HDLParsers:164 - "C:/...." Line 87. parse error, unexpected IF, expecting PROCESS

Ergo: du hast das "end if;" VERSCHOBEN. Und zwar so:

process(clock)
variable address_z3 : integer range 0 to 255 := 0; 
variable address_z2 : integer range 0 to 255 := 0; 
variable address_z1 : integer range 0 to 255 := 0; 

begin
  if rising_edge(clock) then
    if (cnt<20000000 and sw2='1') then        
      cnt <= cnt+1;     
    else  
      cnt <= 0;
      we2<='0';
      if address_z1 <= 255 then     
        address_z1 := address_z1 +1;
        address2  <=address_z1;
      end if;  
    end if;  
--   end if;        ---------> hier raus
  
  if sw0='1' then
    address_z1:=0;
    address_z2:=0;
    address_z3:=0;
  end if; 
  
  if sw1='1' then
    we2<='1';
    if address_z2 <= 255 then   
      address_z3 := address_z3 +1;    
      address_z2 := address_z2 +1;
      address1<=address_z2;
      address2<=address_z3;
      
      datain2<=dataout1;
    end if;  
  end if;      
 end if;     --      <----------  hier rein 

end process;

Das ist klar wie Kloßbrühe!

Mit "wait until rising_edge()" wäre das nicht passiert, deshalb verwende 
ich es so gern...

process
variable address_z3 : integer range 0 to 255 := 0; 
variable address_z2 : integer range 0 to 255 := 0; 
variable address_z1 : integer range 0 to 255 := 0; 

begin
  wait until rising_edge(clock);
  if (cnt<20000000 and sw2='1') then        
    cnt <= cnt+1;     
  else  
    cnt <= 0;
    we2<='0';
    if address_z1 <= 255 then     
      address_z1 := address_z1 +1;
      address2  <=address_z1;
    end if;  
  end if;  
 
  if sw0='1' then
    address_z1:=0;
    address_z2:=0;
    address_z3:=0;
  end if; 
  
  if sw1='1' then
    we2<='1';
    if address_z2 <= 255 then   
      address_z3 := address_z3 +1;    
      address_z2 := address_z2 +1;
      address1<=address_z2;
      address2<=address_z3;
      
      datain2<=dataout1;
    end if;  
  end if;      

end process;

Achja, Peter: wenn du das Zeug so leicht wieder vergisst, das ich zum 
Thema Bibliotheken und Variablen schon alles geschrieben habe, dann 
DRUCK ES DIR AUS und häng es an die Wand.

[Schlumpf (Gast)]

Lothar Miller schrieb:
> dann DRUCK ES DIR AUS und häng es an die Wand.

Und was soll das bringen? Er schaut es eh nicht an. Genauso wenig, wie 
seine Fehlermeldungen oder ein VHDL-Buch oder sonstwas.

Und gleich kommt sicher irgendwas in der Art:
"Jup, danke. Mein blöder Editor hat einfach das end if verschoben"

[berndl (Gast)]

Lothar Miller schrieb:
> Achja, Peter: wenn du das Zeug so leicht wieder vergisst, das ich zum
> Thema Bibliotheken und Variablen schon alles geschrieben habe, dann
> DRUCK ES DIR AUS und häng es an die Wand.

Ich bin ja dafuer, dass Peter uns mal den folgenden, unheimlich 
komplizierten Design (pardon, das Programm) erklaert, also was machen 
die LEDs 1..4?:

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
entity variable_top is
port (
   clk : in std_logic;
   led1 : out std_logic := '0';
   led2 : out std_logic := '0';
   led3 : out std_logic := '0';
   led4 : out std_logic := '0'
);
end;
architecture rtl of variable_top is
   constant OUTBIT : natural range 0 to 3 := 3;
   signal cnt : unsigned (3 downto 0) := (others => '0');
begin
   proc_cntvar : process
      variable cnt : unsigned (3 downto 0) := (others => '0');
   begin
      wait until rising_edge (clk);
      led1 <= cnt (OUTBIT);
      cnt := cnt + 1;
      led2 <= cnt (OUTBIT);
   end process;
   proc_cntsig : process
   begin
      wait until rising_edge (clk);
      led3 <= cnt (OUTBIT);
      cnt <= cnt + 1;
      led4 <= cnt (OUTBIT);
   end process;
end rtl;

Da Peter ja aus Prinzip keinen Simulator benutzt, haenge ich die TB auch 
mal an...

[peter (Gast)]

Hmmm.. Led2 und 4 gehen an , wenn das 3.Bit von cnt erreicht ist.

Gruss

[berndl (Gast)]

peter schrieb:
> Hmmm.. Led2 und 4 gehen an , wenn das 3.Bit von cnt erreicht ist.

Das ist prinzipiell richtig, aber halt nur unvollstaendig...

Auch die LEDs 1 und 3 gehen an. Und interessant sind die Phasenlagen der 
4 LEDs... Das kannst du mit einem 4-Kanal Oszilloskop an der echten HW 
nachschauen oder eben halt den Simulator bemuehen...