Schieberegister am ATMega8

[Luigi A. (spok)]

Hallo zusammen, ich habe ein Schieberegister an meinem ATMega8 
angeschlossen.(wie im Anhang dargestellt)
Steuerung via SPI funktioniert enínwandfrei.

Wenn ich jedoch einen Schiebevorgang stand alone losjage verändert sich 
das LED Muster nicht :-(

Codeauschnitt:

bis hier hin steht der Code via SPI Modul und das Muster 0b00000011 wird 
an die LED´s ausgegeben.

....
       cbi schiebe_port, SIN
       sbi schiebe_port, SCK
       cbi schiebe_port, SCK
       sbi schiebe_port, RCK
       cbi schiebe_port, RCK
....

der Code sollte doch ein Schiebevorgang verursachen und das Muster 
0b00000110

erzeugen oder?

Danke für eure Unterstüzung.

[Karl H. (kbuchegg)]

Luigi A. schrieb:

> Codeauschnitt:
>
> bis hier hin steht der Code via SPI Modul und das Muster 0b00000011 wird
> an die LED´s ausgegeben.
>
> ....
>        cbi schiebe_port, SIN
>        sbi schiebe_port, SCK
>        cbi schiebe_port, SCK
>        sbi schiebe_port, RCK
>        cbi schiebe_port, RCK
> ....
>
> der Code sollte doch ein Schiebevorgang verursachen


ja sollte er.

Bist du zb sicher, dass du nicht anderwärtig gleich danach wieder das 
urspüngliche Muster drüber jagst?
/Genau deswegen haben wir hier keine Freude mit Code-Schnipseln. Man 
sieht einfach nicht, was sonst noch so alles passiert und welche 
Nebenbedingungen existieren.

[Luigi A. (spok)]

Hi kbuchegg,

hier der gesamte code:
den Passus findest du kurz unter main:

.include "m8def.inc"
.def temp1 = r16
.def temp2 = r17
.def temp3 = r18

; Die Definitionen müssen an den jeweiligen AVR angepasst werden
 
.equ SCHIEBE_DDR  = DDRB
.equ SCHIEBE_PORT = PORTB
.equ RCK          = PB2     ; SS
.equ SCK          = PB5     ; SCK
.equ SIN          = PB3     ; MOSI
 
    ldi   temp1, LOW(RAMEND)     ; Stackpointer initialisieren
    out   SPL, temp1
    ldi   temp1, HIGH(RAMEND)
    out   SPH, temp1  
;
; SCK, MOSI, SS als Ausgänge schalten
;
    in    temp1, SCHIEBE_DDR
    ori   temp1, (1<<SIN) | (1<<SCK) | (1<<RCK) 
    out   SCHIEBE_DDR,temp1     
;
; SPI Modul konfigurieren
;
    ldi   temp1, (1<<SPE) | (1<<MSTR)
    out   SPCR, temp1           ; keine Interrupts, MSB first, Master
                                ; CPOL = 0, CPHA =0
                                ; SCK Takt = 1/2 XTAL
    ldi   temp1, (1<<SPI2X)
    out   SPSR, temp1           ; double speed aktivieren
    out   SPDR, temp1           ; Dummy Daten, um SPIF zu setzen

    
; LED alle aus
  rcall led_all_off

main:

  ldi   temp1, 0b00000011
  rcall Schiebe               ; Daten schieben
  rcall SchiebeOut            ; Daten in Ausgangsregister übernehmen
   
  

  rcall wait1s        ;1 Sekunde waten

  sbi schiebe_port, SCK
  cbi schiebe_port, SCK
  sbi   SCHIEBE_PORT, RCK
    cbi   SCHIEBE_PORT, RCK
  
loop:
    rjmp  loop
 
;-----------------------------------------------------------------------------
;
; Die Daten im Schieberegister in das Ausgaberegister übernehmen
;
; Dazu am RCK Eingang am Schieberegister einen 0-1-0 Puls erzeugen
;
SchiebeOut:
    sbis  SPSR, SPIF            ; prüfe ob eine alte Übertragung beendet ist
    rjmp  SchiebeOut
    sbi   SCHIEBE_PORT, RCK
    cbi   SCHIEBE_PORT, RCK
    ret
 
;-----------------------------------------------------------------------------
;
; 8 Bits aus temp1 an das Schieberegister ausgeben
;
Schiebe:
    sbis    SPSR, SPIF      ; prüfe ob eine alte Übertragung beendet ist
    rjmp    Schiebe
    out     SPDR, temp1     ; Daten ins SPI Modul schreiben, Übertragung beginnt automatisch
    ret





;-----------------------------------------------------------------------------
;
;Warteschleife 1s über 16 Bit Zähler
;Bei 4Mhz Prozessortakt ca 1sec Dauer
;Formel Zeit=[(5+(3*(mk-1)+1+2))*(dl1-1)+2] * (1/OSCfreq)
;mit dl1(Anfangsstand 16 Bit Zähler) und mk(Verlängerung der Takte) kann die Zeit verändert werden

.equ dl1 = 0xffff
.equ mk = 19

wait1s:
  push temp1
  
  
  ldi r25, high(dl1)  ;1 Takt
  ldi r24, low(dl1)  ;1 Takt
  

loop1:
  ldi temp1, mk  ;1 Takt
  sbiw r24, 1    ;2 Takte
  brne loop2    ;2 Takte, wenn Z=0 dann 1 Takt
  rjmp end1    ;2 Takte


loop2:
  dec temp1    ;1 Takt
  brne loop2    ;2 Takte, wenn Z=0 dann 1 Takt
  rjmp loop1    ;2 Takte


end1:
  pop temp1
  ret


;-----------------------------------------------------------------------------
;
;LED alle aus

LED_all_off:
  push temp1

  ldi   temp1, 0b0000000
    rcall Schiebe               ; Daten schieben
  ldi   temp1, 0b0000000
    rcall Schiebe               ; Daten schieben
  ldi   temp1, 0b0000000
    rcall Schiebe               ; Daten schieben
  ldi   temp1, 0b0000000
    rcall Schiebe               ; Daten schieben
    rcall SchiebeOut            ; Daten in Ausgangsregister übernehmen  
  
  pop temp1
  ret

[Felix A. (madifaxle)]

So beim Überfliegen würde ich sagen, dass es deshalb nicht geht, weil du 
nach Init des SPI keinen Zugriff mehr auf die IO-Pins SCK und MOSI hast.

Wenn du nach derinem Wait1s den SPI deaktivierst, sollte sich was 
ändern.

[Luigi A. (spok)]

Felix A. schrieb:

> Wenn du nach derinem Wait1s den SPI deaktivierst, sollte sich was
> ändern.

Hallo Felix,

danke genau das war es gewesen.
:-)

Gruß