LCD an PORTC  ATmega8

[Lukas G. (lukas88)]

Hallo users,

Bastle momentan etwas mit LCD's rum. Klappt soweit gut. Nun habe zurzeit 
das Problem, das mein LCD an PORTD tadellos  funktioniert, sobald ich 
aber auf das PORTC oder auch PORTB wechsle, bleibt die Anzeige auf dem 
Dislay aus. Von den Pinnummern her wurde nichts geändert. Den Quellcode 
ist eine Kopie vom LCD Tutorial (mikrocontroller.net)

Möchte das LCD an PORTC oder B betreiben, da ich PD2 /PD 3 brauche für 
Interrupts.

Zitat:

"Natürlich kann man die LCD-Ansteuerung auch an einen anderen Port des 
Mikrocontrollers "verschieben": Wenn das LCD z. B. an Port B 
angeschlossen ist, dann reicht es, im Programm alle "PORTD" durch 
"PORTB" und "DDRD" durch "DDRB" zu ersetzen."

Genau so gemacht, leider keine Anzeige bei PORTC/B. Und ja kontrastpoti 
wurde auch schon probiert, leider auch nichts.

ADC ist übrigens bei  dieser Anwendung( noch) nicht in gebrauch.

 Woran könnte es (noch) liegen?

Kontroller: Atmega8
LCD: AV1624 
(http://www.produktinfo.conrad.com/datenblaetter/175000-199999/183342-da-01-ml-LCD_Modul_16x2_Zeichen_de_en.pdf)

lukas88

[STK500-Besitzer (Gast)]

Zeig dein Programm! Da es nicht funktioniert. ALles andere ist nur 
Kristallkugelmurmeln.

[Gasst (Gast)]

Lukas G. schrieb:
> Bastle momentan etwas mit LCD's rum.
-------------------------------^------
--> http://www.deppenapostroph.info

[Karl H. (kbuchegg)]

Lukas G. schrieb:

> Zitat:
>
> "Natürlich kann man die LCD-Ansteuerung auch an einen anderen Port des
> Mikrocontrollers "verschieben": Wenn das LCD z. B. an Port B
> angeschlossen ist, dann reicht es, im Programm alle "PORTD" durch
> "PORTB" und "DDRD" durch "DDRB" zu ersetzen."

Was ist denn das für ein Ansteuercode?

Ein ordentlicher Code hat das bereits erledigt und es gibt nur eine 
einzige Stelle, an der man seine Portbezeichnung einträgt. Wenn der 
Ansteuercode es verträgt, dann können es unter Umständen auch mehrere 
sein, weil die Steuerleitungen auf einem anderen Port liegen können.
Aber wie auch immer: die Portumstellung wird nicht im Code selber 
gemacht, indem man im C Code rumfuhrwerkt, sondern an einer einzigen 
Stelle, der normalerweise ein #define ist.

Von einem Code, bei dem das nicht so gemacht ist, sondern ich direkt in 
den C-Anweisungen die Portbezeichnungen ändern muss, würde ich schon mal 
grundsätzlich die Finger lassen.

> Genau so gemacht, leider keine Anzeige bei PORTC/B. Und ja kontrastpoti
> wurde auch schon probiert, leider auch nichts.

Wenn das LCD an einem Port funktioniert, dann stimmt auch der Kontrast. 
Der ändert sich nicht, wenn du an einen anderen Port gehst

>  Woran könnte es (noch) liegen?

Du könntest irgendwo ein PORTB oder ein PINB gegen den entsprechend 
anderen Portnamen auszutauschen vergessen haben.
Du kannst aber auch einen Fehler in der Verkabelung haben. Der Port B 
ist beim Mega8 ja schon ganz schön verstreut, weil da ja auch die 
Anschlüsse für einen Quarz drauf sind. Und am Port C gibt es noch die 
Möglichkeit, dass du AVcc nicht angeschlossen hast.

[Dieter F. (Gast)]

Schon mal aufs Pinout geschaut? Welche Pins verwendest Du denn? Sind die 
auf C und D auch nutzbar - bzw. überhaupt da? ATMega8 hat nur eine 
begrenzte Anzahl von Pins ... oder?

[Lukas G. (lukas88)]

.nolist
.include "/home/lukas/Dokumente/AVR/includes/m8def.inc"
.list

; .def definiert ein Synonym (Namen) für ein µC Register
.def   z  = r20
.def   up = r21
.def temp1 = r16
.def temp2 = r17
.def temp3 = r18
.def temp4 = r19


.org 0x0000
  rjmp  conf

.org 0x0009
    rjmp  timer0_overflow



timer0_overflow:

  inc      z
  reti

z_zero:

  clr      z
  ret


lcd_number:
    mov    temp1,up
        push    temp2               ; register sichern,
                                    ; wird für Zwsichenergebnisse gebraucht     
        ldi     temp2, '0'         
lcd_number_10:                
        subi    temp1, 10           ; abzählen wieviele Zehner in
        brcs    lcd_number_1        ; der Zahl enthalten sind
        inc     temp2
        rjmp    lcd_number_10
lcd_number_1:
        push    temp1               ; den Rest sichern (http://www.mikrocontroller.net/topic/172026)
        mov     temp1,temp2         ; 
        rcall   lcd_data            ; die Zehnerstelle ausgeben
        pop     temp1               ; den Rest wiederherstellen
        subi    temp1, -10          ; 10 wieder dazuzählen, da die
                                    ; vorhergehende Schleife 10 zuviel
                                    ; abgezogen hat
                                    ; das Subtrahieren von -10
                                    ; = Addition von +10 ist ein Trick
                                    ; da kein addi Befehl existiert
        ldi     temp2, '0'          ; die übrig gebliebenen Einer
        add     temp1, temp2        ; noch ausgeben
        rcall   lcd_data
 
        pop     temp2               ; Register wieder herstellen
        ret
  

conf:
 
           ldi temp1, LOW(RAMEND)      ; LOW-Byte der obersten RAM-Adresse
           out SPL, temp1
           ldi temp1, HIGH(RAMEND)     ; HIGH-Byte der obersten RAM-Adresse
           out SPH, temp1


          
 
      ldi      temp1,0xFF
    out      DDRC,temp1

           

           ldi       temp1,0b00000101     ; CS00 setzen: Teiler 1
           out       TCCR0, temp1
 
           ldi       temp1, (1<<TOIE0)      ; TOIE0: Interrupt bei Timer Overflow
           out       TIMSK, temp1
              
           rcall lcd_init     ; Display initialisieren
           rcall lcd_clear    ; Display löschen
    sei

main:

  clr      up
  rcall    z_zero

zahlen:

  cpi      z,15
  breq    up_one
  rjmp    zahlen

up_one:

  cpi      up,50
  breq    main
  inc      up
  rcall    lcd_clear
  ldi      temp1,'S'
  rcall    lcd_data
  ldi      temp1,':'
  rcall    lcd_data
  rcall    lcd_number
  rcall    z_zero
  rjmp    zahlen

  


  
  
  
  
  
  

.include "funk_lcd.asm"

[Lukas G. (lukas88)]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                 LCD-Routinen                ;;
;;                 ============                ;;
;;              (c)[e-mail]            ;;
;;                                             ;;
;; 4bit-Interface                              ;;
;; DB4-DB7:       PD0-PD3                      ;;
;; RS:            PD4                          ;;
;; E:             PD5                          ;;
;;                                             ;;
;; Takt:          4 MHz                        ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
 
 
 ;sendet ein Datenbyte an das LCD
lcd_data:

       
       push  temp2
           mov temp2, temp1             ; "Sicherungskopie" für
                                        ; die Übertragung des 2.Nibbles
           swap temp1                   ; Vertauschen
           andi temp1, 0b00001111       ; oberes Nibble auf Null setzen
           sbr temp1, 1<<4              ; entspricht 0b00010000 (Anm.1)
           out PORTC, temp1             ; ausgeben
           rcall lcd_enable             ; Enable-Routine aufrufen
                                        ; 2. Nibble, kein swap da es schon
                                        ; an der richtigen stelle ist
           andi temp2, 0b00001111       ; obere Hälfte auf Null setzen 
           sbr temp2, 1<<4              ; entspricht 0b00010000
           out PORTC, temp2             ; ausgeben
           rcall lcd_enable             ; Enable-Routine aufrufen
           rcall delay50us
           pop  temp2             ; Delay-Routine aufrufen
           ret                          ; zurück zum Hauptprogramm
 
 ; sendet einen Befehl an das LCD
lcd_command:
       push temp2; wie lcd_data, nur RS=0
           mov temp2, temp1
           swap temp1
           andi temp1, 0b00001111
           out PORTC, temp1
           rcall lcd_enable
           andi temp2, 0b00001111
           out PORTC, temp2
           rcall lcd_enable
           rcall delay50us
           pop  temp2
           ret
 
 ; erzeugt den Enable-Puls
 ;
 ; Bei höherem Takt (>= 8 MHz) kann es notwendig sein, 
 ; vor dem Enable High 1-2 Wartetakte (nop) einzufügen. 
 ; Siehe dazu http://www.mikrocontroller.net/topic/81974#685882
lcd_enable:
           sbi PORTC, 5                 ; Enable high
           nop                          ; mindestens 3 Taktzyklen warten
           nop
           nop
           cbi PORTC, 5                 ; Enable wieder low
           ret                          ; Und wieder zurück                     
 
 ; Pause nach jeder Übertragung
delay50us:                              ; 50µs Pause (bei 4 MHz)
           ldi  temp1, $42
delay50us_:dec  temp1
           brne delay50us_
           ret                          ; wieder zurück
 
 ; Längere Pause für manche Befehle
delay5ms:                               ; 5ms Pause (bei 4 MHz)
           ldi  temp1, $21
WGLOOP0:   ldi  temp2, $C9
WGLOOP1:   dec  temp2
           brne WGLOOP1
           dec  temp1
           brne WGLOOP0
           ret                          ; wieder zurück
 
 ; Initialisierung: muss ganz am Anfang des Programms aufgerufen werden
lcd_init:
           ldi  temp3,6
powerupwait:
           rcall  delay5ms
           dec  temp3
           brne powerupwait
           ldi temp1, 0b00000011        ; muss 3mal hintereinander gesendet
           out PORTC, temp1             ; werden zur Initialisierung
           rcall lcd_enable             ; 1
           rcall delay5ms
           rcall lcd_enable             ; 2
           rcall delay5ms
           rcall lcd_enable             ; und 3!
           rcall delay5ms
           ldi temp1, 0b00000010        ; 4bit-Modus einstellen
           out PORTC, temp1
           out PORTC, temp1
           rcall lcd_enable
           rcall delay5ms
           ldi temp1, 0b00101000        ; 4Bit / 2 Zeilen / 5x8
           rcall lcd_command
           ldi temp1, 0b00001100        ; Display ein / Cursor aus / kein Blinken
           rcall lcd_command
           ldi temp1, 0b00000100        ; inkrement / kein Scrollen
           rcall lcd_command
           ret
 
 ; Sendet den Befehl zur Löschung des Displays
lcd_clear:
       push  temp1
           ldi temp1, 0b00000001   ; Display löschen
           rcall lcd_command
           rcall delay5ms
           pop   temp1
           ret
 
 ; Sendet den Befehl: Cursor Home
lcd_home:
           ldi temp1, 0b00000010   ; Cursor Home
           rcall lcd_command
           rcall delay5ms
           ret

[Lukas G. (lukas88)]

Ja ok LCDs

[Karl H. (kbuchegg)]

Die Portbezeichnungen scheinen alle angepasst worden zu sein.

Kommen wir zur Hardware:
Verkabelung stimmt? (Ist mir auch schon passiert, dass ich mich in den 
Pinbezeichnungen geirrt habe)
AVcc ist angeschlossen?

[Lukas G. (lukas88)]

Hallo kbuchegg,

Verkabelung sollte stimmen, soweit.

Mit AVcc hab schon probiert, sowie ich mich informiert habe sollte 
dieser Auf GND gezogen werden!? Hat aber nicht wirklich funktioniert. 
Kann morgen noch ein Bild zur Verkabelung reinstellen. Für heute ist 
schluss, sollte morgen noch Arbeiten...

mfg

[Karl H. (kbuchegg)]

Lukas G. schrieb:
> Hallo kbuchegg,
>
> Verkabelung sollte stimmen, soweit.
>
> Mit AVcc hab schon probiert, sowie ich mich informiert habe sollte
> dieser Auf GND gezogen werden!?

Äh nein,
AVcc ist die Versorgungsspannung dieses Ports. Der hat seine eigene, 
weil dort der ADC beheimatet ist.

d.h. der wird mit 5V verbunden.
Und noch ein 100nF Kondensator nach GND

[Forist (Gast)]

Lukas G. schrieb:
> Mit AVcc hab schon probiert, sowie ich mich informiert habe sollte
> dieser Auf GND gezogen werden!?

Wer hat dir denn diesen Bären aufgebunden?

Was meinst du, was im Datenblatt auf S. 6 der Satz

It [AVCC] should be externally connected to VCC, even if the ADC is not used.

und auf S. 248 die Zeile

Symbol Parameter Condition    Min(1)       Typ(1) Max(1)       Units
AVCC   Analog Supply Voltage  VCC - 0.3(2)        VCC + 0.3(3) V

und die Fußnoten 2 und 3

Notes: ...
2. Minimum for AVCC is 2.7V.
3. Maximum for AVCC is 5.5V.

bedeuten?

[Michael (Gast)]

An PortD läufts problemlos aber an Port B und Port C nicht? Sind auch 
wirklich alles Pins richtig eingestellt? Port D unterscheidet sich von 
Port B und Port C in der weise, dass hier kein Sonderpin im Spiel ist. 
Bei Port C hat man z.B. PC6 der der Resetpin ist. Da muss man etwas mehr 
einstellen als bei anderen, "einfachen", Pins um den als IO nutzen zu 
können. Bei Port B fällt mir da spontan PB6 und PB7 ein, die 
Oszilatorpins. Auch hier ist etwas mehr Justage nötig um die als 
gewöhnliche IOs nutzen zu können. (nutzt du einen Quartz-Oszilator?)
Mit Assembler kenne ich mich leider nicht so dolle aus aber schau 
einfach mal ob du diese Pins auch wirklich richtig initialisiert hast. 
Bei deinem Beispielcode mit Port C wäre hier die Frage ob du das 
FUSE-BIT entsprechend gesetzt hast damit PC6 auch als IO-Pin nutzbar 
ist.
Und wie ist deine Clocksource für den Atmega eingestellt? Das hat 
Einfluss auf die Funktion von PB6 und PB7.
Und natürlich prüfen ob man auch wirklich alle Verbinungen richtig 
verdrahtet hat, also das Pin-out auch wirklich stimmt und man keinen 
Kabelbruch hat. Insbesondere bei letzterem hab ich mir bei einem LCD 
auch schon mal nen Wolf gesucht weil es nicht funktionierte (kalte 
Lötstelle wars bei mir an DB1, hat mich fast nen ganze Tag gekostet 
diesen Fehler zu finden)

[Karl H. (kbuchegg)]

Michael schrieb:

> Bei deinem Beispielcode mit Port C wäre hier die Frage ob du das
> FUSE-BIT entsprechend gesetzt hast damit PC6 auch als IO-Pin nutzbar
> ist.


NEIN! Nicht!

Einem Anfänger zu empfehlen, sich den Reset Pin wegzufusen ist grob 
fahrlässig! Ohne High-Volt Programmer kann er den Mega danach wegwerfen.


Er braucht 6 Pins zur Ansteuerung. PC0 bis PC3 für die Daten. PC4 und 
PC5 für die Steuerleitungen. PC6 braucht er nicht.

[Michael (Gast)]

Karl H. schrieb:
> Einem Anfänger zu empfehlen, sich den Reset Pin wegzufusen ist grob
> fahrlässig! Ohne High-Volt Programmer kann er den Mega danach wegwerfen.

Oh, nicht falsch verstehen. Ich empfehle ihm das nicht, ich weise nur 
darauf hin. Er könnte auch weiterhin Port D für das LCD benutzen, 
immerhin kann jeder Pin als externer Interrupt benutzt werden, nicht nur 
PD2 und PD3. Aber weil du es grade sagst (das fiel mir gar nicht auf, 
dass er nur 6 Leitungen fürs LCD benutzt): Was ist denn mit dem RW-Pin 
des LCDs? Auch sicher auf Low gezogen?

[Lukas G. (lukas88)]

Werd heute abend mal versuchen, das ganze mit dem stk500 aufzubauen. 
Falls es funktioniert, hab ich was falsches verdratet oder vergessen. Da 
ich bis jetzt immer mit dem stk500 garbeitet habe , könnte es gut sein 
dass ich was hardwaremässig nicht ganz richtig konfiguriert habe!

[oldmax (Gast)]

Hi
Hab nur mal kurz reingeschaut. Dabei ist mir aufgefallen, das du das 
Register r20 als Z deklarierst. Klar, kann man machen, aber Z ist in der 
m8def.inc ein Doppelregister aus r30 und r31, soweit ich es in 
Erinnerung habe. Mit deiner Deklaration machst du diese zunichte und 
wenn du später mal die Doppelregister X, Y und Z einsetzen willst, 
kommen neue interessante Fehler auf dich zu.
So, jetzt sehe ich mir den Rest an.
Gruß oldmax

[oldmax (Gast)]

Hi
Ok, soweit für einen Anfänger erst mal ok, dennoch erlaube mir ein paar 
Hinweise:
Einrücken ist ok, aber setz den Rücksprungbefehl ruhig wieder an den 
Anfang einer Zeile. So finsest du leichter das Ende einer Sub.
Du hast den Timer aktiviert. Gut, aber warum nicht gleich in den 
Compare-Mode. So kannst du dir eine Zeitbasis schaffen und auf die 
üblichen Programmbremsen (delays) verzichten.
Statt Push und POP sind u.U. Variablen sinnvoll. In einfachen 
Subroutinen muss man nicht unbedingt die Register retten. Nur wenn du 
diese in Interruptrotinen aufrufst ist es zwingend notwendig. Der SRAM 
ist groß genug, um Variablen darin abzulegen. Nebenbei, wenn du dir dann 
ein kleines Programm schaffst welches dir den Variablenbereich im Block 
an den PC sendet, kannst du die Inhalte leicht überprüfen. Irgendwann 
hab ich mal "OpenEye" für diesen Zweck geschrieben und hier 
veröffentlicht. Ist aber schon ein paar Jahre her.
Gruß oldmax

[Lukas G. (lukas88)]

Hab jetzt mal ein paar Bilder gemacht, vielleicht könnt ihr ein Problem 
erkennen! STK500 hat es übrigens auch nicht funktioniert, scheint also 
eventuell ein Konfigurations Problem zu sein.

[Strabe (Gast)]

sieht aus wie das Standard 2x16 LCD (Pollin?). müssen da auf der Platine 
rechts nicht noch A und K angeschlossen werden ?

[Lukas G. (lukas88)]

Ja theoretisch schon, für die Hintergrundbeleuchtung. Benötige ich aber 
nicht, darum hab ichs ausgelassen!

[Karl H. (kbuchegg)]

Jetzt mal abgesehen von den fehlenden Blockkondensatoren kann ich auf 
den Bildern nichts erkennen, was falsch verdrahtet wäre.

Hast du schon mal durchgeklingelt, ob irgendein Kabel zum LCD einen 
schlechten Kontakt hat?

Ich würde jetzt erst mal zum Plan B greifen und mir ein Programm 
schreiben, welche am PortC 1 Pin auf High setzt und dann nachmessen, ob 
am LCD auch wirklich an der richtigen Stelle ein High auftaucht.
Dann den nächsten Pin.

Denn: Da das Programm mit einer Belegung am Port D funktioniert und du 
soweit ich sehen kann tatsächlich alle Erwähnungen von Port D gegen Port 
C ausgetauscht hast (DDR natürlich auch), müsste das eigentlich 
funktionieren. Selbst wenn du mit dem fehlerhaften Anlegen von GND an 
AVcc den Port C komplett geschossen hast, sollte eigentlich der Port B 
immer noch funktionieren.

Aber sollte ist Konjunktiv. Nachmessen ist immer besser.

[Karl H. (kbuchegg)]

Und steck noch 2 100nF Kondensatoren an die Versorgungspins des Mega8. 
Jeweils einer der Vcc bzw. AVcc mit dem GND Pin auf der jeweiligen Seite 
verbindet. Kondensatoren dicht an den µC ran.

Es wurde schon von den tollsten Effekten berichtet, die dann mit dem 
Einfügen dieser Blockkondensatoren plötzlich verschwunden sind.

[Dieter F. (Gast)]

Steck das Ganze doch mal so 10 Reihen weiter ... ich habe mittlerweile 3 
Breadboards entsorgt, da die schlicht nicht zuverlässig waren. Ich traue 
den Dingern nicht mehr - wenn ich Probleme habe stecke ich erstmal um 
und dann auf ein anderes Breadboard, um Breadboard-Fehler 
auszuschliessen. Habe mir schon einen Wolf gesucht und dann war es am 
Ende ein Kontaktproblem im Breadboard.

[Lukas G. (lukas88)]

Schon versucht, leider auch nichts! Paradoxerweise funktioniert das 
LCD ausschließlich auf Port D.


Und durchprobiert/gemessen, ob die Pins strom ein/aus schalten hab ich 
auch schon. Hab sogar den Atmega ausgewechselt gegen einen neuen!


Muss mich wohl langsam damit abfinden, da mir langsam die Ideen 
ausgehen.... Obwohl es mich natürlich schon wunder nehmen würde wieso..

[Heinz V. (heinz_v)]

Lukas G. schrieb:
>

> .......
>  ;sendet ein Datenbyte an das LCD
> lcd_data:
> 
> 
>        push  temp2
>            mov temp2, temp1             ; "Sicherungskopie" für
> .......
>

Ähm, wo wird denn das DDRC auf Output geschaltet?

[Kast (Gast)]

Könnte das helfen?

Beitrag "ATMega16 und PORTC / JTAG Fuse"

[Karl H. (kbuchegg)]

Heinz V. schrieb:
> Lukas G. schrieb:
>>

>> .......
>>  ;sendet ein Datenbyte an das LCD
>> lcd_data:
>>
>>
>>        push  temp2
>>            mov temp2, temp1             ; "Sicherungskopie" für
>> .......
>>

>
> Ähm, wo wird denn das DDRC auf Output geschaltet?

Im Hauptprogramm.
Beitrag "Re: LCD an PORTC  ATmega8"

conf:
 
           ldi temp1, LOW(RAMEND)      ; LOW-Byte der obersten RAM-Adresse
           out SPL, temp1
           ldi temp1, HIGH(RAMEND)     ; HIGH-Byte der obersten RAM-Adresse
           out SPH, temp1


          
 
      ldi      temp1,0xFF
    out      DDRC,temp1

Ja ich weiss. Ist scheisse gemacht und sollte eigentlich mit in die Init 
Funktion. Aber: das ist nicht das Problem. Leider.

[Karl H. (kbuchegg)]

Kast schrieb:
> Könnte das helfen?
>
> Beitrag "ATMega16 und PORTC / JTAG Fuse"

Der Mega8 hat kein JTAG

[Lukas G. (lukas88)]

Hier: 

conf:

           ldi temp1, LOW(RAMEND)      ; LOW-Byte der obersten 
RAM-Adresse
           out SPL, temp1
           ldi temp1, HIGH(RAMEND)     ; HIGH-Byte der obersten 
RAM-Adresse
           out SPH, temp1




      ldi      temp1,0xFF   <=======
    out      DDRC,temp1     <=======



           ldi       temp1,0b00000101     ; CS00 setzen: Teiler 1
           out       TCCR0, temp1

           ldi       temp1, (1<<TOIE0)      ; TOIE0: Interrupt bei Timer 
Overflow
           out       TIMSK, temp1

           rcall lcd_init     ; Display initialisieren
           rcall lcd_clear    ; Display löschen
    sei

main:

[Lukas G. (lukas88)]

Kurze Frage: 


Von euch hat nicht zufälligerweise jemand ein kleines Projekt zur 
Verfügung, das man 1:1 nachbauen könnte die andere PORTS als D benutzen.

Suche morgen selber  noch im netz, aber vielleicht hat jemand grad eins 
zur hand. Ne einfache Uhr oder so... Inklusive schaltplan und Quellcode.

Damit ich Etwas testen kann, wo ich weiß ,dass Hard/Software 
konfiguration schon irgendwo funktioniert haben! 

mfg

[Peter D. (peda)]

Lukas G. schrieb:
> Von euch hat nicht zufälligerweise jemand ein kleines Projekt zur
> Verfügung, das man 1:1 nachbauen könnte die andere PORTS als D benutzen.

http://www.avrfreaks.net/forum/tutc-lcd-tutorial-1001

In Assembler hat man einfach zuviele Fehlermöglichkeiten.

[chris (Gast)]

mmmhh wenn du wirklich auf Portc das so machst

Lukas G. schrieb:
> ldi      temp1,0xFF   <=======
>     out      DDRC,temp1     <=======

schiest du den Controller ausm Leben und sperrst dich aus denn damit 
wird PC6 als Ausgang konfiguriert wo bekanntlich ja der Rest zu hause 
ist...
besser wär

ldi     temp1,$3f


In meiner Anfangszeit hatte ich ähnliche Probleme da 1 Port 
funktionierte und die anderen beiden beim M8 nicht wollten lag an der 
Verkabelung und der SW.

Kann dir empfehlen das du in der LCD Routine alle PortC/B/D durch ein 
Pseudonym ersetzt wie LCD_Portx/LCD_ddrx und am Anfang der Hauptdatei

.equ LCD_portx = PortC
.equ LCD_ddrx  = DDRC
.equ LCD_RS    = 4
.equ LCD_E     = 5

ersetz. Dadurch hast du nur eine Quelle wo man was ändern müsste und es 
kann dir nicht passieren das du evtl was in der LCDRoutine ein 
Portumbenennung vergisst was dir gerade diesen Ärger einhandelt. ;-)

[Karl H. (kbuchegg)]

chris schrieb:
> mmmhh wenn du wirklich auf Portc das so machst
>
> Lukas G. schrieb:
>> ldi      temp1,0xFF   <=======
>>     out      DDRC,temp1     <=======
>
> schiest du den Controller ausm Leben und sperrst dich aus denn damit
> wird PC6 als Ausgang konfiguriert wo bekanntlich ja der Rest zu hause
> ist...
> besser wär
>
> ldi     temp1,$3f

besser wäre es zweifellos.
Allerdings wär mir das neu, dass man den Reset so ansprechen kann. Wenn 
der Pin auf seiner Standardeinstellung eingestellt ist und als Reset 
konfiguriert ist, dann ist er vom Port Register getrennt. Was immer dort 
auch passiert, es löst keinen Reset aus.

[chris (Gast)]

Karl H. schrieb:
> Allerdings wär mir das neu, dass man den Reset so ansprechen kann. Wenn
> der Pin auf seiner Standardeinstellung eingestellt ist und als Reset
> konfiguriert ist, dann ist er vom Port Register getrennt.

Das war wie gesagt zu meiner Anfangszeit mit dem M8 und auch noch 
Ponyprog. Auf jeden Fall hatte ich mich bei 2-3 Testobjekten ausgesperrt 
gehabt und nur mit nen STK500 über HighvoltageProgrammierung 
zurückgesetzt bekommen. Seit dem lasse ich das mit einem doppel belegten 
Pin IO/Reset und lasse ihn als Reset beschaltet ohne Probleme.

Wo ist eigentlich der TO hin???

[Ralf G. (ralg)]

Lukas G. schrieb:
> Von euch hat nicht zufälligerweise jemand ein kleines Projekt zur
> Verfügung

Ich schlage vor, du kümmerst dich um die Grundlagen. Die Ansteuerung 
eines Pins mit LED dran zum Testen dürfte ein guter Einstieg sein.

[Lukas G. (lukas88)]

Hab mein Problem endlich lösen können, naja fast zumindest.

Scheinbar lag es daran, dass ich Funktionen/labels in eine externe Datei 
verlagert habe und per .include einbunden habe.

Hab die Labels in die Haupdatei kopiert, und lief danach ohne Probleme, 
auch über verschieden Ports hinweg.

Offenbar geht irgendwo ein Registerwert verloren, oder wird verfälscht. 
Ev. Stackpointer?? Wieso genau müsste ich noch einmal den Code intensiv 
Studieren... Aber nach 1 Woche rumprobieren lass ich das momentan sein. 
Jetzt kann ich endlich weiter mit meinem Projekt.

Danke für eure Zahlreichen Ratschläge und inputs.

lukas88

[Peter D. (peda)]

Include bedeutet eine direkte Texteinfügung. Daher ist oft auch die 
Stelle entscheidend, wo die Inlcude-Anweisung steht. In der Regel ist zu 
Anfang der Programmdatei die optimale Stelle.
Enthält das Include Code, dann darf es aber erst nach der Vektortabelle 
includiert werden.

[Bernd (Gast)]

> Scheinbar lag es daran, ...

Und woran hat es tatsächlich gelegen?

[Dieter F. (Gast)]

Bernd schrieb:
> Und woran hat es tatsächlich gelegen

Am breadboard :-) ? Der Include war doch sicher schon auch bei der 
PortD-Variante im Spiel ...