.dseg am Ende oder auch Anfang?

[Lukas G. (lukas88)]

Hallo zusammen,

Blieb bei meinem Projekt  grad bei SRAM hängen.

Zunächst mal möchte ich sagen, das ich das SRAM zum ersten mal nutze. 
Hab bis jetzt alles mit Registern gemacht. Aber da meine Projekte immer 
umfangreicher werden, muss ich nun das SRAM benützen, um etwas Übersicht 
zu gewinnnen.

Zur Frage:

Spielt generell es ein Rolle WO ich die Assemblerdirektive;

.dseg
count:  .BYTE 1

im Code selbst hinschreibe?

Also ich meine nicht direkt im Code, sondern dort wo ich die Register 
deklariere also Am Ganz am Anfang, oder erst am Schluss?

Ich hab bei den ersten Versionen, das Codesegment ganz am Anfang 
deklariert, dann hat aber das Programm nicht mehr Funktioniert.

Hab ich es entfernt ging wieder alles wunderbar.

Schreibe ich es am Schluss funktioniert alles wie gewünscht, waber warum 
ist das SO? Oder mache ich sonst was verkehrt.


Mein Code (der Funktionsfähige =)

.nolist
.include "/home/lukas/Dokumente/AVR/includes/m8def.inc"
.list

;Register

.def  t1    = r16 ; temp Register
.def   z1    = r17 ; Zähler 1 für die Zeitmessung 
.def  stat  = r18 ; Status
.def  z2    = r19 ; Timer für Warteschleifen
.def    z3    = r20 ; Impulszähler

;Konstanten
.equ  PD       = PORTD
.equ  DD       = DDRD

.equ  PB      = PORTB
.equ  DB      = DDRB

.equ   F_CPU     = 4000000 ; Systemtakt in Hz
.equ  BAUD     = 9600    ; Baudrate


; Berechnungen 
.equ UBRR_VAL   = ((F_CPU+BAUD*8)/(BAUD*16)-1)  ; clever runden
.equ BAUD_REAL  = (F_CPU/(16*(UBRR_VAL+1)))     ; Reale Baudrate
.equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)  ; Fehler in Promille
 
.if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))       ; max. +/-10 Promille Fehler
  .error "Systematischer Fehler der Baudrate grösser 1 Prozent und damit zu hoch!"
.endif

;Vektoren
.org 0x0000
  rjmp   configurations
.org 0x0001
  rjmp  int_1
.org 0x0009
  rjmp  timer0_overflow
  
;Interrupts
int_1:

  ldi    stat,1 ; Wenn Interrupt ausgelöst stat auf 1
reti

timer0_overflow:

  inc    z2
  inc    z1
  
reti

;Sprungprgramme:




configurations:

  ldi      t1,LOW(RAMEND)  ;Stackpointer LOW
  out      SPL,t1

  ldi      t1,HIGH(RAMEND) ;Stackpointer HIGH
  out      SPH,t1

  ldi      t1,0x00  ;PortD als Eingang
  out      DD,t1

  ldi      t1,0xFF  ;Pullups PortD aktivieren 
  out      PD,t1  

  ldi      t1,0xFF  ;PortB als Ausgang
  out      DB,t1

  ldi      t1,0xFF  ;PortB Pullups deaktiviert
  out      PB,t1

  ldi      t1,(1<<ISC01)|(1<<ISC00) ; Interrupt auf steigende flanke
  out      MCUCR,t1

  ldi      t1,(1<<INT0) ; Interrupt auf INT0 aka PortD 2
  out      GICR,t1

  ldi      t1,(1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0) ;Senden aktivieren UART
  out      UCSRC,t1
  
  sbi      UCSRB,TXEN
  
  ldi      t1,(0<<CS02)|(1<<CS01)|(1<<CS00) ; Timer teiler  64
  out      TCCR0,t1
  
  ldi      t1,(1<<TOIE0) ; Interrupt bei Timer Interrupt
  out      TIMSK,t1
  
  clr      stat  ; Alles auf null sezen 
  clr      z2
  clr      z1
  clr      z3
  
  sei  ; Aktiviere Interrupts
  
main:

  cpi      stat,1   ;Wenn interrupt hat ausgelöst!
  breq    i_1 
  rjmp    main
i_1:
  clr      stat   ; stat auf null setzen
  clr      z2    ; Timer auf null setzen für Wartezeit     
i_2:
  cpi      stat,1   ; Prüfen ob Interrupt wären der Wartezeit ausgelöst hat!
  breq    i_1    ; Wenn ausgelöst, springe zurück zu  i_1
  cpi      z2,10  ; Wenn  wärend der Wartezeit kein Interrupt stattfand, wird der Impuls registriert!
  breq    impuls
  rjmp    i_2    ;
impuls:
  cpi      z3,0
  breq    m_start
m_ret:
  cpi      z3,10  ; z3 Inkrementieren bis 10 Impulse
  brsh    end
  inc      z3  
  clr      stat  
  rjmp    main  ; Zurück zu Anfang
m_start:
  clr      z1    ; Beim start, Zeitmessung beginnen 
  rjmp    m_ret  ; Zurück zum Impuszähler
  
end:
  sts      count,z1
  cbi      PB,0
w_1:
  clr      z2
w_2:
  cpi      z2,10
  breq    w_3
  rjmp    w_2
w_3:
  sbi      PB,0
  clr      z3 ; Impulszähler auf null setzen
  clr      stat
  rjmp    main
  
