avr asm: interrupt int0 löst bei fallender flanke nicht aus

[ckrex (Gast)]

Hallo an alle,

seit einigen Stunden versuche ich schon den interrupt für int0 und int1 
am atmega16 zu aktivieren. Im Forum, im wiki und im restlichen Internet 
habe ich bereits gesucht, jedoch brachten mich die Informationen auch 
nicht weiter. Wenn ich mir meinen Code anschaue kann ich auch keinen 
Fehler finden. Ich bin noch Anfänger in Sachen Assembler.

.include "m16def.inc"    ;Definitionen für den ATMega16 einbinden 
.org 0x0000        ;Die Interruptvektortabelle beginnt bei 0x0000 


rjmp RESET        ;1 POWER ON RESET 
rjmp INT0_HANDLER    ;2 Int0-Interrupt 
rjmp INT1_HANDLER    ;3 Int1-Interrupt 
reti          ;4 
reti          ;5 
reti          ;6 
reti          ;7 
reti          ;8 
reti          ;9 
reti          ;10 
reti          ;11 
reti          ;12 
reti          ;13 
reti          ;14 
reti          ;15 
reti          ;16 
reti          ;17 
reti          ;18 
reti          ;19 
reti          ;20
reti          ;21

RESET:            ;RESET Label 
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ldi r16, high(RAMEND)  ;Initialisierung des Stackpointers 
  out SPH, r16      ;erst das High - Byte 
  ldi r16, low(RAMEND) 
  out SPL, r16      ;dann das Low - Byte
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;



  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

  in R16,MCUCSR         ; Read MCUCSR
  ori      R16,1 << JTD        ; Set jtag disable flag
  out      MCUCSR, R16         ; Write MCUCSR
  out      MCUCSR, R16         ; and again as per datasheet 

  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


  ldi r16, 0xFF      ;PORTC als Ausgang konfigurieren 
  out DDRC, r16

  ldi r16, 0x00      ;PORTD als Eingang konfigurieren 
  out DDRD, r16 
  ldi r16, 0xFF      ;Pull-up Widerstände für PORTD 
  out PORTD, r16      ;einschalten 
  ldi r16, 0b00001010    ;INT0 und INT1 einstellen für fallenden flanke
  out MCUCR, r16      ;FALLENDE Flanke löst den Interrupt aus  
  ldi r16, (1<<INT0) | (1<<INT1) ; hier nur int0 und int1 aktivieren
  out GICR, r16      ; hier freigabe für int0 und int1


              ; in der m16def.inc in Zeile 219 -220 findet man folgendes:
              ;.equ  INT0  = 6  ; External Interrupt Request 0 Enable
              ;.equ  INT1  = 7  ; External Interrupt Request 1 Enable
  


  sei            ; globale Interruptfreigabe




  ;;;;;;;;;;;;;;;;;;;;;;;;; test
  ;ldi r19, 0b11111111 
  ;out PORTC, r19 

  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

WDH: 
  rjmp WDH        ;Hauptprogrammschleife macht nichts 

INT0_HANDLER: ;macht die led an
  push r16        ;Inhalt von r16 retten 
  in  r16, SREG      ;Inhalt des Statusregisters retten 
  push r16 
  ldi r16, 0b11111111 
  out PORTC, r16 
  pop r16          ;Statusregister wieder herstellen 
  out SREG, r16 
  pop r16          ;r16 wieder herstellen 
  reti          ;Rückkehr von der ISR 

INT1_HANDLER: ;macht die led aus
  push r16        ;Inhalt von r16 retten 
  in  r16, SREG      ;Inhalt des Statusregisters retten 
  push r16 
  ldi r16, 0b00000000 
  out PORTC, r16 
  pop r16          ;Statusregister wieder herstellen 
  out SREG, r16 
  pop r16          ;r16 wieder herstellen 
  reti          ;Rückkehr von der ISR

