Arduino: Bei erfüllter Bedingung Anweisung nur einmal ausführen

[Joe J. (neutrino)]

Hallo Leute,

Zum Einarbeiten in die Arduino-Welt habe ich Neuling auf dem Steckbrett 
eine Lüftersteuerung simuliert - mit Poti statt Sensor, LED und Oszi 
statt Lüfter. Bei Erreichen einer bestimmten Temperatur startet PWM mit 
etwa 10 % und mit zunehmender Temperatur werden die Pulse breiter.
Klappt so weit wunderbar.

Nun möchte ich aber, dass auch ein älterer, verstaubter Lüfter sicher 
startet. Daher soll der Lüfter nicht mit nur 10 % Pulsbreite starten, 
sondern für die ersten ein oder zwei Sekunden mit 100 %.
Ich krieg das einfach nicht hin, egal was ich auch versuche. :(

Hier der Code:

int pwmPin = 6;                   // Lüfter
int t1Pin = A1;                   // Temperatursensor
int t1ValC(0);                    // Begrenzter Wert für Temperatursensor
int pwmVal(0);                    // Variable für die Pulsbreite

void setup()
{
  pinMode(pwmPin, OUTPUT);        // setzt Pin als Ausgang
}

void loop()
{
int t1Val = analogRead(t1Pin);
t1ValC = constrain(t1Val, 100, 800);  // brgrenzt min. und max. Wert

{  
  pwmVal = map(t1ValC,100,800,24,255);   // rechnet begrenzten Wert von 100 - 800
}                                        // in PWM 24 - 255 um (entspricht 10 - 100 % Pulsbreite)

 { 
  if (pwmVal >=25) {
  analogWrite(pwmPin, pwmVal);
  } else {
  analogWrite(pwmPin,0);
  }

Gruß, Joe

[Frank L. (hermastersvoice)]

kleiner Tipp: was im Setupbereich steht wird nur einmal ausgeführt. 
Ansonsten macht man sich eine Variable die als Flag dient. Ist dieses 
Flag nicht gesetzt wird die Funktion ausgeführt, bei gesetztem Flag 
nicht.

[Joachim B. (jar)]

bei 0% oder 100% setzt die PWM aus wenn ich mich recht erinnere, es geht 
nur von 1%-99%, genauer von 1-255 oder war es 1-254 weil 255 keine PWM 
mehr ist?

0 oder 255 ist Dauer low/high und keine PWM

alternativ, PWM Port nur auf out als PORT und nach Anlaufzeit auf PWM 
umstellen.

[Falk B. (falk)]

@Joachim B. (jar)

>bei 0% oder 100% setzt die PWM aus wenn ich mich recht erinnere,

Was soll da aussetzen? 0% = dauerhaft LOW, 100% dauerhaft HIGH.

>es geht nur von 1%-99%

Nö. Ausserdem geht der Parameter von analog_write von 0-255.

>alternativ, PWM Port nur auf out als PORT und nach Anlaufzeit auf PWM
>umstellen.

Nö, denn der Arduino nutzt die PWM im phase correct mode, da sind 0 und 
100% sprich 0 und 255 kein Problem.

[Falk B. (falk)]

@ Joe J. (neutrino)

int pwmPin = 6;                   // Lüfter
int t1Pin = A1;                   // Temperatursensor
int t1ValC(0);                    // Begrenzter Wert für Temperatursensor
int pwmVal(0);                    // Variable für die Pulsbreite

void setup()
{
  pinMode(pwmPin, OUTPUT);        // setzt Pin als Ausgang
  analogWrite(pwmPin, 255);
  delay(2000);
}

void loop()
{
  int t1Val = analogRead(t1Pin);
  t1ValC = constrain(t1Val, 100, 800);  // brgrenzt min. und max. Wert
  
  pwmVal = map(t1ValC,100,800,24,255);   // rechnet begrenzten Wert von 100 - 800
                                         // in PWM 24 - 255 um (entspricht 10 - 100 % Pulsbreite)
 
  if (pwmVal >=25) {
    analogWrite(pwmPin, pwmVal);
  } else {
    analogWrite(pwmPin,0);
  }
}

[Joe J. (neutrino)]

Im Setup möchte ich das aber nicht reinmachen. Denn der Lüfter soll ja 
nicht beim Einschalten des Gerätes starten, sondern erst beim Erreichen 
einer bestimmten Temperatur.

Ähm, was ist ein Flag, wie setzt man das und wo kommt das hin? Ich habe 
bereits folgenden versucht:
Eine Variable namens "state" gesetzt und dann mit dem if-Befehl bei 
analogwert > 100 state auf 1 gesetzt. Hat aber auch nicht geklappt. 
Irgendwie steh ich auf dem Schlauch.

Danke inzwischen.

[Joachim B. (jar)]

Falk B. schrieb:
> Was soll da aussetzen? 0% = dauerhaft LOW, 100% dauerhaft HIGH.

mir war so bei einer invertierten LED Fading Geschichte ein 0 oder 255 
machte nicht dunkel sondern volle Helligkeit, ich musste ja die original 
LED Fading Tabelle bei einem LCD umdrehen weil es LCD mit HG Beleuchtung 
gibt die invers arbeiten, die Kennlinie also nicht passte und mit 0 oder 
255 war nix mit gedimmt weil der Zustand statisch wurde und eben volle 
Helligkeit war statt voll dunkel.

[Nobody (Gast)]

Joe J. schrieb:
> Eine Variable namens "state" gesetzt
Das ist schon mal eine gute Idee.

Der erste Schritt zu einem endlichen Automaten.

Mehr Zustände einführen!
1. Aus (startbedingung)
2. Anlauf (kurz auf Vollgas)
3. Regelung

[Falk B. (falk)]

@Joe J. (neutrino)

>Im Setup möchte ich das aber nicht reinmachen. Denn der Lüfter soll ja
>nicht beim Einschalten des Gerätes starten, sondern erst beim Erreichen
>einer bestimmten Temperatur.

Das sollte man sagen ;-)

>Ähm, was ist ein Flag, wie setzt man das und wo kommt das hin? Ich habe
>bereits folgenden versucht:
>Eine Variable namens "state" gesetzt und dann mit dem if-Befehl bei
>analogwert > 100 state auf 1 gesetzt.

Erspar uns diese Lyrik, poste originalen Quelltext.

> Hat aber auch nicht geklappt.
>Irgendwie steh ich auf dem Schlauch.

Statemachine

int pwmPin = 6;                   // Lüfter
int t1Pin = A1;                   // Temperatursensor
int t1ValC;                       // Begrenzter Wert für Temperatursensor
int pwmVal;                       // Variable für die Pulsbreite
int fan_state;                    // State machine
int delay_cnt;

#define FAN_STATE_OFF    0
#define FAN_STATE_ON     1
#define FAN_STATE_DELAY  2

void setup()
{
  pinMode(pwmPin, OUTPUT);        // setzt Pin als Ausgang
  fan_state = FAN_STATE_OFF;
}

void loop()
{
  int t1Val = analogRead(t1Pin);
  t1ValC = constrain(t1Val, 100, 800);    // begrenzt min. und max. Wert

  switch(fan_state) {
    case FAN_STATE_OFF:
      if (t1ValC > 200) {
        fan_state = FAN_STATE_DELAY;
        delay_cnt = 2;
        pwmVal = 0;
      }
    break;

    case FAN_STATE_DELAY:
      delay_cnt--;
      if (delay_cnt == 0) {
        fan_state = FAN_STATE_ON;
      }
    break;

    case FAN_STATE_ON:
      if (t1ValC < 200) {
        fan_state = FAN_STATE_OFF;
        pwmVal = 0;
      } else {
        pwmVal = map(t1ValC,100,800,24,255);    // rechnet begrenzten Wert von 100 - 800
                                                // in PWM 24 - 255 um (entspricht 10 - 100 % Pulsbreite)
      }

    break;
  }
  if (pwmVal < 25) pwmVal=0;
  analogWrite(pwmPin, pwmVal);    
  delay(1000);                                   // Taktzyklus 1s
}

[Oller (Gast)]

Das wäre ein schöner Troll-Thread für unseren Asm-Fanatiker.
Ein Tipp: schnapp dir ein Blatt Papier und mach ein Ablaufdiagrm. Dann 
proggst du das schön nach...

[Joe J. (neutrino)]

Falk B. schrieb:
> Das sollte man sagen ;-)

Ich dachte, das ging aus dem Eingangspost hervor...


Falk B. schrieb:
> Erspar uns diese Lyrik, poste originalen Quelltext.

Es gibt nur den von mir bereits geposteten. Alle anderen Quelltexte, 
welche ich mit ergoogelten Codestückchen zu erweitern versuchte, habe 
ich frustriert wieder verworfen.

Dass ich ein Neuling bin, habe ich geschrieben. Vielleicht hätte ich 
noch erwähnen sollen, dass ich von Programmiersprachen bis vor wenigen 
Wochen absolut keine Ahnung hatte. Ich programmierte meine PICs bis 
jetzt (bitte nicht lachen) immer mit Parsic.
Nun, mit den Begriffen #define, switch, case und break bin ich noch 
absolut nicht vertraut. Ich werde mich morgen etwas damit beschäftigen 
und versuchen deinen Code zu verstehen. :)

