DCC Signal wird nicht erkannt

[Michael E. (mieb)]

Hallo Leute,

die letzten Tage hab ich mich wieder an mein Projekt eines DCC-Dekoders 
Marke Eigenbau gesetzt. Allerdings bin ich langsam am verzweifeln, da 
ich nicht mehr weiß wo noch der Fehler liegen könnte.
Zum Abgreifen des Signals verwende ich die angehängte Schaltung.
Um die Schaltung zu testen wollte ich eine LED einschalten, wenn eine 0 
empfangen wird. Allerdings leuchtet diese nie (ja die LED funktioniert 
und ist richtig herum eingebaut).

Wäre sehr dankbar wenn da mal jemand über Schaltung und Progrämmchen 
drüberschauen könnte und vielleicht ne Idee hat wo ich einen Fehler 
mache.

; Mikrocontroller: ATtiny45
; Versorgungsspannung: 4,5-5V
; Taktart: Interner Oszillator
; Taktfrequenz: 8MHz
; Brown-out Detection: 2,7V
.include "tn45def.inc"

.def temp = r16

;------------------------------- Interruptvektortabelle --------------------------------
.org 0x0
  rjmp RESET        ; 0x0 (Reset Handler)
  rjmp INT0_ISR      ; 0x1 (External Interrupt Request 0 Handler)
  reti          ; 0x2 (Pin Change Interrupt Request 0 Handler)
  reti          ; 0x3 (Timer/Counter1 Compare Match A Handler)
  reti          ; 0x4 (Timer/Counter1 Overflow Handler)
  reti          ; 0x5 (Timer/Counter0 Overflow Handler)
  reti          ; 0x6 (EEPROM Ready Handler)
  reti          ; 0x7 (Analog Comparator Handler)
  reti          ; 0x8 (ADC Conversion Complete Handler)
  reti          ; 0x9 (Timer/Counter1 Compare Match B Handler)
  rjmp TIMER0_COMPA_ISR  ; 0xA (Timer/Counter0 Compare Match A Handler)
  reti          ; 0xB (Timer/Counter0 Compare Match B Handler)
  reti          ; 0xC (Watchdog Time-out Handler)
  reti          ; 0xD (USI Start Handler)
  reti          ; 0xE (USI Overflow Handler)

RESET:
  ; Stackpointer initialisieren
  ldi temp, LOW(RAMEND)
  out SPL, temp

  ldi temp, HIGH(RAMEND)
  out SPH, temp

  ; Alle I/O Pins werden vom Controller als Eingänge ohne aktivierten Pull-Up Widerstand initialisiert
  ; Alle benötigten Ausgänge müssen festgelegt werden
  sbi DDRB, DDB4  ; PB4 wird als Spannungsquelle für eine LED verwendet

  ; Um undefinierte Potenziale zu vermeiden werden an allen eingängen die Pull-Up Widerstände aktiviert, um diese auf ein definiertes Potenzial(VCC) zu bringen
  ldi temp, (1 << PORTB0) | (1 << PORTB1) | (1 << PORTB2) | (1 << PORTB3) | (1 << PORTB5)
  out PORTB, temp

  ; Timer/Counter0 Initialisierung
  ; Frequenz: ~12,8kHz (80us)
  ldi temp, (1 << TSM) | (1 << PSR0)  ; Timer/Counter0 wird in Konfigurationsmodus versetzt
  out GTCCR, temp

  ldi temp, (1 << WGM01)  ; Verwende Timer im CTC-Modus
  out TCCR0A, temp

  ldi temp, (1 << CS01)  ; Timer/Counter Prescaler von 8 (=> Timer/Counter Frequenz von ~1MHz)
  out TCCR0B, temp

  ldi temp, 80  ; Nach 80 Zählzyklen soll der Timer zurückgesetzt werden
  out OCR0A, temp

  ldi temp, (1 << OCIE0A)  ; Aktiviere Timer/Counter0 Compare Match A Interrupt
  out TIMSK, temp

  ; Konfiguration des External Interrupt 0
  ldi temp, (1 << ISC01) | (1 << ISC00)
  out MCUCR, temp  ; Auslösen eines Interrupts bei steigender Flanke an INT0

  ldi temp, (1 << INT0)
  out GIMSK, temp  ; Aktiviere External Interrupt 0

  sei ; Interrupts global aktivieren

dcc:
  rjmp dcc
  
INT0_ISR:
  push temp
  clr temp
  out GTCCR, temp  ; Timer/Counter0 starten
  pop temp
  reti

TIMER0_COMPA_ISR:
  push temp
  ldi temp, (1 << TSM) | (1 << PSR0)  ; Timer/Counter0 wieder stoppen
  out GTCCR, temp
  sbic PINB, INT0
  sbi PORTB, PORTB4 ; Einschalten wenn eine 0 empfangen wurde
  pop temp
  reti

[Paul B. (paul_baumann)]

Ich habe Dir mal meine funktionsfähige Schaltung (allerdings mit Tiny15) 
angehangen. Bei mir ist aber ein 100nF Stützkondensator drin und ein 
Ziehwiderstand an Reset gegen +Ub.

Daß das funktioniert, sieht man am 2. angefügten Bild.



MfG Paul

[J. S. (engineer)]

Müsste man das nicht generell kapazitiv ankoppeln?

[Paul B. (paul_baumann)]

Jürgen S. schrieb:
> Müsste man das nicht generell kapazitiv ankoppeln?

Müsste man offensichtlich nicht ,denn es funktioniert ja so.

MfG Paul

[Thomas P. (topla)]

Michael E. schrieb:
> TIMER0_COMPA_ISR:
>   push temp
>   ldi temp, (1 << TSM) | (1 << PSR0)  ; Timer/Counter0 wieder stoppen
>   out GTCCR, temp
>   sbic PINB, INT0
>   sbi PORTB, PORTB4 ; Einschalten wenn eine 0 empfangen wurde
>   pop temp
>   reti

INT0 ist mit "6" definiert, siehe auch Deine Initialisierung von GIMSK.
Mit "sbic PINB, INT0" fragst Du Pin6 von PortB ab, der ist im Tiny nicht 
vorhanden und wird laut Datenblatt immer mit 0 gelesen.

Thomas

[Michael E. (mieb)]

Paul B. schrieb:
> Ich habe Dir mal meine funktionsfähige Schaltung (allerdings mit Tiny15)
> angehangen. Bei mir ist aber ein 100nF Stützkondensator drin und ein
> Ziehwiderstand an Reset gegen +Ub.
>
> Daß das funktioniert, sieht man am 2. angefügten Bild.
>
>
>
> MfG Paul

Hab die Reset Beschaltung jetzt mal so übernommen (sprich 10k Pull-up 
zwischen VCC und Reset sowie 100nF Elko(?!) zwischen Reset und GND)

Hab die schon öfter gesehen und kann ja nix schaden

Thomas P. schrieb:
> INT0 ist mit "6" definiert, siehe auch Deine Initialisierung von GIMSK.
> Mit "sbic PINB, INT0" fragst Du Pin6 von PortB ab, der ist im Tiny nicht
> vorhanden und wird laut Datenblatt immer mit 0 gelesen.

Das hab ich nun wirklich voll übersehen
Dachte zugunsten der Lesbarkeit schreib ich hin, dass das der INT0 Pin 
ist.
Ich vermute einfach mal, dass das der Wurm bei der Angelegenheit war.
Vielen Dank schonmal im Voraus (hab es noch nicht getestet)
Da wäre ich noch 3 Tage gesessen bis ich auf den Trichter gekommen wäre.

Viele Grüße
Michael