Wenn ich nun den pin 16 (int0) am µC auf Masse ziehe, dann sollte nach 
meinem Wissen der INT0-INTERRUPT ausgeführt werden. Die an portC 
angeschlossene LED bleibt jedoch aus. Was mache ich falsch?

Gruß
ckrex

[chris (Gast)]

Hallo

erstmal dein Programm funktioniert nur nicht so wie du gedacht hast

1. du nutzt INT 0/1 diese liegen auf Portd und den hast du komplett als 
Ausgang geschaltet.
2. wenn die Ints auslösen, lösen beide auf fallende Flanke
3. und einer springt den falschen ISR_Handler an der nur ein reti ist

mal nachgeschaut auf welchen adressen die Handler liegen??

[LostInMusic (Gast)]

rjmp RESET           ;1 POWER ON RESET
rjmp INT0_HANDLER    ;2 Int0-Interrupt
rjmp INT1_HANDLER    ;3 Int1-Interrupt

Diese drei "rjmp" durch "jmp" ersetzen.

[chris (Gast)]

ich muss mich korrigieren zu Punkt 1. streiche erstatzlos das PD als 
ausgang geschlatet ist die sind gepullupt sry...

du musst bei der org Anweisung

weitermachen mit

.org 0x0000
rjmp    reset
.org 0x0002
rjmp    Int0_Handler
.org 0x0004
rjmp    Int1_Handler

denn gehts auch schau mal ins Datenblatt

rjmp ist -2kbyte zurück und +2kbyte vorwärts

jmp ist bis 4Mbyte Sprungweite

[chris (Gast)]

falls du wirklich in ASM schreiben willst empfiehl ich dir es ähnlich 
dem Anhang zu machen und zu includieren macht vieles einfacher...

[ckrex (Gast)]

Danke für die schnellen Rückantworten!
Mein Fehler liegt wie chris schon geschrieben habe in der falschen 
addressierung der interruptvektortabelle. Ich hab wohl aus irgendeinem 
Grund geglaubt, dass diese so änlich wie die vom atmega8 adressiert 
wird.
Zitat von chris:

>rjmp ist -2kbyte zurück und +2kbyte vorwärts
>
>jmp ist bis 4Mbyte Sprungweite

Woher weiß man soetwas? Im Datenblatt zum atmega16 unter der Kategorie 
"Instruction Set Summary" kann ich keinen Hinweis dazu finden.

Was bedeutet eigentlich die Syntax: "PC <- PC + k + 1" (rjmp) die man 
ebenfalls im "Instruction Set Summary" unter der Kategorie "Operations" 
finden kann?


>falls du wirklich in ASM schreiben willst empfiehl ich dir es ähnlich
>dem Anhang zu machen und zu includieren macht vieles einfacher...

Danke. Ich muss in ASM schreiben weil das von der Schule so verlangt 
wird.
Außerdem ist es doch ganz cool wenn man es kann ;)

[Matthias S. (Firma: matzetronics) (mschoeldgen)]

ckrex schrieb:
> Woher weiß man soetwas? Im Datenblatt zum atmega16 unter der Kategorie
> "Instruction Set Summary" kann ich keinen Hinweis dazu finden.

Auf Seite 45 im ATMega16 Datenblatt (meines ist 06/08), Kapitel 
Interrupts ist beispielhaft die komplette IRQ Vektortabelle aufgeführt 
und da stehen 'jmp'. rjmps wären auch nur 2 Bytes lang und die 
Vektortabelle des Mega16/32 reserviert 3 Bytes pro Vektor.

[sosole (Gast)]

>Vektortabelle des Mega16/32 reserviert 3 Bytes pro Vektor.

soso

[oldmax (Gast)]

Hi
>Danke. Ich muss in ASM schreiben weil das von der Schule so verlangt
>wird.
>Außerdem ist es doch ganz cool wenn man es kann ;)

Na, dann hilft dir vielleicht ein Beitrag in AVR-Praxis "keine Angst vor 
Assembler" etwas weiter. Findest du in der Rubrik FAQ. Viel Spaß.
gruß oldmax