Vielen Dank für deine Mühe, Falk Brunner (falk)!
Gruß, Joe

[Nobody (Gast)]

Joe J. schrieb:
> Nun, mit den Begriffen #define, switch, case und break bin ich noch
> absolut nicht vertraut.
Darauf kann man verzichten.
Mit Zeiger auf Funktionen tuts das genau so gut.

[Falk B. (falk)]

@ Nobody (Gast)

>> Nun, mit den Begriffen #define, switch, case und break bin ich noch
>> absolut nicht vertraut.
>Darauf kann man verzichten.
>Mit Zeiger auf Funktionen tuts das genau so gut.

Pädagogisch sehr sinnvoll für einen Anfänger . . .

[Kolja L. (kolja82)]

Aber so ist es übersichtlicher.

case ist wie eine Akte voll Code zu verstehen
und switch die Entscheidungsmöglichkeit,
welche Akte voll Code ausgeführt wird.

Es werden also drei Fälle (engl. case) definiert,
für jeden deiner möglichen Zustände einer.
Und dann wird immer wieder (bei jedem loop) abgefragt, welcher Fall 
gerade behandelt werden soll.

[Joe J. (neutrino)]

@ Falk Brunner:

Dein Code funktioniert leider nicht so wie gewünscht. "delay(1000)" ist 
ständig aktiv, so dass auch das Drehen am Poti verzögert reagiert. Und 
der Lüfter startet nicht mit Vollgas, sondern pwmVal entsprechend.
Aber Dank deines Codes und mit dem Link zur Statemachine (den Begriff 
hatte ich vorher noch nie gehört) habe ich es nun endlich hingekriegt! 
:-D

