AVR Arduino Timerproblem

[Shaggie S. (shaggie)]

Hallo,

mein Projekt ist ein K-line OBD Sniffer. Ich möchte die Bytes lesen die 
Übertragen werden, dafür nehme ich einen Arduino Nano Clone.
Es handelt sich also um einen ATMega328p. Zur Programmierung nutze ich 
das Ardunio Studio.

Die Baudrate des K-Line-Bus liegt bei 10400 Baud, ich habe nun zu 
Testzwecken eine TTL UART USB Stick mit CP2101 auf 9600 Baud eingestellt 
und sende ein Signal mit Druck der a-Taste und versuche dieses nun mit 
dem Arduino zu messen. Jedoch kommt dabei nicht immer das richtige 
Ergebnis raus.
Um nun zu überprüfen woran es liegt, habe ich einen Logicanalyzer eines 
Bekannten geliehen, um zu schauen was der Timer so macht.

Dabei kommt raus, dass der Timer schon bei Aktivierung einen Interrupt 
wirft. Was mir nicht einleuchtet, da er erstmal loszählen soll. Das er 
28µs benötigt um loszulegen stört mich nicht. aber dass der erste 
Timerlauf nur 54µs dauert, an Stelle von 104µs, verwundert mich sehr.

Woran kann das liegen?

Ergebnis siehe Anhang.
Erklärung zum Bild:
Kanal 0 ist das Signal vom UART Stick
Kanal 1 das alternierende Debugsignal des Arduino

// digital pin 2 has a K-LineWire attached to it. Give it a name:
int kLinePin = 2;
// globaler Counter
int counter = 0;
// zustandsvariable für die Messung
byte messung = 0x00;
// ergebnisbyte
byte kLineByte = 0x00;

// the setup routine runs once when you press reset:
void setup() {
  // initialize serial communication at 115200 bits per second:
  Serial.begin(9600);
  
  pinMode(kLinePin, INPUT);   // Pin D2 als input setzen
  pinMode(3, OUTPUT);         // Pin D3 für debug als output setzen
  
  digitalWrite(3,1);          // setze Pin D3 internen pullup
  digitalWrite(kLinePin,1);   // setze Pin D2 internen pullup
  
  noInterrupts();             // Alle Interrupts temporär abschalten
  
  // Timer 1 setzen
  TCCR1A = 0x00;                 // Timer Control Register mit 0 initialisieren
  TCCR1B = 0x00;                 // Timer Control Register mit 0 initialisieren
  TCCR1B |= (0x01 << WGM12);     // Timer Modus CTC
  TCCR1B |= (0x01 << CS10);      // ohne prescaler
  TCNT1 = 0;                     // Timer Counter mit 0 initialisieren
  OCR1A = 1666;                  // Output Compare Register vorbelegen
      
  //Pinchange interrupt auf Pin D2 scharf schalten
  PCMSK2 |= (0x01<<PCINT18);
  PCICR |= (0x01<<PCIE2);
   
  interrupts();               // alle Interrupts scharf schalten
  
}

//Interrupthandler für Pinchange an D2
//wenn eine Pegeländerung an Pin D2 passiert, werfe interrupt
ISR (PCINT2_vect){
  // wenn Messungszustand 0 und signal an D2 0 Messung starten
  if(messung == 0x00 && digitalRead(kLinePin)==0 ){
    messung = 0x01;
    TIMSK1 |= (1 << OCIE1A);    // starte den timer, alle ~104µs (1667 takte) pin d2 zu messen
  }
}

//Interrupthandler für Abtastraster
ISR(TIMER1_COMPA_vect) {
  byte val = digitalRead(kLinePin)==0 ? 0x00 : 0x01; // miss signal an D2, wandel in byte um
    
  //debug
  digitalRead(3)==1 ? digitalWrite(3,0) : digitalWrite(3,1); // gebe an D3 alternierend 1 oder 0 aus 
    
  erzeugeByte(val); // sende den gemessenen wert an die funktion
}


// befüllt das byte und gibt es an die console weiter
void erzeugeByte(byte _kLinePinState){
  if (counter<8){    
    kLineByte = kLineByte << 1 | _kLinePinState;    
    counter++;
    return;
  }
  
  Serial.print("Byte: ");
  Serial.println(kLineByte, BIN);
  digitalWrite(3,1);
  messung = 0x00;
  TIMSK1 &= ~(1 << OCIE1A);    // stoppe den timer
  kLineByte = 0x00;
  counter = 0;
}

// the loop routine runs over and over again forever:
void loop() {        // delay in between reads for stability
  }

[Peter D. (peda)]

ShAG G. schrieb:
> TIMSK1 |= (1 << OCIE1A);    // starte den timer

Nö, damit wird der Interrupthandler erlaubt.
Start/stop erfolgt mit den CS1x-Bits im TCCR1B;

[Shaggie S. (shaggie)]

Peter D. schrieb:
> ShAG G. schrieb:
>> TIMSK1 |= (1 << OCIE1A);    // starte den timer
>
> Nö, damit wird der Interrupthandler erlaubt.
> Start/stop erfolgt mit den CS1x-Bits im TCCR1B;

DANKE!!!!!