[Matthias S. (Firma: matzetronics) (mschoeldgen)]

Matthias Sch. schrieb:
> rjmps wären auch nur 2 Bytes lang und die
> Vektortabelle des Mega16/32 reserviert 3 Bytes pro Vektor

Tja, wer zählen kann, ist bei Assembler klar im Vorteil. Sind auch nur 2 
Bytes. Trotzdem ist der Hinweis auf die Vektortabelle im Datenblatt 
deswegen nicht schlecht :-)

[chris (Gast)]

ckrex schrieb:
> Zitat von chris:
>
>>rjmp ist -2kbyte zurück und +2kbyte vorwärts
>>
>>jmp ist bis 4Mbyte Sprungweite
>
> Woher weiß man soetwas? Im Datenblatt zum atmega16 unter der Kategorie
> "Instruction Set Summary" kann ich keinen Hinweis dazu finden.

im AVR4 Studio unter Help -> Assembler Help da kommen gleich die ganzen 
Befehle einfach mal ansehen

> Was bedeutet eigentlich die Syntax: "PC <- PC + k + 1" (rjmp) die man
> ebenfalls im "Instruction Set Summary" unter der Kategorie "Operations"
> finden kann?

PC = ProgrammCounter
k   = Konstante ist dein Label wo du hin willst

heißt es wird quasi in den ProgrammCounter geschrieben
so ähnlich wie
add      r16,r17 ; R16+R17 werden addiert und in R16 steht das Ergebniss

ckrex schrieb:
> Danke. Ich muss in ASM schreiben weil das von der Schule so verlangt
> wird.
> Außerdem ist es doch ganz cool wenn man es kann ;)

Es ist nicht nur cool wenn man es kann es bringt ne Menge 
Sytemverständis wie der µC tickt und persönlich kann ich sagen du hast 
maximale Kontrolle ohne Umwege.
Wenn du zu den Hochsprachen wechseln solltest ist es ein Vorteil wenn 
man sich damit auskennt.

[sosole (Gast)]

>Tja, wer zählen kann, ist bei Assembler klar im Vorteil. Sind auch nur 2 Bytes.

soso

[LostInMusic (Gast)]

> k = Konstante ist dein Label wo du hin willst

Nein, bei rjmp ist k die um 1 verminderte Differenz zwischen der 
Adresse des Sprungziels und der Adresse der rjmp-Instruktion. Das muss 
auch so sein, denn nur dann steht nach Ausführung von "PC <-- PC + k + 
1" durch die ALU im PC (program counter) der gewünschte Wert, nämlich 
die Sprungziel-Adresse. (Wenn Du Zweifel hast, schau es Dir im 
Disassembler an. Dabei beachten: Die Adressen liegen im Flash, der 
wortweise adressiert wird.)

Nur beim absoluten Springen mit jmp gibt k direkt die Zieladresse an.

>soso

Dem kann ich mich nur anschließen... :-/

[ckrex (Gast)]

Hier ist übrigens noch eine Referenz für avr assembler
http://www.atmel.com/webdoc/avrassembler/index.html

[Peter D. (peda)]

Man sollte immer die im betreffenden Include-File definierten 
Vektornamen verwenden.
Besonders einfach geht das mit folgendem Makro:

.include "m48def.inc"                   ;target
;--------------------------------------------------------------------------------
.macro  isr                             ;macro for Interrupt Service Routine
        .set    _curr_addr = pc
        .org    @0
        rjmp    _curr_addr
        .org    _curr_addr
.endmacro
;--------------------------------------------------------------------------------
        .org    0x0000
        rjmp    init
        .org    INT_VECTORS_SIZE
init:
        ; init stuff
main:
        ; main loop
        rjmp    main
;--------------------------------------------------------------------------------
        ISR     OC1Aaddr
        ; interrupt handler
        reti
;--------------------------------------------------------------------------------