/*
Analoger Temperatureingang, PWM-Ausgang für Lüfter.
LCD ist nur für Testzwecke.
*/

#include <LiquidCrystal.h>
LiquidCrystal lcd(12, 11, 5, 4, 3, 2); // diese Pins werden benutzt (RS, E, D4, D5, D6, D7)

int pwmPin = 6;                   // Lüfter
int t1Pin = A1;                   // Temperatursensor
int t1ValC(0);                    // Begrenzter Wert für Temperatursensor
int pwmVal(0);                    // Variable für die Pulsbreite
unsigned char state = 1;          // globale Variable, die den Status repräsentiert

void setup()
{
  pinMode(pwmPin, OUTPUT);        // setzt Pin als Ausgang
  lcd.clear();                    // LCD löschen
  lcd.begin(16, 4);               // verfügbare Spalten und Zeilen
}

void loop()
{

int t1Val = analogRead(t1Pin);
t1ValC = constrain(t1Val, 100, 800);  // brgrenzt min. und max. Wert
pwmVal = map(t1ValC,100,800,24,255);  // rechnet begrenzten Wert von 100 - 800
                                      // in PWM 24 - 255 um (entspricht 10 - 100 % Pulsbreite)
  lcd.clear();  
  lcd.setCursor(0,0);
  lcd.print(t1Val);
  lcd.setCursor(0,1);
  lcd.print(pwmVal);
  lcd.setCursor(0,2);
  lcd.print(state);
  delay(50);


switch (state) {
  case 1:                             //Temperatur niedrig, Lüfter aus..
  if (t1Val < 100) 
  {
    analogWrite(pwmPin,0);
    state = 1;
  }  else  {                          //.. ansonsten schalte auf case 2
  state = 2;
  }
  break;

  case 2:                             //Lüfter startet für 2 s Vollgas
  if (t1Val >= 100) analogWrite(pwmPin, 255);
  delay(2000);
  state = 3;                          //schalte auf case 3
  break;

  case 3:                             //Lüfter läuft mit Wert "pwmVal"
  if (t1Val >= 100)
  {
    analogWrite(pwmPin, pwmVal);
  } else if (t1Val < 90) {            //Temperatur zu niedrig, schalte auf case 1
  state = 1;
  }
  break;
}
}

Toll ist auch, dass ich den Ausschaltwert in case 3 niedriger als den 
Einschaltwert setzen konnte; dadurch erhält man eine Hysterese. 
Womöglich setze ich diesen Code tatsächlich mal ein einem Labornetzteil, 
Ladegerät o.ä. ein.


Vielen Dank an falk und auch den anderen für die Beiträge!
Gruß, Joe