.dseg 
count:  .BYTE 1

[Karl H. (kbuchegg)]

Lukas G. schrieb:

> Spielt generell es ein Rolle WO ich die Assemblerdirektive;
>
> .dseg
> count:  .BYTE 1
>
> im Code selbst hinschreibe?

Vom Prinzip her ist es wurscht.
Alles was unter .dseg kommt wird gesammelt und dem SRAM zugewiesen (in 
der Reihenfolge in der es von oben nach unten auftaucht)
Alles was unter .csef definiert wird, wird genaso gesammelt und dem 
Flash zugewiesen (wieder von oben nach unten).

.dseg bzw. .cseg sind also so ähnlich wie Umschalter, die bestimmen 
wohin das Nachfolgende gehört. Entweder SRAM oder Flash.

> Also ich meine nicht direkt im Code, sondern dort wo ich die Register
> deklariere also Am Ganz am Anfang, oder erst am Schluss?

Die Register definierst du sowieso nicht. Die gibt es schon. Was du 
vereinbarst, das sind andere Namen für die Register. Da geht es aber 
nicht darum, dass dafür irgendwelcher Code generiert werden soll oder 
dass irgendwelche Speicherreservierungen im SRAM gemacht werden sollen, 
sondern es geht einzig und alleine um eine Vereinabarung zwischen dir 
und dem Assembler-Übersetzungspogramm "Hör mal. Wenn ich in Zukunft 
'hamstibamsti' schreibe, dann meine ich damit das Register r18". Das 
kann daher stehen wo es will, solange es nur vor der ersten Verwendung 
des somit neu bekannt gemachten Namens passiert.

> Ich hab bei den ersten Versionen, das Codesegment ganz am Anfang
> deklariert, dann hat aber das Programm nicht mehr Funktioniert.

Was jetzt. Codesegment (.cseg) oder Datensegment (.dseg). Wenn weder das 
eine noch das andere angegeben ist, dann ist automatisch das Codesegment 
erst mal das 'aktive Segment'.

> Schreibe ich es am Schluss funktioniert alles wie gewünscht, waber warum
> ist das SO?

Weil du irgendeinen Fehler gemacht hast. Dann kann man aber nicht 
eruieren, wenn du die Version zeigst, die dann letzten Endes 
funktioniert.

[Michael U. (amiga)]

Hallo,

.dseg ist das Datensegment, also der Ram. Kannst Du prinzipiell an 
beliebige Stelle schreiben, Du mußt nur daran denken, wieder auf .cseg 
(Codesegmeht) zu schalten, bevor Du wieder mit Programmcode schreibst.

Bei mir landen die .dseg-Sachen auch bei den Registerdefinitionen, vor 
dem Begin der Vektoren steht dann generll bei mir

.cseg

;Vektoren
.org 0x0000
  rjmp   configurations
.org 0x0001
  rjmp  int_1
.org 0x0009
  rjmp  timer0_overflow

um bei Deinem Progarmm zu bleiben.

Gruß aus Berlin
Michael

[Lukas G. (lukas88)]

Ich glaub ich weis vo der Hund begraben liegt.

.cseg


Muss ich also in demfall anwenden wie .nolist & .list

Habs gerade ausprobiert, und es hat Funktioniert!

Komischerweise steht davon im Tutorial nichts. Aber dort ist .dseg ja 
auch am Schluss...

Besten dank für die Hilfe

mfg Lukas

[Michael U. (amiga)]

Hallo,

Karl Heinz war wieder ausführlicher sehe ich gerade.

Ein Tipp von mir ganz allgemein:
verfalle nicht in den Trend, wenig tippen zu wollen.
Dann über lieber den Umgang nit Ctrl-c/ctrl-v, also kopieren/einfügen.

.equ  PD       = PORTD
.equ  DD       = DDRD

.equ  PB      = PORTB
.equ  DB      = DDRB

wenn schon, dann bei Deinem Programm:

.equ  KEY_PORT = PORTD
.equ  KEY_DDR  = DDRD
.equ  KEY_PIN  = PIND

.equ  LED_PORT  = PORTB
.equ  LED_DDR   = DDRB
.equ  LED_PIN   = PB0

...

  ldi      t1,0x00  ;PortD als Eingang
  out      KEY_DDR,t1

  ldi      t1,0xFF  ;Pullups PortD aktivieren
  out      KEY_PORT,t1

  ldi      t1,0xFF  ;PortB als Ausgang
  out      LED_DDR,t1

  ldi      t1,0xFF  ;PortB Pullups deaktiviert
  out      LED_PORT,t1

...

  sts      count,z1
  cbi      LED_PORT,LED_PIN
w_1:
  clr      z2
w_2:
  cpi      z2,10
  breq    w_3
  rjmp    w_2
w_3:
  sbi      LED_PORT,LED_PIN
  clr      z3 ; Impulszähler auf null setzen
  clr      stat

Ich habe nur eine Beispielstelle genommen.

Wenn Du jetzt die LED statt an PB0 an PC2 hängst, muß Du nur
.equ  LED_PORT  = PORTB
.equ  LED_DDR   = DDRB
.equ  LED_PIN   = PB0

in

.equ  LED_PORT  = PORTC
.equ  LED_DDR   = DDRC
.equ  LED_PIN   = PC2

"Spechende Namen" sind eine sehr praktische Hilfe, wenn man was ändern 
will oder nach 2 Jahren wieder in das Programm schaut.

Gruß aus Berlin
Michael