Arduino UNO Power Safe mit Watchdog

[poertner (Gast)]

Hallo zusammen,

wie oben schon geschrieben habe ich Probleme mit dem Watchdog bei meinem 
Arduino UNO. Ich google und probiere jetzt schon eine ganze Weile, finde 
den bug aber nicht.
Vielleicht kann einer helfen?

Ich möchte meinen Arduino UNO für 20 sek. in den PWR_DOWN Mode schicken. 
Bei meinem Sketch scheinen es aber nur 2 sek zu sein. Und startet immer 
mit dem Setup neu :-(.

Gruß poertner



void setup() {
  Serial.begin(57600);     // Set console baud rate
  Serial.println ("Setup... ");
  wdt_enable(WDTO_2S); // WDT 2s
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // den tiefsten Schlaf auswählen 
PWR_DOWN
  Serial.println ("Setup wird beendet.");
}

void loop() {

  Serial.println ("Hauptschleife wird durchlaufen ");
  for (int i = 0; i < 10; i++) {
    Serial.println ("enter sleep-Funktion ");
    Serial.println (i);
    delay(1000); //delay, für serial monitor
    sleep_enable(); // sleep mode einschalten
    sleep_mode(); // in den sleep mode gehen
    sleep_disable(); // hier nach dem sleep weiter machen
  }
  Serial.println ("nach der Schalfdauer???");
  wdt_disable();
}

[arduino-fan (Gast)]

Hej,

zum ersten Problem:

was verlangt denn der Code

       wdt_enable(WDTO_2S); // WDT 2s

vom Arduino?

Gruß

[Frank E. (Firma: Q3) (qualidat)]

Ich glaube (weiss aber nicht genau), dass mit dem Watchdog so lange 
Zeiten wie 20s wg. inermem Zählerüberlauf garnicht machbar sind. Bereits 
2s sind für einen Mikrocontroller quasi Äonen ...

Lösung (so ungefähr): Immer mal kurz aufwachen und zusätzlichen Zähler 
hochsetzen. Wenn Soll-Zählerstand noch nicht erreicht, wieder schlafen 
legen.

[Ulrich F. (Gast)]

poertner schrieb:
> Und startet immer
> mit dem Setup neu :-(.

Ich sehe keine ISR für den WDT!

Und dann geht es zwangsläufig nach 2S über Los

[chris (Gast)]

WDT auf 4 Sec einstellen, und 5x sleep in einem Loop durchlaufen.
Beispiel:

void sleep(unsigned int times) {
//  wdt init
    wdt_reset();
    MCUSR &= ~(1<<WDRF);
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer.
    WDTCSR |= (1<<WDIF); // disable interrupt flag
    WDTCSR |= (1<<WDCE) | (1<<WDE) | 8;
    wdt_reset();

  do {
    digitalWrite(13, LOW);
    WDTCSR |= (1<<WDIE);
    set_sleep_mode(SLEEP_MODE_PWR_DOWN); // den tiefsten Schlaf 
auswählen
    sleep_enable(); // sleep mode einschalten
    sleep_mode(); // in den sleep mode gehen
    sleep_disable(); // hier nach dem sleep weiter machen
    digitalWrite(13, HIGH);
  } while(--times);

}

  ISR(WDT_vect) // Watchdog timer ISR
  {
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer.
  }

[chris (Gast)]

Hier die bessere Version, times ist jetzt in Sekunden.

void sleep(unsigned int times) {
    unsigned char t=6;
    if(!(times&1)) { times>>=1; t++; }
    if(!(times&1)) { times>>=1; t++; }
    if(!(times&1)) { times>>=1; t++; }

//  wdt init
    wdt_reset();
    MCUSR &= ~(1<<WDRF);
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer.
    WDTCSR |= (1<<WDIF); // disable interrupt flag
    WDTCSR |= (1<<WDCE) | (1<<WDE) | t;
    wdt_reset();

  do {
    digitalWrite(13, LOW);
    WDTCSR |= (1<<WDIE);
    set_sleep_mode(SLEEP_MODE_PWR_DOWN); // den tiefsten Schlaf
auswählen
    sleep_enable(); // sleep mode einschalten
    sleep_mode(); // in den sleep mode gehen
    sleep_disable(); // hier nach dem sleep weiter machen
    digitalWrite(13, HIGH);
  } while(--times);

}

  ISR(WDT_vect) // Watchdog timer ISR
  {
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer.
  }

[poertner (Gast)]

@arduino-fan

wdt_enable(WDTO_2S); // WDT 2s aktiviert meinem Verständis nach den 
Watchdog mit 2 sekunden-Zeit.

@Frank Esselbach
Der Controller auf dem Arduino UNO kann bis 8s.
Darüber hinaus schwebt mir eine Lösung wie von dir vorgeschlagen vor. 
Habe ich mit der for - Schleife versucht zu realisieren.

[Ulrich F. (Gast)]

poertner schrieb:
> Habe ich mit der for - Schleife versucht zu realisieren.
Kann man tun....

Du hast vergessen die WDT Interrupts zu aktivieren und keine ISR im 
Programm. Daran solltest du vermutlich noch etwas arbeiten.


Zusätzlich könnte man noch die millis() Zählvariable um die 
entsprechende Sekunden Anzahl hoch setzen. Wird nicht sonderlich genau, 
aber vielleicht reichts ja...

[poertner (Gast)]

@chris
Danke für den Code-Vorschlag, der leider auch immer in der 
Setup-Funktion startet.
Für mein besseres Verständnis habe ich den Code kommentiert. Und meine 
Fragen in fett eingefügt.


Hier der komplette Code:

// libraries
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

void setup() {
  Serial.begin(57600);     // Set console baud rate
  Serial.println ("Setup... ");
  delay(1000);
  }

void loop() {

  Serial.println ("Hauptschleife wird durchlaufen ");
  delay(500);
  sleep(20); /Aufrufen der sleep-Funktion - Wert in Sekunden eintragen
  Serial.println ("20 sec gewartet???");
}


void sleep(unsigned int times) {
    unsigned char t=6;

    // Umbau von Sekunden in WDP2 WDP1 WDP0 (timer prescaler bits)
    if(!(times&1)) { times>>=1; t++; }
    if(!(times&1)) { times>>=1; t++; }
    if(!(times&1)) { times>>=1; t++; }


//  wdt init
    wdt_reset();
    MCUSR &= ~(1<<WDRF); //reset flag leeren
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer.
    WDTCSR |= (1<<WDIF); // disable interrupt flag
    WDTCSR |= (1<<WDCE) | (1<<WDE) | t; //WDCE um prescaler setzen zu 
können 4 takte!
    wdt_reset();

  do {
    digitalWrite(13, LOW);
    WDTCSR |= (1<<WDIE); // Enable the WD interrupt (note no reset)
    set_sleep_mode(SLEEP_MODE_PWR_DOWN); // den tiefsten Schlaf 
auswählen
    sleep_enable(); // sleep mode einschalten
    sleep_mode(); // in den sleep mode gehen
    sleep_disable(); // hier nach dem sleep weiter machen
    digitalWrite(13, HIGH);
  } while(--times); // *???*

} //Sleep Funktion Ende

  ISR(WDT_vect) // Watchdog timer ISR
  {
    WDTCSR &= ~(1<<WDIE); // Disable watchdog timer. // *Warum steht 
diese Zeile nicht in der sleep Funktion?*
  }

[Ulrich F. (Gast)]

Aus meiner Wühlkiste, leicht für dich modifiziert:

#include <avr/wdt.h>
#include <avr/sleep.h>

extern volatile unsigned long timer0_millis;
const byte LED = 13;


void sleep(uint16_t seconds)
{
  wdt_enable(WDTO_1S);
  WDTCSR |= _BV(WDIE);
  while(seconds--)
  {
    set_sleep_mode(SLEEP_MODE_PWR_DOWN);// SLEEP_MODE_PWR_SAVE
    sleep_enable(); 
    sleep_mode(); 
    // sleeping
    sleep_disable();
    WDTCSR |= _BV(WDIE);
  }
  wdt_disable();
}


void setup() 
{
  pinMode(LED,OUTPUT);
}

void loop() 
{
  sleep(3);
  digitalWrite(LED,!digitalRead(LED));
}



ISR(WDT_vect) // Watchdog timer ISR
{
    timer0_millis += 1000; // atomic
}

[poertner (Gast)]

@Ulrich F.

Danke Danke.

Mit dem Code läuft es, ohne das der Arduino regelmäßig in den Reset 
geht. :-)
Ich werde morgen mal probieren den Code in mein Programm zu 
implementieren.